[bison.git] / data / bison.m4

                                                            -*- Autoconf -*-

# Language-independent M4 Macros for Bison.
# Copyright (C) 2002, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.

# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.

# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
# 02110-1301  USA


## ---------------- ##
## Identification.  ##
## ---------------- ##

# b4_copyright(TITLE, YEARS)
# --------------------------
m4_define([b4_copyright],
[b4_comment([A Bison parser, made by GNU Bison b4_version.])

b4_comment([$1

m4_text_wrap([Copyright (C) $2 Free Software Foundation, Inc.], [   ])

This program is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2, or (at your option)
any later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program; if not, write to the Free Software
Foundation, Inc., 51 Franklin Street, Fifth Floor,
Boston, MA 02110-1301, USA.])

b4_comment([As a special exception, you may create a larger work that contains
part or all of the Bison parser skeleton and distribute that work
under terms of your choice, so long as that work isn't itself a
parser generator using the skeleton or a modified version thereof
as a parser skeleton.  Alternatively, if you modify or redistribute
the parser skeleton itself, you may (at your option) remove this
special exception, which will cause the skeleton and the resulting
Bison output files to be licensed under the GNU General Public
License without this special exception.

This special exception was added by the Free Software Foundation in
version 2.2 of Bison.])])


## ---------------- ##
## Error handling.  ##
## ---------------- ##

# b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
# -------------------------------------------
# Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
m4_define([b4_error],
[m4_divert_push(0)[@]$1[(]$2[]m4_if([$#], [2], [],
[m4_foreach([b4_arg],
            m4_dquote(m4_shift(m4_shift($@))),
            [[@,]b4_arg])])[@)]m4_divert_pop(0)])

# b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
# ----------------------------------------------------------
# Write @KIND(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
m4_define([b4_error_at],
[m4_divert_push(0)[@]$1[_at(]$2[@,]$3[@,]$4[]m4_if([$#], [4], [],
[m4_foreach([b4_arg],
            m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
            [[@,]b4_arg])])[@)]m4_divert_pop(0)])

# b4_warn(FORMAT, [ARG1], [ARG2], ...)
# ------------------------------------
# Write @warn(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
#
# As a simple test suite, this:
#
#   m4_define([asdf], [ASDF])
#   m4_define([fsa], [FSA])
#   m4_define([fdsa], [FDSA])
#   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
#   m4_divert(0)
#   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
#   m4_divert(0)
#   b4_warn([asdf), asdf], [fsa), fsa], [fdsa), fdsa])
#   m4_divert(0)
#   b4_warn()
#   m4_divert(0)
#   b4_warn(1)
#   m4_divert(0)
#   b4_warn(1, 2)
#
# Should produce this:
#
#   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
#   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
#   @warn(ASDF), ASDF@,FSA), FSA@,FDSA), FDSA@)
#   @warn(@)
#   @warn(1@)
#   @warn(1@,2@)
m4_define([b4_warn],
[b4_error([[warn]], $@)])

# b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
# ---------------------------------------------------
# Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
m4_define([b4_warn_at],
[b4_error_at([[warn]], $@)])

# b4_complain(FORMAT, [ARG1], [ARG2], ...)
# ----------------------------------------
# Write @complain(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
#
# See the test suite for b4_warn above.
m4_define([b4_complain],
[b4_error([[complain]], $@)])

# b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
# -------------------------------------------------------
# Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
m4_define([b4_complain_at],
[b4_error_at([[complain]], $@)])

# b4_fatal(FORMAT, [ARG1], [ARG2], ...)
# -------------------------------------
# Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
#
# See the test suite for b4_warn above.
m4_define([b4_fatal],
[b4_error([[fatal]], $@)])

# b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
# ----------------------------------------------------
# Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
m4_define([b4_fatal_at],
[b4_error_at([[fatal]], $@)])


## ---------------- ##
## Default values.  ##
## ---------------- ##

# m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
m4_define_default([b4_pre_prologue], [])
m4_define_default([b4_post_prologue], [])
m4_define_default([b4_epilogue], [])
m4_define_default([b4_parse_param], [])

# The initial column and line.
m4_define_default([b4_location_initial_column], [1])
m4_define_default([b4_location_initial_line],   [1])


## ------------ ##
## Data Types.  ##
## ------------ ##

# b4_ints_in(INT1, INT2, LOW, HIGH)
# ---------------------------------
# Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
m4_define([b4_ints_in],
[m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])


## ------------------ ##
## Decoding options.  ##
## ------------------ ##

# b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
# -----------------------------------
# Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
m4_define([b4_flag_if],
[m4_case(b4_$1_flag,
         [0], [$3],
	 [1], [$2],
	 [m4_fatal([invalid $1 value: ]$1)])])


# b4_define_flag_if(FLAG)
# -----------------------
# Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
# value of the Boolean FLAG.
m4_define([b4_define_flag_if],
[_b4_define_flag_if($[1], $[2], [$1])])

# _b4_define_flag_if($1, $2, FLAG)
# --------------------------------
# This macro works around the impossibility to define macros
# inside macros, because issuing `[$1]' is not possible in M4 :(.
# This sucks hard, GNU M4 should really provide M5 like $$1.
m4_define([_b4_define_flag_if],
[m4_if([$1$2], $[1]$[2], [],
       [m4_fatal([$0: Invalid arguments: $@])])dnl
m4_define([b4_$3_if],
          [b4_flag_if([$3], [$1], [$2])])])


# b4_FLAG_if(IF-TRUE, IF-FALSE)
# -----------------------------
# Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
b4_define_flag_if([defines])	        # Whether headers are requested.
b4_define_flag_if([error_verbose])	# Whether error are verbose.
b4_define_flag_if([glr])		# Whether a GLR parser is requested.
b4_define_flag_if([locations])	        # Whether locations are tracked.
b4_define_flag_if([nondeterministic])	# Whether conflicts should be handled.
b4_define_flag_if([pull])	        # Whether pull parsing is requested.
b4_define_flag_if([pure])	        # Whether the interface is pure.
b4_define_flag_if([push])	        # Whether push parsing is requested.
b4_define_flag_if([use_push_for_pull])  # Whether push parsing should be used
                                        # in place of pull parsing (where
                                        # available) for the sake of the test
                                        # suite.
b4_define_flag_if([yacc])	        # Whether POSIX Yacc is emulated.


## ------------------------- ##
## Assigning token numbers.  ##
## ------------------------- ##


## ----------- ##
## Synclines.  ##
## ----------- ##

# b4_basename(NAME)
# -----------------
# Similar to POSIX basename; the differences don't matter here.
# Beware that NAME is not evaluated.
m4_define([b4_basename],
[m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])


# b4_syncline(LINE, FILE)
# -----------------------
m4_define([b4_syncline],
[b4_flag_if([synclines], [
b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
b4_sync_start([$1], [$2])])])

m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])

