configure.in

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  16 # 02111-1307  USA
  17
  18 # We need a recent Autoconf to run a recent Autotest.
  19 AC_PREREQ(2.52e)
  20
  21 AC_INIT([GNU Bison], [1.29d], [bug-bison@gnu.org])
  22 AC_CONFIG_AUX_DIR(config)
  23
  24 AM_INIT_AUTOMAKE([bison], [1.29d])
  25 AM_CONFIG_HEADER(config.h:config.hin)
  26
  27 # Initialize the test suite.
  28 AC_CONFIG_TESTDIR(tests)
  29 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
  30
  31 # Checks for programs.
  32 AC_PROG_CC
  33 AC_MINIX
  34 AC_ISC_POSIX
  35 AM_PROG_CC_STDC
  36 AC_PROG_RANLIB
  37 # GNU M4 is needed to build the testsuite.
  38 BISON_AC_PROG_GNU_M4
  39 if test "$ac_cv_prog_gnu_m4" != yes; then
  40   missing_dir=`cd $ac_aux_dir && pwd`
  41   M4="$missing_dir/missing m4"
  42 fi
  43
  44 AC_ARG_ENABLE(gcc-warnings,
  45 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  46 [case "${enableval}" in
  47    yes|no) ;;
  48    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  49  esac],
  50               [enableval=no])
  51 if test "${enableval}" = yes; then
  52   BISON_WARNING(-Wall)
  53   BISON_WARNING(-W)
  54   BISON_WARNING(-Wbad-function-cast)
  55   BISON_WARNING(-Wcast-align)
  56   BISON_WARNING(-Wcast-qual)
  57   BISON_WARNING(-Wformat)
  58   BISON_WARNING(-Wmissing-declarations)
  59   BISON_WARNING(-Wmissing-prototypes)
  60   BISON_WARNING(-Wnested-externs)
  61   BISON_WARNING(-Wshadow)
  62   BISON_WARNING(-Wstrict-prototypes)
  63   BISON_WARNING(-Wwrite-strings)
  64   CFLAGS="$CFLAGS $WARNING_CFLAGS"
  65 fi
  66
  67 # Checks for libraries.
  68 AC_DEFINE([_GNU_SOURCE],1,[Define to 1 for GNU C library extensions.])
  69
  70 # Checks for header files.
  71 AC_HEADER_STDC
  72 AC_CHECK_HEADERS(ctype.h locale.h memory.h stdlib.h string.h unistd.h)
  73
  74 # Checks for typedefs.
  75
  76 # Checks for structures.
  77
  78 # Checks for compiler characteristics.
  79 AC_C_CONST
  80 AC_C_INLINE
  81 AM_C_PROTOTYPES
  82
  83 # Checks for library functions.
  84 AC_FUNC_ALLOCA
  85 AC_CHECK_FUNCS(mkstemp setlocale)
  86 AC_CHECK_DECLS([stpcpy, strndup, strnlen, memchr])
  87 AC_REPLACE_FUNCS(stpcpy strndup strnlen strspn memchr)
  88 jm_FUNC_MALLOC
  89 jm_FUNC_REALLOC
  90 jm_PREREQ_QUOTEARG
  91 jm_PREREQ_ERROR
  92 AM_WITH_DMALLOC
  93
  94 ALL_LINGUAS="de es et fr ja nl tr ru"
  95 AM_GNU_GETTEXT
  96
  97 # This is necessary so that .o files in LIBOBJS are also built via
  98 # the ANSI2KNR-filtering rules.
  99 LIBOBJS=`echo $LIBOBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`
 100 AC_SUBST(LIBOBJS)
 101
 102 AC_OUTPUT([Makefile
 103            config/Makefile
 104            intl/Makefile po/Makefile.in
 105            lib/Makefile src/Makefile doc/Makefile
 106            m4/Makefile
 107            tests/Makefile])