libkern/ppc/OSAtomic.s

   1 /*
   2  * Copyright (c) 2000 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23  /*
  24  * Copyright (c) 1997-1998 Apple Computer, Inc.
  25  *
  26  *
  27  * HISTORY
  28  *
  29  * sdouglas  22 Oct 97 - first checked in from DriverServices
  30  * sdouglas  28 Jul 98 - start IOKit
  31  */
  32
  33 #include <architecture/ppc/asm_help.h>
  34
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;
  37 ; ENTRY         functionName
  38 ;
  39 ; Assembly directives to begin an exported function.
  40 ;
  41 ; Takes: functionName - name of the exported function
  42 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  43
  44 .macro ENTRY
  45     .text
  46     .align      2
  47     .globl      $0
  48 $0:
  49 .endmacro
  50
  51 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  52
  53 /*
  54 int     OSCompareAndSwap( UInt32 oldVal, UInt32 newVal, UInt32 * addr )
  55     This is now an alias to hw_compare_and_store, see xnu/libkern/Makefile.
  56
  57 void *  OSDequeueAtomic(void ** inList, SInt32 inOffset)
  58     This is also aliased, to hw_dequeue_atomic.
  59
  60 void    OSEnqueueAtomic(void ** inList, void * inNewLink, SInt32 inOffset)
  61     This is aliased to hw_queue_atomic.
  62 */
  63
  64 /*
  65 Note:  We can not use the hw_atomic routines provided by osfmk/ppc as
  66 the return the result of the addition not the original value.
  67 */
  68 /*
  69 SInt32  OSDecrementAtomic(SInt32 * value)
  70 */
  71     ENTRY       _OSDecrementAtomic
  72     mr          r4, r3
  73     li          r3, -1
  74     b           _OSAddAtomic
  75
  76 /*
  77 SInt32  OSIncrementAtomic(SInt32 * value)
  78 */
  79
  80     .align      5
  81
  82     ENTRY       _OSIncrementAtomic
  83     mr          r4, r3
  84     li          r3, 1
  85
  86 /*
  87 SInt32  OSAddAtomic(SInt32 amount, SInt32 * value)
  88 */
  89
  90     ENTRY       _OSAddAtomic
  91
  92     mr          r5,r3           /* Save the increment */
  93 .L_AAretry:
  94     lwarx       r3, 0, r4       /* Grab the area value */
  95     add         r6, r3, r5      /* Add the value */
  96     stwcx.      r6, 0, r4       /* Try to save the new value */
  97     bne-        .L_AAretry      /* Didn't get it, try again... */
  98     blr                         /* Return the original value */