# b4_user_code(USER-CODE)
# -----------------------
# Emit code from the user, ending it with synclines.
m4_define([b4_user_code],
[$1
b4_syncline([@oline@], [@ofile@])])


# b4_define_user_code(MACRO)
# --------------------------
# From b4_MACRO, build b4_user_MACRO that includes the synclines.
m4_define([b4_define_user_code],
[m4_define([b4_user_$1],
[b4_user_code([b4_$1])])])


# b4_user_actions
# b4_user_initial_action
# b4_user_post_prologue
# b4_user_pre_prologue
# b4_user_stype
# ----------------------
# Macros that issue user code, ending with synclines.
b4_define_user_code([actions])
b4_define_user_code([initial_action])
b4_define_user_code([post_prologue])
b4_define_user_code([pre_prologue])
b4_define_user_code([stype])


# b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
# --------------------------------------------------------
# Warn if any name of type WHAT is used by the user (as recorded in USER-LIST)
# but is not used by Bison (as recorded by macros in the namespace
# BISON-NAMESPACE).
#
# USER-LIST must expand to a list specifying all grammar occurrences of all
# names of type WHAT.   Each item in the list must be a triplet specifying one
# occurrence: name, start boundary, and end boundary.  Empty string names are
# fine.  An empty list is fine.
#
# For example, to define b4_foo_user_names to be used for USER-LIST with three
# name occurrences and with correct quoting:
#
#   m4_define([b4_foo_user_names],
#             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
#               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
#               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
#
# The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
# is used by Bison (in the front-end or in the skeleton).  Empty string names
# are fine, but it would be ugly for Bison to actually use one.
#
# For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
# the names bar and baz are used by Bison:
#
#   m4_define([b4_foo_bison_names(bar)])
#   m4_define([b4_foo_bison_names(baz)])
#
# To invoke b4_check_user_names with TYPE foo, with USER-LIST
# b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
# quoting:
#
#   b4_check_user_names([[foo]], [b4_foo_user_names],
#                       [[b4_foo_bison_names]])
m4_define([b4_check_user_names],
[m4_foreach([b4_occurrence], $2,
[m4_pushdef([b4_occurrence], b4_occurrence)dnl
m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
m4_ifndef($3[(]m4_quote(b4_user_name)[)],
          [b4_warn_at([b4_start], [b4_end],
                      [[%s `%s' is not used]],
                      [$1], [b4_user_name])])[]dnl
m4_popdef([b4_occurrence])dnl
m4_popdef([b4_user_name])dnl
m4_popdef([b4_start])dnl
m4_popdef([b4_end])dnl
])])

# b4_percent_define_get(VARIABLE)
# -------------------------------
# Mimic muscle_percent_define_get in ../src/muscle_tab.h exactly.  That is, if
# the %define variable VARIABLE is defined, emit its value.  Also, record
# Bison's usage of VARIABLE by defining
# b4_percent_define_bison_variables(VARIABLE).
#
# For example:
#
#   b4_percent_define_get([[foo]])
m4_define([b4_percent_define_get],
[m4_define([b4_percent_define_bison_variables(]$1[)])dnl
m4_ifdef([b4_percent_define(]$1[)], [m4_indir([b4_percent_define(]$1[)])])])

# b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
# ------------------------------------------------------
# Mimic muscle_percent_define_ifdef in ../src/muscle_tab.h exactly.  That is,
# if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
# IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
# b4_percent_define_bison_variables(VARIABLE).
#
# For example:
#
#   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
m4_define([b4_percent_define_ifdef],
[m4_ifdef([b4_percent_define(]$1[)],
	  [m4_define([b4_percent_define_bison_variables(]$1[)])$2],
	  [$3])])

# b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
# --------------------------------------------------------
# Mimic muscle_percent_define_flag_if in ../src/muscle_tab.h exactly.  That is,
# if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
# If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
# (a Bison or skeleton error since the default value should have been set
# already) or defined to any other value (possibly a user error).  Also, record
# Bison's usage of VARIABLE by defining
# b4_percent_define_bison_variables(VARIABLE).
#
# For example:
#
#   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
m4_define([b4_percent_define_flag_if],
[b4_percent_define_ifdef([$1],
  [m4_case(b4_percent_define_get([$1]),
           [], [$2], [true], [$2], [false], [$3],
           [m4_expand_once([dnl
             m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
             b4_complain_at(b4_loc,
                            [[invalid value for %%define boolean variable `%s']],
                            [$1])dnl
             m4_popdef([b4_loc])],
             [[b4_percent_define_flag_if($1)]])])],
  [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_flag_if]], [$1])])])

