configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2011 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.
  21 AC_PREREQ(2.64)
  22
  23 AC_INIT([GNU Bison],
  24         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  25         [bug-bison@gnu.org])
  26 AC_DEFINE([PACKAGE_COPYRIGHT_YEAR], [2011],
  27           [The copyright year for this package])
  28 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2011])
  29
  30 AC_CONFIG_AUX_DIR([build-aux])
  31 AC_CONFIG_MACRO_DIR([m4])
  32
  33 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  34 #
  35 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  36 #
  37 # To avoid 1.11, we make 1.11.1 the minimum version.
  38 #
  39 # We want gnits strictness only when rolling a stable release.  For
  40 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  41 # doesn't like that, so we let the underscore disable gnits.  Between
  42 # releases, we want to be able run make dist without being required to
  43 # add a bogus NEWS entry.  In that case, the version string
  44 # automatically contains a dash, which we also let disable gnits.
  45 AM_INIT_AUTOMAKE([1.11.1 dist-xz]
  46                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  47                            [gnu], [gnits]))
  48 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  49
  50 # Checks for the compiler.
  51 AC_PROG_CC_STDC
  52
  53 # Gnulib (early checks).
  54 gl_EARLY
  55
  56 AC_ARG_ENABLE(gcc-warnings,
  57 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  58 [case "${enableval}" in
  59    yes|no) ;;
  60    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  61  esac],
  62               [enableval=no])
  63 if test "${enableval}" = yes; then
  64   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  65   AC_SUBST([WERROR_CFLAGS])
  66   gl_WARN_ADD([-Wall])
  67   gl_WARN_ADD([-Wextra -Wno-sign-compare])
  68   gl_WARN_ADD([-Wcast-align])
  69   gl_WARN_ADD([-Wcast-qual])
  70   gl_WARN_ADD([-Wformat])
  71   gl_WARN_ADD([-Wpointer-arith])
  72   gl_WARN_ADD([-Wwrite-strings])
  73   AC_SUBST([WARN_CXXFLAGS], [$WARN_CFLAGS])
  74   # The following warnings are not suitable for C++.
  75   gl_WARN_ADD([-Wbad-function-cast])
  76   gl_WARN_ADD([-Wmissing-declarations])
  77   gl_WARN_ADD([-Wmissing-prototypes])
  78   gl_WARN_ADD([-Wshadow])
  79   gl_WARN_ADD([-Wstrict-prototypes])
  80   AC_SUBST([WARN_CFLAGS])
  81   # Warnings for the test suite only.
  82   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  83   WARN_CXXFLAGS_TEST="$WARN_CXXFLAGS $WARN_CFLAGS_TEST"
  84   WARN_CFLAGS_TEST="$WARN_CFLAGS $WARN_CFLAGS_TEST"
  85   AC_SUBST([WARN_CXXFLAGS_TEST])
  86   AC_SUBST([WARN_CFLAGS_TEST])
  87 fi
  88
  89 BISON_TEST_FOR_WORKING_C_COMPILER
  90
  91 AC_ARG_ENABLE([yacc],
  92   [AC_HELP_STRING([--disable-yacc],
  93      [do not build a yacc command or an -ly library])],
  94   , [enable_yacc=yes])
  95 case $enable_yacc in
  96 yes)
  97   YACC_SCRIPT=src/yacc
  98   YACC_LIBRARY=lib/liby.a;;
  99 *)
 100   YACC_SCRIPT=
 101   YACC_LIBRARY=;;
 102 esac
 103 AC_SUBST([YACC_SCRIPT])
 104 AC_SUBST([YACC_LIBRARY])
 105
 106 # Checks for programs.
 107 AC_PROG_LEX
 108 AC_PROG_YACC
 109 AC_PROG_RANLIB
 110 AC_PROG_GNU_M4
 111 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 112 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 113 supports -g, otherwise to "".])
 114 AM_MISSING_PROG([HELP2MAN], [help2man])
 115 AC_PATH_PROG([XSLTPROC], [xsltproc])
 116 AC_SUBST([XSLTPROC])
 117
 118 # Checks for header files.
 119 AC_CHECK_HEADERS_ONCE([locale.h])
 120
 121 # Checks for compiler characteristics.
 122 AC_C_INLINE
 123
 124 # Gnulib (later checks).  Putting them here rather than right after
 125 # gl_EARLY avoids some redundant checks.
 126 gl_INIT
 127
 128 # Checks for library functions.
 129 AC_CHECK_FUNCS_ONCE([setlocale])
 130 AM_WITH_DMALLOC
 131 BISON_PREREQ_SUBPIPE
 132 BISON_PREREQ_TIMEVAR
 133
 134 # Gettext.
 135 # We use gnulib, which is only guaranteed to work properly with the
 136 # latest Gettext.
 137 AM_GNU_GETTEXT([external], [need-ngettext])
 138 AM_GNU_GETTEXT_VERSION([0.18])
 139 BISON_I18N
 140
 141 # Internationalized parsers.
 142 AC_CONFIG_FILES([runtime-po/Makefile.in])
 143 # Autoconf macros for packages using internationalized parsers.
 144 aclocaldir='${datadir}/aclocal'
 145 AC_SUBST([aclocaldir])
 146
 147 # Create the benchmark script.
 148 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 149
 150 # Initialize the test suite.
 151 AC_CONFIG_TESTDIR(tests)
 152 AC_CONFIG_FILES([tests/atlocal])
 153 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 154 AC_CHECK_PROGS([VALGRIND], [valgrind])
 155 AC_PROG_CXX
 156 BISON_TEST_FOR_WORKING_CXX_COMPILER
 157 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 158 # Needed by tests/atlocal.in.
 159 AC_SUBST([GCC])
 160 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 161 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 162
 163 gt_JAVACOMP([1.3], [1.4])
 164 gt_JAVAEXEC
 165
 166 # We use gnulib, but from lib/local.mk instead of lib/Makefile.am.
 167 # So prefix paths with lib/.  See also etc/prefix-gnulib-mk.
 168 gl_LIBOBJS=`echo "$gl_LIBOBJS" | sed -e 's, , lib/,g'`
 169 for ac_var in ALLOCA_H ERRNO_H FCNTL_H GETOPT_H INTTYPES_H \
 170               LIBUNISTRING_UNITYPES_H LIBUNISTRING_UNIWIDTH_H \
 171               STDBOOL_H STDINT_H SYS_WAIT_H WCHAR_H WCTYPE_H
 172 do
 173   eval "test x\$$ac_var = x || $ac_var=lib/\$$ac_var"
 174 done
 175 AC_CONFIG_FILES([Makefile
 176                  po/Makefile.in
 177                  examples/calc++/Makefile
 178                  doc/yacc.1])
 179 AC_OUTPUT