libkern/i386/OSAtomic.s

   1 /*
   2  * Copyright (c) 2000 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. The rights granted to you under the License
  10  * may not be used to create, or enable the creation or redistribution of,
  11  * unlawful or unlicensed copies of an Apple operating system, or to
  12  * circumvent, violate, or enable the circumvention or violation of, any
  13  * terms of an Apple operating system software license agreement.
  14  *
  15  * Please obtain a copy of the License at
  16  * http://www.opensource.apple.com/apsl/ and read it before using this file.
  17  *
  18  * The Original Code and all software distributed under the License are
  19  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  20  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  21  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  22  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  23  * Please see the License for the specific language governing rights and
  24  * limitations under the License.
  25  *
  26  * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
  27  */
  28
  29 #;***************************************************************************
  30 #;* Boolean OSCompareAndSwap(SInt32 oldValue, SInt32 newValue, SInt32 *ptr) *
  31 #;***************************************************************************
  32
  33         .globl _OSCompareAndSwap
  34
  35 _OSCompareAndSwap:
  36         movl             4(%esp), %eax  #; oldValue
  37         movl             8(%esp), %edx  #; newValue
  38         movl            12(%esp), %ecx  #; ptr
  39         lock
  40         cmpxchgl        %edx, 0(%ecx)   #; CAS (eax is an implicit operand)
  41         sete            %al                     #; did CAS succeed? (TZ=1)
  42         movzbl          %al, %eax               #; clear out the high bytes
  43         ret
  44
  45 #;*****************************************************************************
  46 #;* Boolean OSCompareAndSwap64(SInt64 oldValue, SInt64 newValue, SInt64 *ptr) *
  47 #;*****************************************************************************
  48
  49         .globl _OSCompareAndSwap64
  50
  51 _OSCompareAndSwap64:
  52         pushl           %edi
  53         pushl           %ebx
  54
  55         movl             4+8(%esp), %eax        #; low 32-bits of oldValue
  56         movl             8+8(%esp), %edx        #; high 32-bits of oldValue
  57         movl            12+8(%esp), %ebx        #; low 32-bits of newValue
  58         movl            16+8(%esp), %ecx        #; high 32-bits of newValue
  59         movl            20+8(%esp), %edi        #; ptr
  60         lock
  61         cmpxchg8b       0(%edi)         #; CAS (eax:edx, ebx:ecx implicit)
  62         sete            %al                     #; did CAS succeed? (TZ=1)
  63         movzbl          %al, %eax               #; clear out the high bytes
  64
  65         popl            %ebx
  66         popl            %edi
  67         ret
  68
  69 #;*******************************************************
  70 #;* SInt64 OSAddAtomic64(SInt64 theAmount, SInt64 *ptr) *
  71 #;*******************************************************
  72
  73         .globl  _OSAddAtomic64
  74 _OSAddAtomic64:
  75         pushl           %edi
  76         pushl           %ebx
  77
  78         movl            12+8(%esp), %edi        #; ptr
  79         movl            0(%edi), %eax           #; load low 32-bits of *ptr
  80         movl            4(%edi), %edx           #; load high 32-bits of *ptr
  81 1:
  82         movl            %eax, %ebx
  83         movl            %edx, %ecx              #; ebx:ecx := *ptr
  84         addl            4+8(%esp), %ebx
  85         adcl            8+8(%esp), %ecx         #; ebx:ecx := *ptr + theAmount
  86         lock
  87         cmpxchg8b       0(%edi)         #; CAS (eax:edx, ebx:ecx implicit)
  88         jnz             1b              #; - failure: eax:edx re-loaded, retry
  89                                         #; - success: old value in eax:edx
  90         popl            %ebx
  91         popl            %edi
  92         ret
  93
  94 #;*******************************************************
  95 #; SInt32 OSAddAtomic(SInt32 delta, SInt32 *address)
  96 #;*******************************************************
  97
  98         .globl  _OSAddAtomic
  99 _OSAddAtomic:
 100         movl    4(%esp), %eax           #; Load addend
 101         movl    8(%esp), %ecx           #; Load address of operand
 102         lock
 103         xaddl   %eax, 0(%ecx)           #; Atomic exchange and add
 104         ret