configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006 Free Software
   4 # Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301  USA
  20
  21 # We use macros like AC_CHECK_HEADERS_ONCE, so we need Autoconf 2.60 or better.
  22 AC_PREREQ(2.60)
  23
  24 AC_INIT([GNU Bison], [2.3+], [bug-bison@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 # We don't have a file m4/Makefile.am, so we need Automake 1.8 or later.
  29 AM_INIT_AUTOMAKE([1.8 check-news readme-alpha dist-bzip2])
  30 AC_CONFIG_HEADERS([config.h:config.hin])
  31
  32 gl_USE_SYSTEM_EXTENSIONS
  33
  34 # Checks for the compiler.
  35 AC_PROG_CC
  36 AM_PROG_CC_STDC
  37 AC_ARG_ENABLE(gcc-warnings,
  38 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  39 [case "${enableval}" in
  40    yes|no) ;;
  41    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  42  esac],
  43               [enableval=no])
  44 if test "${enableval}" = yes; then
  45   gl_WARNING_CFLAGS([-Werror])
  46   AC_SUBST([WERROR_CFLAGS], [$WARNING_CFLAGS])
  47   WARNING_CFLAGS=
  48   gl_WARNING_CFLAGS([-Wextra -Wno-sign-compare])
  49   gl_WARNING_CFLAGS([-Wall])
  50   gl_WARNING_CFLAGS([-Wcast-align])
  51   gl_WARNING_CFLAGS([-Wcast-qual])
  52   gl_WARNING_CFLAGS([-Wformat])
  53   gl_WARNING_CFLAGS([-Wpointer-arith])
  54   gl_WARNING_CFLAGS([-Wwrite-strings])
  55   AC_SUBST([WARNING_CXXFLAGS], [$WARNING_CFLAGS])
  56   # The following warnings are not suitable for C++.
  57   gl_WARNING_CFLAGS([-Wbad-function-cast])
  58   gl_WARNING_CFLAGS([-Wmissing-declarations])
  59   gl_WARNING_CFLAGS([-Wmissing-prototypes])
  60   gl_WARNING_CFLAGS([-Wshadow])
  61   gl_WARNING_CFLAGS([-Wstrict-prototypes])
  62   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  63 fi
  64
  65 BISON_TEST_FOR_WORKING_C_COMPILER
  66
  67 AC_ARG_ENABLE([yacc],
  68   [AC_HELP_STRING([--disable-yacc],
  69      [do not build a yacc command or an -ly library])],
  70   , [enable_yacc=yes])
  71 case $enable_yacc in
  72 yes)
  73   YACC_SCRIPT=yacc
  74   YACC_LIBRARY=liby.a;;
  75 *)
  76   YACC_SCRIPT=
  77   YACC_LIBRARY=;;
  78 esac
  79 AC_SUBST([YACC_SCRIPT])
  80 AC_SUBST([YACC_LIBRARY])
  81
  82 # Checks for programs.
  83 AC_PROG_LEX
  84 AC_PROG_YACC
  85 AC_PROG_RANLIB
  86 BISON_PROG_GNU_M4
  87 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  88   AC_MSG_ERROR([GNU M4 1.4 is required])
  89 fi
  90 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
  91
  92 # Checks for header files.
  93 AC_CHECK_HEADERS_ONCE([locale.h])
  94 AM_STDBOOL_H
  95
  96 # Checks for compiler characteristics.
  97 AC_C_INLINE
  98
  99 # Checks for library functions.
 100 AC_CHECK_FUNCS_ONCE([setlocale])
 101 AM_WITH_DMALLOC
 102 BISON_PREREQ_SUBPIPE
 103 BISON_PREREQ_TIMEVAR
 104
 105 # gnulib and gettext.
 106 GNULIB_AUTOCONF_SNIPPET
 107 # We've never tested with gettext versions before 0.15, so play it safe.
 108 AM_GNU_GETTEXT_VERSION([0.15])
 109 BISON_I18N
 110
 111 # Internationalized parsers.
 112 AC_CONFIG_FILES([runtime-po/Makefile.in])
 113 # Autoconf macros for packages using internationalized parsers.
 114 aclocaldir='${datadir}/aclocal'
 115 AC_SUBST([aclocaldir])
 116
 117 # Initialize the test suite.
 118 AC_CONFIG_TESTDIR(tests)
 119 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 120 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 121 AC_CHECK_PROGS([VALGRIND], [valgrind])
 122 AC_PROG_CXX
 123 BISON_TEST_FOR_WORKING_CXX_COMPILER
 124 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 125 # Needed by tests/atlocal.in.
 126 AC_SUBST([GCC])
 127 O0CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]] *//'`
 128 AC_SUBST([O0CFLAGS])
 129 O0CXXFLAGS=`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`
 130 AC_SUBST([O0CXXFLAGS])
 131
 132 AC_CONFIG_FILES([Makefile
 133                  build-aux/Makefile
 134                  po/Makefile.in
 135                  data/Makefile
 136                  examples/Makefile
 137                     examples/calc++/Makefile
 138                  lib/Makefile src/Makefile doc/Makefile])
 139 AC_OUTPUT