configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009,
   4 # 2010 Free Software Foundation, Inc.
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # In order for some versions of Sun Studio to compile our C++ test cases
  20 # correctly, we need Autoconf 2.64 or better to handle the restrict
  21 # keyword in at least string.h from gnulib.
  22 AC_PREREQ(2.64)
  23
  24 AC_INIT([GNU Bison],
  25         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  26         [bug-bison@gnu.org])
  27 AC_DEFINE([PACKAGE_COPYRIGHT_YEAR], [2010],
  28           [The copyright year for this package])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2010])
  30
  31 AC_CONFIG_AUX_DIR([build-aux])
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  35 #
  36 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  37 #
  38 # To avoid 1.11, we make 1.11.1 the minimum version.
  39 #
  40 # We want gnits strictness only when rolling a formal release so that we can,
  41 # for example, run make dist at other times without being required to add a
  42 # bogus NEWS entry.
  43 AM_INIT_AUTOMAKE([1.11.1 dist-bzip2]
  44                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [-], [gnu], [gnits]))
  45 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  46
  47 # Checks for the compiler.
  48 AC_PROG_CC_STDC
  49
  50 # Gnulib (early checks).
  51 gl_EARLY
  52
  53 AC_ARG_ENABLE(gcc-warnings,
  54 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  55 [case "${enableval}" in
  56    yes|no) ;;
  57    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  58  esac],
  59               [enableval=no])
  60 if test "${enableval}" = yes; then
  61   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  62   AC_SUBST([WERROR_CFLAGS])
  63   gl_WARN_ADD([-Wall])
  64   gl_WARN_ADD([-Wextra -Wno-sign-compare])
  65   gl_WARN_ADD([-Wcast-align])
  66   gl_WARN_ADD([-Wcast-qual])
  67   gl_WARN_ADD([-Wformat])
  68   gl_WARN_ADD([-Wpointer-arith])
  69   gl_WARN_ADD([-Wwrite-strings])
  70   AC_SUBST([WARN_CXXFLAGS], [$WARN_CFLAGS])
  71   # The following warnings are not suitable for C++.
  72   gl_WARN_ADD([-Wbad-function-cast])
  73   gl_WARN_ADD([-Wmissing-declarations])
  74   gl_WARN_ADD([-Wmissing-prototypes])
  75   gl_WARN_ADD([-Wshadow])
  76   gl_WARN_ADD([-Wstrict-prototypes])
  77   AC_SUBST([WARN_CFLAGS])
  78   # Warnings for the test suite only.
  79   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  80   WARN_CXXFLAGS_TEST="$WARN_CXXFLAGS $WARN_CFLAGS_TEST"
  81   WARN_CFLAGS_TEST="$WARN_CFLAGS $WARN_CFLAGS_TEST"
  82   AC_SUBST([WARN_CXXFLAGS_TEST])
  83   AC_SUBST([WARN_CFLAGS_TEST])
  84   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  85 fi
  86
  87 BISON_TEST_FOR_WORKING_C_COMPILER
  88
  89 AC_ARG_ENABLE([yacc],
  90   [AC_HELP_STRING([--disable-yacc],
  91      [do not build a yacc command or an -ly library])],
  92   , [enable_yacc=yes])
  93 case $enable_yacc in
  94 yes)
  95   YACC_SCRIPT=yacc
  96   YACC_LIBRARY=liby.a;;
  97 *)
  98   YACC_SCRIPT=
  99   YACC_LIBRARY=;;
 100 esac
 101 AC_SUBST([YACC_SCRIPT])
 102 AC_SUBST([YACC_LIBRARY])
 103
 104 # Checks for programs.
 105 AC_PROG_LEX
 106 AC_PROG_YACC
 107 AC_PROG_RANLIB
 108 AC_PROG_GNU_M4
 109 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 110 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 111 supports -g, otherwise to "".])
 112 AM_MISSING_PROG([HELP2MAN], [help2man])
 113 AC_PATH_PROG([XSLTPROC], [xsltproc])
 114 AC_SUBST([XSLTPROC])
 115
 116 # Checks for header files.
 117 AC_CHECK_HEADERS_ONCE([locale.h])
 118
 119 # Checks for compiler characteristics.
 120 AC_C_INLINE
 121
 122 # Gnulib (later checks).  Putting them here rather than right after
 123 # gl_EARLY avoids some redundant checks.
 124 gl_INIT
 125
 126 # Checks for library functions.
 127 AC_CHECK_FUNCS_ONCE([setlocale])
 128 AM_WITH_DMALLOC
 129 BISON_PREREQ_SUBPIPE
 130 BISON_PREREQ_TIMEVAR
 131
 132 # Gettext.
 133 # We use gnulib, which is only guaranteed to work properly with the
 134 # latest Gettext.
 135 AM_GNU_GETTEXT([external], [need-ngettext])
 136 AM_GNU_GETTEXT_VERSION([0.17])
 137 BISON_I18N
 138
 139 # Internationalized parsers.
 140 AC_CONFIG_FILES([runtime-po/Makefile.in])
 141 # Autoconf macros for packages using internationalized parsers.
 142 aclocaldir='${datadir}/aclocal'
 143 AC_SUBST([aclocaldir])
 144
 145 # Create the benchmark script.
 146 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 147
 148 # Initialize the test suite.
 149 AC_CONFIG_TESTDIR(tests)
 150 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 151 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 152 AC_CHECK_PROGS([VALGRIND], [valgrind])
 153 AC_PROG_CXX
 154 BISON_TEST_FOR_WORKING_CXX_COMPILER
 155 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 156 # Needed by tests/atlocal.in.
 157 AC_SUBST([GCC])
 158 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 159 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 160
 161 gt_JAVACOMP([1.3])
 162 gt_JAVAEXEC
 163
 164 AC_CONFIG_FILES([Makefile
 165                  build-aux/Makefile
 166                  po/Makefile.in
 167                  data/Makefile
 168                  etc/Makefile
 169                  examples/Makefile
 170                     examples/calc++/Makefile
 171                  lib/Makefile src/Makefile
 172                  doc/Makefile
 173                    doc/yacc.1])
 174 AC_OUTPUT