osfmk/i386/cswitch.s

   1 /*
   2  * Copyright (c) 2000-2006 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. The rights granted to you under the License
  10  * may not be used to create, or enable the creation or redistribution of,
  11  * unlawful or unlicensed copies of an Apple operating system, or to
  12  * circumvent, violate, or enable the circumvention or violation of, any
  13  * terms of an Apple operating system software license agreement.
  14  *
  15  * Please obtain a copy of the License at
  16  * http://www.opensource.apple.com/apsl/ and read it before using this file.
  17  *
  18  * The Original Code and all software distributed under the License are
  19  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  20  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  21  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  22  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  23  * Please see the License for the specific language governing rights and
  24  * limitations under the License.
  25  *
  26  * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
  27  */
  28 /*
  29  * @OSF_COPYRIGHT@
  30  */
  31 /*
  32  * Mach Operating System
  33  * Copyright (c) 1991,1990 Carnegie Mellon University
  34  * All Rights Reserved.
  35  *
  36  * Permission to use, copy, modify and distribute this software and its
  37  * documentation is hereby granted, provided that both the copyright
  38  * notice and this permission notice appear in all copies of the
  39  * software, derivative works or modified versions, and any portions
  40  * thereof, and that both notices appear in supporting documentation.
  41  *
  42  * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
  43  * CONDITION.  CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR
  44  * ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
  45  *
  46  * Carnegie Mellon requests users of this software to return to
  47  *
  48  *  Software Distribution Coordinator  or  Software.Distribution@CS.CMU.EDU
  49  *  School of Computer Science
  50  *  Carnegie Mellon University
  51  *  Pittsburgh PA 15213-3890
  52  *
  53  * any improvements or extensions that they make and grant Carnegie Mellon
  54  * the rights to redistribute these changes.
  55  */
  56 /*
  57  */
  58
  59 #include <platforms.h>
  60
  61 #include <i386/asm.h>
  62 #include <i386/proc_reg.h>
  63 #include <i386/mp.h>
  64 #include <assym.s>
  65
  66
  67 #define CX(addr, reg)   addr(,reg,4)
  68
  69         .text
  70 /*
  71  * Context switch routines for i386.
  72  */
  73
  74 Entry(Load_context)
  75         movl    S_ARG0,%ecx                     /* get thread */
  76         movl    TH_KERNEL_STACK(%ecx),%ecx      /* get kernel stack */
  77         lea     -IKS_SIZE(%ecx),%edx
  78         add     EXT(kernel_stack_size),%edx             /* point to stack top */
  79         movl    %ecx,%gs:CPU_ACTIVE_STACK       /* store stack address */
  80         movl    %edx,%gs:CPU_KERNEL_STACK       /* store stack top */
  81
  82         movl    %edx,%esp
  83         movl    %edx,%ebp
  84
  85         subl    $12, %esp                       /* align stack */
  86         xorl    %eax,%eax                       /* return zero (no old thread) */
  87         pushl   %eax
  88         call    EXT(thread_continue)
  89
  90 /*
  91  *      This has to save registers only
  92  *      when there is no explicit continuation.
  93  */
  94
  95 Entry(Switch_context)
  96         popl    %eax                            /* pop return PC */
  97
  98         /* Test for a continuation and skip all state saving if so... */
  99         cmpl    $0,4(%esp)
 100         jne     5f
 101         movl    %gs:CPU_KERNEL_STACK,%ecx       /* get old kernel stack top */
 102         movl    %ebx,KSS_EBX(%ecx)              /* save registers */
 103         movl    %ebp,KSS_EBP(%ecx)
 104         movl    %edi,KSS_EDI(%ecx)
 105         movl    %esi,KSS_ESI(%ecx)
 106         movl    %eax,KSS_EIP(%ecx)              /* save return PC */
 107         movl    %esp,KSS_ESP(%ecx)              /* save SP */
 108 5:
 109         movl    0(%esp),%eax                    /* return old thread */
 110         movl    8(%esp),%ecx                    /* get new thread */
 111         movl    %ecx,%gs:CPU_ACTIVE_THREAD      /* new thread is active */
 112         movl    TH_KERNEL_STACK(%ecx),%ebx      /* get its kernel stack */
 113         lea     -IKS_SIZE(%ebx),%ecx
 114         add     EXT(kernel_stack_size),%ecx
 115                                                 /* point to stack top */
 116
 117         movl    %ebx,%gs:CPU_ACTIVE_STACK       /* set current stack */
 118         movl    %ecx,%gs:CPU_KERNEL_STACK       /* set stack top */
 119
 120
 121         movl    KSS_ESP(%ecx),%esp              /* switch stacks */
 122         movl    KSS_ESI(%ecx),%esi              /* restore registers */
 123         movl    KSS_EDI(%ecx),%edi
 124         movl    KSS_EBP(%ecx),%ebp
 125         movl    KSS_EBX(%ecx),%ebx
 126         jmp     *KSS_EIP(%ecx)                  /* return old thread */
 127
 128 Entry(Thread_continue)
 129         subl    $12, %esp                       /* align stack */
 130         pushl   %eax                            /* push the thread argument */
 131         xorl    %ebp,%ebp                       /* zero frame pointer */
 132         call    *%ebx                           /* call real continuation */
 133
 134 /*
 135  * thread_t Shutdown_context(thread_t thread,
 136  *                       void (*routine)(processor_t),
 137  *                       processor_t processor)
 138  *
 139  * saves the kernel context of the thread,
 140  * switches to the interrupt stack,
 141  * continues the thread (with thread_continue),
 142  * then runs routine on the interrupt stack.
 143  *
 144  */
 145 Entry(Shutdown_context)
 146         movl    %gs:CPU_KERNEL_STACK,%ecx /* get old kernel stack */
 147         movl    %ebx,KSS_EBX(%ecx)              /* save registers */
 148         movl    %ebp,KSS_EBP(%ecx)
 149         movl    %edi,KSS_EDI(%ecx)
 150         movl    %esi,KSS_ESI(%ecx)
 151         popl    KSS_EIP(%ecx)                   /* save return PC */
 152         movl    %esp,KSS_ESP(%ecx)              /* save SP */
 153
 154         movl    %gs:CPU_ACTIVE_STACK,%ecx       /* get old stack */
 155         movl    0(%esp),%eax                    /* get old thread */
 156         movl    %ecx,TH_KERNEL_STACK(%eax)      /* save old stack */
 157         movl    4(%esp),%ebx                    /* get routine to run next */
 158         movl    8(%esp),%esi                    /* get its argument */
 159
 160         movl    %gs:CPU_INT_STACK_TOP,%esp      /* switch to interrupt stack */
 161
 162         subl    $12, %esp                       /* align stack */
 163         pushl   %esi                            /* push argument */
 164         call    *%ebx                           /* call routine to run */
 165         hlt                                     /* (should never return) */