# b4_percent_define_default(VARIABLE, DEFAULT)
# --------------------------------------------
# Mimic muscle_percent_define_default in ../src/muscle_tab.h exactly.  That is,
# if the %define variable VARIABLE is undefined, set its value to DEFAULT.
# Don't record this as a Bison usage of VARIABLE as there's no reason to
# suspect that the value has yet influenced the output.
#
# For example:
#
#   b4_percent_define_default([[foo]], [[default value]])
m4_define([b4_percent_define_default],
[m4_ifndef([b4_percent_define(]$1[)],
           [m4_define([b4_percent_define(]$1[)], [$2])dnl
            m4_define([b4_percent_define_loc(]$1[)],
                      [[[[[Bison:b4_percent_define_default]:0.0]], [[[Bison:b4_percent_define_default]:0.0]]]])])])

# b4_percent_code_get([QUALIFIER])
# --------------------------------
# If any %code blocks for QUALIFIER are defined, emit them beginning with a
# comment and ending with synclines and a newline.  If QUALIFIER is not
# specified or empty, do this for the unqualified %code blocks.  Also, record
# Bison's usage of QUALIFIER (if specified) by defining
# b4_percent_code_bison_qualifiers(QUALIFIER).
#
# For example, to emit any unqualified %code blocks followed by any %code
# blocks for the qualifier foo:
#
#   b4_percent_code_get
#   b4_percent_code_get([[foo]])
m4_define([b4_percent_code_get],
[m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
m4_ifdef(b4_macro_name,
[b4_comment([m4_if([$#], [0], [[Unqualified %code]],
                   [[%code "]$1["]])[ blocks.]])
b4_user_code([m4_indir(b4_macro_name)])
])dnl
m4_popdef([b4_macro_name])])

# b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
# -----------------------------------------------------
# If any %code blocks for QUALIFIER (or unqualified %code blocks if
# QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
# Also, record Bison's usage of QUALIFIER (if specified) by defining
# b4_percent_code_bison_qualifiers(QUALIFIER).
m4_define([b4_percent_code_ifdef],
[m4_ifdef([b4_percent_code(]$1[)],
          [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
	  [$3])])


## ----------------------------------------------------------- ##
## After processing the skeletons, check that all the user's   ##
## %define variables and %code qualifiers were used by Bison.  ##
## ----------------------------------------------------------- ##

m4_define([b4_check_user_names_wrap],
[m4_ifdef([b4_percent_]$1[_user_]$2[s],
          [b4_check_user_names([[%]$1 $2],
                               [b4_percent_]$1[_user_]$2[s],
                               [[b4_percent_]$1[_bison_]$2[s]])])])

m4_wrap([
b4_check_user_names_wrap([[define]], [[variable]])
b4_check_user_names_wrap([[code]], [[qualifier]])
])
Commit	Line	Data
08af01c2	1	-- Autoconf --
90b9908d PB	2
90b9908d PB	3	# Language-independent M4 Macros for Bison.
945e396c	4	# Copyright (C) 2002, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
90b9908d PB	5
	6	# This program is free software; you can redistribute it and/or modify
	7	# it under the terms of the GNU General Public License as published by
	8	# the Free Software Foundation; either version 2 of the License, or
	9	# (at your option) any later version.
	10
	11	# This program is distributed in the hope that it will be useful,
	12	# but WITHOUT ANY WARRANTY; without even the implied warranty of
	13	# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	14	# GNU General Public License for more details.
	15
	16	# You should have received a copy of the GNU General Public License
	17	# along with this program; if not, write to the Free Software
	18	# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
	19	# 02110-1301 USA
	20
	21
	22	## ---------------- ##
	23	## Identification. ##
	24	## ---------------- ##
	25
	26	# b4_copyright(TITLE, YEARS)
	27	# --------------------------
	28	m4_define([b4_copyright],
	29	[b4_comment([A Bison parser, made by GNU Bison b4_version.])
	30
	31	b4_comment([$1
	32
	33	m4_text_wrap([Copyright (C) $2 Free Software Foundation, Inc.], [ ])
	34
	35	This program is free software; you can redistribute it and/or modify
	36	it under the terms of the GNU General Public License as published by
	37	the Free Software Foundation; either version 2, or (at your option)
	38	any later version.
	39
	40	This program is distributed in the hope that it will be useful,
	41	but WITHOUT ANY WARRANTY; without even the implied warranty of
	42	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	43	GNU General Public License for more details.
	44
	45	You should have received a copy of the GNU General Public License
	46	along with this program; if not, write to the Free Software
	47	Foundation, Inc., 51 Franklin Street, Fifth Floor,
	48	Boston, MA 02110-1301, USA.])
	49
	50	b4_comment([As a special exception, you may create a larger work that contains
	51	part or all of the Bison parser skeleton and distribute that work
	52	under terms of your choice, so long as that work isn't itself a
	53	parser generator using the skeleton or a modified version thereof
	54	as a parser skeleton. Alternatively, if you modify or redistribute
	55	the parser skeleton itself, you may (at your option) remove this
	56	special exception, which will cause the skeleton and the resulting
	57	Bison output files to be licensed under the GNU General Public
	58	License without this special exception.
	59
	60	This special exception was added by the Free Software Foundation in
	61	version 2.2 of Bison.])])
	62
	63
08af01c2 JD	64	## ---------------- ##
	65	## Error handling. ##
	66	## ---------------- ##
	67
	68	# b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
7eb8a0bc	69	# -------------------------------------------
08af01c2 JD	70	# Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
	71	m4_define([b4_error],
	72	[m4_divert_push(0)[@]$1[(]$2[]m4_if([$#], [2], [],
	73	[m4_foreach([b4_arg],
1c7b7e1d	74	m4_dquote(m4_shift(m4_shift($@))),
08af01c2 JD	75	[[@,]b4_arg])])[@)]m4_divert_pop(0)])
08af01c2 JD	76
3fc65ead	77	# b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
7eb8a0bc	78	# ----------------------------------------------------------
3fc65ead JD	79	# Write @KIND(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
	80	m4_define([b4_error_at],
	81	[m4_divert_push(0)[@]$1[_at(]$2[@,]$3[@,]$4[]m4_if([$#], [4], [],
	82	[m4_foreach([b4_arg],
	83	m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
	84	[[@,]b4_arg])])[@)]m4_divert_pop(0)])
	85
08af01c2	86	# b4_warn(FORMAT, [ARG1], [ARG2], ...)
7eb8a0bc	87	# ------------------------------------
08af01c2 JD	88	# Write @warn(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
	89	#
	90	# As a simple test suite, this:
	91	#
	92	# m4_define([asdf], [ASDF])
	93	# m4_define([fsa], [FSA])
	94	# m4_define([fdsa], [FDSA])
	95	# b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
	96	# m4_divert(0)
	97	# b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
	98	# m4_divert(0)
	99	# b4_warn([asdf), asdf], [fsa), fsa], [fdsa), fdsa])
	100	# m4_divert(0)
08af01c2 JD	101	# b4_warn()
	102	# m4_divert(0)
	103	# b4_warn(1)
	104	# m4_divert(0)
	105	# b4_warn(1, 2)
	106	#
	107	# Should produce this:
	108	#
	109	# @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
	110	# @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
	111	# @warn(ASDF), ASDF@,FSA), FSA@,FDSA), FDSA@)
	112	# @warn(@)
08af01c2 JD	113	# @warn(1@)
	114	# @warn(1@,2@)
	115	m4_define([b4_warn],
	116	[b4_error([[warn]], $@)])
	117
3fc65ead	118	# b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
7eb8a0bc	119	# ---------------------------------------------------
3fc65ead JD	120	# Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
	121	m4_define([b4_warn_at],
	122	[b4_error_at([[warn]], $@)])
	123
08af01c2	124	# b4_complain(FORMAT, [ARG1], [ARG2], ...)
7eb8a0bc	125	# ----------------------------------------
08af01c2 JD	126	# Write @complain(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
	127	#
	128	# See the test suite for b4_warn above.
	129	m4_define([b4_complain],
	130	[b4_error([[complain]], $@)])
	131
3fc65ead	132	# b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
7eb8a0bc	133	# -------------------------------------------------------
3fc65ead JD	134	# Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
	135	m4_define([b4_complain_at],
	136	[b4_error_at([[complain]], $@)])
	137
08af01c2	138	# b4_fatal(FORMAT, [ARG1], [ARG2], ...)
7eb8a0bc	139	# -------------------------------------
08af01c2 JD	140	# Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
	141	#
	142	# See the test suite for b4_warn above.
	143	m4_define([b4_fatal],
	144	[b4_error([[fatal]], $@)])
	145
3fc65ead	146	# b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
7eb8a0bc	147	# ----------------------------------------------------
3fc65ead JD	148	# Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to diversion 0.
	149	m4_define([b4_fatal_at],
	150	[b4_error_at([[fatal]], $@)])
	151
08af01c2	152
90b9908d PB	153	## ---------------- ##
	154	## Default values. ##
	155	## ---------------- ##
	156
	157	# m4_define_default([b4_lex_param], []) dnl breaks other skeletons
7ecec4dd JD	158	m4_define_default([b4_pre_prologue], [])
7ecec4dd JD	159	m4_define_default([b4_post_prologue], [])
90b9908d PB	160	m4_define_default([b4_epilogue], [])
	161	m4_define_default([b4_parse_param], [])
	162
	163	# The initial column and line.
	164	m4_define_default([b4_location_initial_column], [1])
	165	m4_define_default([b4_location_initial_line], [1])
	166
	167
	168	## ------------ ##
	169	## Data Types. ##
	170	## ------------ ##
	171
	172	# b4_ints_in(INT1, INT2, LOW, HIGH)
	173	# ---------------------------------
	174	# Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
	175	m4_define([b4_ints_in],
	176	[m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
	177
	178
	179
	180	## ------------------ ##
	181	## Decoding options. ##
	182	## ------------------ ##
	183
	184	# b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
	185	# -----------------------------------
	186	# Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
	187	m4_define([b4_flag_if],
	188	[m4_case(b4_$1_flag,
	189	[0], [$3],
	190	[1], [$2],
	191	[m4_fatal([invalid $1 value: ]$1)])])
	192
	193
	194	# b4_define_flag_if(FLAG)
	195	# -----------------------
	196	# Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
	197	# value of the Boolean FLAG.
	198	m4_define([b4_define_flag_if],
	199	[_b4_define_flag_if($[1], $[2], [$1])])
	200
	201	# _b4_define_flag_if($1, $2, FLAG)
	202	# --------------------------------
	203	# This macro works around the impossibility to define macros
	204	# inside macros, because issuing `[$1]' is not possible in M4 :(.
	205	# This sucks hard, GNU M4 should really provide M5 like $$1.
	206	m4_define([_b4_define_flag_if],
	207	[m4_if([$1$2], $[1]$[2], [],
	208	[m4_fatal([$0: Invalid arguments: $@])])dnl
	209	m4_define([b4_$3_if],
	210	[b4_flag_if([$3], [$1], [$2])])])
	211
	212
	213	# b4_FLAG_if(IF-TRUE, IF-FALSE)
	214	# -----------------------------
	215	# Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
	216	b4_define_flag_if([defines]) # Whether headers are requested.
	217	b4_define_flag_if([error_verbose]) # Whether error are verbose.
	218	b4_define_flag_if([glr]) # Whether a GLR parser is requested.
	219	b4_define_flag_if([locations]) # Whether locations are tracked.
	220	b4_define_flag_if([nondeterministic]) # Whether conflicts should be handled.
7172e23e	221	b4_define_flag_if([pull]) # Whether pull parsing is requested.
90b9908d	222	b4_define_flag_if([pure]) # Whether the interface is pure.
7172e23e	223	b4_define_flag_if([push]) # Whether push parsing is requested.
945e396c JD	224	b4_define_flag_if([use_push_for_pull]) # Whether push parsing should be used
	225	# in place of pull parsing (where
	226	# available) for the sake of the test
	227	# suite.
90b9908d PB	228	b4_define_flag_if([yacc]) # Whether POSIX Yacc is emulated.
	229
	230
	231	## ------------------------- ##
	232	## Assigning token numbers. ##
	233	## ------------------------- ##
	234
	235
	236	## ----------- ##
	237	## Synclines. ##
	238	## ----------- ##
	239
	240	# b4_basename(NAME)
	241	# -----------------
	242	# Similar to POSIX basename; the differences don't matter here.
	243	# Beware that NAME is not evaluated.
	244	m4_define([b4_basename],
	245	[m4_bpatsubst([$1], [^./\([^/]+\)/$], [\1])])
	246
	247
	248	# b4_syncline(LINE, FILE)
	249	# -----------------------
	250	m4_define([b4_syncline],
	251	[b4_flag_if([synclines], [
	252	b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
	253	b4_sync_start([$1], [$2])])])
	254
	255	m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
	256	m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
	257
	258	# b4_user_code(USER-CODE)
	259	# -----------------------
	260	# Emit code from the user, ending it with synclines.
	261	m4_define([b4_user_code],
	262	[$1
	263	b4_syncline([@oline@], [@ofile@])])
	264
	265
	266	# b4_define_user_code(MACRO)
	267	# --------------------------
	268	# From b4_MACRO, build b4_user_MACRO that includes the synclines.
	269	m4_define([b4_define_user_code],
	270	[m4_define([b4_user_$1],
	271	[b4_user_code([b4_$1])])])
	272
	273
	274	# b4_user_actions
	275	# b4_user_initial_action
	276	# b4_user_post_prologue
136a0f76	277	# b4_user_pre_prologue
90b9908d PB	278	# b4_user_stype
	279	# ----------------------
	280	# Macros that issue user code, ending with synclines.
	281	b4_define_user_code([actions])
	282	b4_define_user_code([initial_action])
	283	b4_define_user_code([post_prologue])
136a0f76	284	b4_define_user_code([pre_prologue])
90b9908d PB	285	b4_define_user_code([stype])
90b9908d PB	286
1c7b7e1d	287
9611cfa2	288	# b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
a4e25e1d	289	# --------------------------------------------------------
6afc30cc	290	# Warn if any name of type WHAT is used by the user (as recorded in USER-LIST)
9611cfa2 JD	291	# but is not used by Bison (as recorded by macros in the namespace
9611cfa2 JD	292	# BISON-NAMESPACE).
7eb8a0bc	293	#
6afc30cc	294	# USER-LIST must expand to a list specifying all grammar occurrences of all
a4e25e1d	295	# names of type WHAT. Each item in the list must be a triplet specifying one
6afc30cc JD	296	# occurrence: name, start boundary, and end boundary. Empty string names are
6afc30cc JD	297	# fine. An empty list is fine.
7eb8a0bc	298	#
a4e25e1d	299	# For example, to define b4_foo_user_names to be used for USER-LIST with three
6afc30cc	300	# name occurrences and with correct quoting:
8e0a5e9e	301	#
a4e25e1d	302	# m4_define([b4_foo_user_names],
7eb8a0bc JD	303	# [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
	304	# [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
	305	# [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
1c7b7e1d	306	#
9611cfa2 JD	307	# The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
	308	# is used by Bison (in the front-end or in the skeleton). Empty string names
	309	# are fine, but it would be ugly for Bison to actually use one.
6afc30cc	310	#
9611cfa2 JD	311	# For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
9611cfa2 JD	312	# the names bar and baz are used by Bison:
1c7b7e1d	313	#
9611cfa2 JD	314	# m4_define([b4_foo_bison_names(bar)])
9611cfa2 JD	315	# m4_define([b4_foo_bison_names(baz)])
1c7b7e1d	316	#
6afc30cc	317	# To invoke b4_check_user_names with TYPE foo, with USER-LIST
9611cfa2 JD	318	# b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
9611cfa2 JD	319	# quoting:
1c7b7e1d	320	#
a4e25e1d	321	# b4_check_user_names([[foo]], [b4_foo_user_names],
9611cfa2	322	# [[b4_foo_bison_names]])
6afc30cc JD	323	m4_define([b4_check_user_names],
	324	[m4_foreach([b4_occurrence], $2,
	325	[m4_pushdef([b4_occurrence], b4_occurrence)dnl
	326	m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
	327	m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
	328	m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
a4e25e1d JD	329	m4_ifndef($3[(]m4_quote(b4_user_name)[)],
a4e25e1d JD	330	[b4_warn_at([b4_start], [b4_end],
5f340b48	331	[[%s `%s' is not used]],
a4e25e1d	332	[$1], [b4_user_name])])[]dnl
6afc30cc JD	333	m4_popdef([b4_occurrence])dnl
	334	m4_popdef([b4_user_name])dnl
	335	m4_popdef([b4_start])dnl
	336	m4_popdef([b4_end])dnl
	337	])])
	338
a4e25e1d JD	339	# b4_percent_define_get(VARIABLE)
a4e25e1d JD	340	# -------------------------------
f124d423 JD	341	# Mimic muscle_percent_define_get in ../src/muscle_tab.h exactly. That is, if
f124d423 JD	342	# the %define variable VARIABLE is defined, emit its value. Also, record
9611cfa2 JD	343	# Bison's usage of VARIABLE by defining
9611cfa2 JD	344	# b4_percent_define_bison_variables(VARIABLE).
a4e25e1d JD	345	#
	346	# For example:
	347	#
	348	# b4_percent_define_get([[foo]])
	349	m4_define([b4_percent_define_get],
9611cfa2	350	[m4_define([b4_percent_define_bison_variables(]$1[)])dnl
a4e25e1d JD	351	m4_ifdef([b4_percent_define(]$1[)], [m4_indir([b4_percent_define(]$1[)])])])
a4e25e1d JD	352
592d0b1e PB	353	# b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
592d0b1e PB	354	# ------------------------------------------------------
f124d423 JD	355	# Mimic muscle_percent_define_ifdef in ../src/muscle_tab.h exactly. That is,
f124d423 JD	356	# if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
9611cfa2 JD	357	# IF-FALSE. Also, record Bison's usage of VARIABLE by defining
	358	# b4_percent_define_bison_variables(VARIABLE).
	359	#
	360	# For example:
	361	#
	362	# b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
592d0b1e PB	363	m4_define([b4_percent_define_ifdef],
592d0b1e PB	364	[m4_ifdef([b4_percent_define(]$1[)],
9611cfa2	365	[m4_define([b4_percent_define_bison_variables(]$1[)])$2],
592d0b1e PB	366	[$3])])
	367
	368	# b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
	369	# --------------------------------------------------------
9611cfa2 JD	370	# Mimic muscle_percent_define_flag_if in ../src/muscle_tab.h exactly. That is,
	371	# if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
	372	# If it is defined to "false", expand IF-FALSE. Complain if it is undefined
	373	# (a Bison or skeleton error since the default value should have been set
	374	# already) or defined to any other value (possibly a user error). Also, record
	375	# Bison's usage of VARIABLE by defining
	376	# b4_percent_define_bison_variables(VARIABLE).
	377	#
	378	# For example:
	379	#
	380	# b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
592d0b1e PB	381	m4_define([b4_percent_define_flag_if],
592d0b1e PB	382	[b4_percent_define_ifdef([$1],
9611cfa2 JD	383	[m4_case(b4_percent_define_get([$1]),
	384	[], [$2], [true], [$2], [false], [$3],
	385	[m4_expand_once([dnl
	386	m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
	387	b4_complain_at(b4_loc,
	388	[[invalid value for %%define boolean variable `%s']],
	389	[$1])dnl
	390	m4_popdef([b4_loc])],
	391	[[b4_percent_define_flag_if($1)]])])],
	392	[b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_flag_if]], [$1])])])
592d0b1e	393
a4e25e1d JD	394	# b4_percent_define_default(VARIABLE, DEFAULT)
a4e25e1d JD	395	# --------------------------------------------
9611cfa2 JD	396	# Mimic muscle_percent_define_default in ../src/muscle_tab.h exactly. That is,
	397	# if the %define variable VARIABLE is undefined, set its value to DEFAULT.
	398	# Don't record this as a Bison usage of VARIABLE as there's no reason to
	399	# suspect that the value has yet influenced the output.
a4e25e1d JD	400	#
	401	# For example:
	402	#
	403	# b4_percent_define_default([[foo]], [[default value]])
	404	m4_define([b4_percent_define_default],
	405	[m4_ifndef([b4_percent_define(]$1[)],
9611cfa2 JD	406	[m4_define([b4_percent_define(]$1[)], [$2])dnl
	407	m4_define([b4_percent_define_loc(]$1[)],
	408	[[[[[Bison:b4_percent_define_default]:0.0]], [[[Bison:b4_percent_define_default]:0.0]]]])])])
6afc30cc	409
a4e25e1d	410	# b4_percent_code_get([QUALIFIER])
6afc30cc JD	411	# --------------------------------
	412	# If any %code blocks for QUALIFIER are defined, emit them beginning with a
	413	# comment and ending with synclines and a newline. If QUALIFIER is not
592d0b1e	414	# specified or empty, do this for the unqualified %code blocks. Also, record
9611cfa2 JD	415	# Bison's usage of QUALIFIER (if specified) by defining
9611cfa2 JD	416	# b4_percent_code_bison_qualifiers(QUALIFIER).
a4e25e1d JD	417	#
	418	# For example, to emit any unqualified %code blocks followed by any %code
	419	# blocks for the qualifier foo:
	420	#
	421	# b4_percent_code_get
	422	# b4_percent_code_get([[foo]])
	423	m4_define([b4_percent_code_get],
592d0b1e	424	[m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
9611cfa2	425	m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
6afc30cc JD	426	m4_ifdef(b4_macro_name,
	427	[b4_comment([m4_if([$#], [0], [[Unqualified %code]],
	428	[[%code "]$1["]])[ blocks.]])
a4e25e1d JD	429	b4_user_code([m4_indir(b4_macro_name)])
a4e25e1d JD	430	])dnl
6afc30cc JD	431	m4_popdef([b4_macro_name])])
6afc30cc JD	432
592d0b1e PB	433	# b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
	434	# -----------------------------------------------------
	435	# If any %code blocks for QUALIFIER (or unqualified %code blocks if
	436	# QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
9611cfa2 JD	437	# Also, record Bison's usage of QUALIFIER (if specified) by defining
9611cfa2 JD	438	# b4_percent_code_bison_qualifiers(QUALIFIER).
592d0b1e PB	439	m4_define([b4_percent_code_ifdef],
592d0b1e PB	440	[m4_ifdef([b4_percent_code(]$1[)],
9611cfa2	441	[m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
592d0b1e PB	442	[$3])])
592d0b1e PB	443
6afc30cc	444
9611cfa2 JD	445	## ----------------------------------------------------------- ##
	446	## After processing the skeletons, check that all the user's ##
	447	## %define variables and %code qualifiers were used by Bison. ##
	448	## ----------------------------------------------------------- ##
6afc30cc	449
a4e25e1d JD	450	m4_define([b4_check_user_names_wrap],
	451	[m4_ifdef([b4_percent_]$1[_user_]$2[s],
	452	[b4_check_user_names([[%]$1 $2],
	453	[b4_percent_]$1[_user_]$2[s],
9611cfa2	454	[[b4_percent_]$1[_bison_]$2[s]])])])
6afc30cc	455
a4e25e1d JD	456	m4_wrap([
	457	b4_check_user_names_wrap([[define]], [[variable]])
	458	b4_check_user_names_wrap([[code]], [[qualifier]])
6afc30cc	459	])