libsyscall/wrappers/mach_approximate_time.s

   1 /*
   2  * Copyright (c) 2003-2007 Apple Inc. All rights reserved.
   3  *
   4  * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. The rights granted to you under the License
  10  * may not be used to create, or enable the creation or redistribution of,
  11  * unlawful or unlicensed copies of an Apple operating system, or to
  12  * circumvent, violate, or enable the circumvention or violation of, any
  13  * terms of an Apple operating system software license agreement.
  14  *
  15  * Please obtain a copy of the License at
  16  * http://www.opensource.apple.com/apsl/ and read it before using this file.
  17  *
  18  * The Original Code and all software distributed under the License are
  19  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  20  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  21  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  22  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  23  * Please see the License for the specific language governing rights and
  24  * limitations under the License.
  25  *
  26  * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
  27  */
  28
  29 #include <sys/appleapiopts.h>
  30 #include <machine/cpu_capabilities.h>
  31
  32 #if defined(__arm__)
  33
  34         .text
  35         .align  2
  36         .globl  _mach_approximate_time
  37 _mach_approximate_time:
  38
  39         movw    r0, #((_COMM_PAGE_APPROX_TIME_SUPPORTED>>0)&0x0FFFF)
  40         movt    r0, #((_COMM_PAGE_APPROX_TIME_SUPPORTED>>16)&0x0FFFF)
  41         ldrb    r0, [r0]                // load COMM_PAGE_APPROX_TIME_SUPPORTED
  42         cmp     r0, #1                  // check if approx time is supported
  43
  44         bne      _mach_absolute_time    // if not supported, fall through to
  45                                         //   absolute_time
  46
  47         movw    r2, #((_COMM_PAGE_APPROX_TIME>>0)&0x0FFFF)
  48         movt    r2, #((_COMM_PAGE_APPROX_TIME>>16)&0x0FFFF)
  49
  50         // at this point, r2->COMM_PAGE_APPROX_TIME, which is a 64-bit value.
  51         // Since this is a 32-bit architecture, and the commpage is readonly,
  52         // there is no "guaranteed" atomic way to read all 64-bits with
  53         // hardware protection. Even the ldrd instruction is not guaranteed to
  54         // complete atomically. The solution is to use a 32-bit high/low/high
  55         // read with a consistency check on the high bits. To further
  56         // complicate things, reading the same location in memory back to back
  57         // could trigger a predictive read, which would defeat the purpose of
  58         // doing the consistency check so we insert a data memory barrier to
  59         // prevent this.
  60 _consistency_check:
  61         ldr     r1, [r2,#4]             // load high
  62         ldr     r0, [r2]                // load low
  63         dsb                             // avoid predictive reads that could
  64                                         //   be invalid if interrupted
  65         ldr     r3, [r2,#4]             // load high again
  66         cmp     r1, r3                  // check that high1 == high2
  67         bne     _consistency_check      // try again if not
  68         bx      lr
  69
  70 #elif defined(__i386__)
  71
  72         .text
  73         .align  4, 0x90
  74         .globl  _mach_approximate_time
  75 _mach_approximate_time:
  76         pushl   %ebp                            // push a frame
  77         movl    %esp, %ebp
  78         cmpb    $0, _COMM_PAGE_APPROX_TIME_SUPPORTED // check commpage
  79                                                 //   "is supported" flag.
  80         je      _approx_time_not_supported      // if zero, fall through to
  81                                                 //   absolute_time
  82         // note the comment above for 32-bit ARM applies equally to 32-bit i386.
  83         .align  4, 0x90
  84 _approx_time_consistency_check:
  85         movl    _COMM_PAGE_APPROX_TIME+4, %edx  // load high
  86         movl    _COMM_PAGE_APPROX_TIME, %eax    // load low
  87         lfence                                  // avoid predictive reads that
  88                                                 //   could be invalid if
  89                                                 //   interrupted
  90         cmpl    _COMM_PAGE_APPROX_TIME+4, %edx  // load high and check if equal
  91                                                 // to the first read
  92         jne     _approx_time_consistency_check  // if not, try again.
  93         popl    %ebp
  94         ret
  95
  96 _approx_time_not_supported:
  97         popl    %ebp
  98         jmp     _mach_absolute_time
  99
 100 #endif