osfmk/i386/commpage/bzero_scalar.s

   1 /*
   2  * Copyright (c) 2003-2006 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. The rights granted to you under the License
  10  * may not be used to create, or enable the creation or redistribution of,
  11  * unlawful or unlicensed copies of an Apple operating system, or to
  12  * circumvent, violate, or enable the circumvention or violation of, any
  13  * terms of an Apple operating system software license agreement.
  14  *
  15  * Please obtain a copy of the License at
  16  * http://www.opensource.apple.com/apsl/ and read it before using this file.
  17  *
  18  * The Original Code and all software distributed under the License are
  19  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  20  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  21  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  22  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  23  * Please see the License for the specific language governing rights and
  24  * limitations under the License.
  25  *
  26  * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
  27  */
  28 /*
  29  * Copyright (c) 1993 Winning Strategies, Inc.
  30  * All rights reserved.
  31  *
  32  * Redistribution and use in source and binary forms, with or without
  33  * modification, are permitted provided that the following conditions
  34  * are met:
  35  * 1. Redistributions of source code must retain the above copyright
  36  *    notice, this list of conditions and the following disclaimer.
  37  * 2. Redistributions in binary form must reproduce the above copyright
  38  *    notice, this list of conditions and the following disclaimer in the
  39  *    documentation and/or other materials provided with the distribution.
  40  * 3. All advertising materials mentioning features or use of this software
  41  *    must display the following acknowledgement:
  42  *      This product includes software developed by Winning Strategies, Inc.
  43  * 4. The name of the author may not be used to endorse or promote products
  44  *    derived from this software withough specific prior written permission
  45  *
  46  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  47  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  48  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  49  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  50  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  51  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  52  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  53  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  54  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  55  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  56  *
  57  */
  58
  59 #include <sys/appleapiopts.h>
  60 #include <machine/cpu_capabilities.h>
  61 #include <machine/commpage.h>
  62
  63 /*
  64  * bzero (void *b, size_t len)
  65  *      write len zero bytes to the string b.
  66  *
  67  * Written by:
  68  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  69  */
  70
  71 .text
  72 .align 5, 0x90
  73 Lbzero_scalar:
  74         pushl   %ebp                    /* set up a frame for backtraces */
  75         movl    %esp,%ebp
  76         pushl   %edi
  77         pushl   %ebx
  78         movl    8(%ebp),%edi
  79         movl    12(%ebp),%ecx
  80
  81         cld                             /* set fill direction forward */
  82         xorl    %eax,%eax               /* set fill data to 0 */
  83
  84         /*
  85          * if the string is too short, it's really not worth the overhead
  86          * of aligning to word boundries, etc.  So we jump to a plain
  87          * unaligned set.
  88          */
  89         cmpl    $0x0f,%ecx
  90         jbe     L1
  91
  92         movl    %edi,%edx               /* compute misalignment */
  93         negl    %edx
  94         andl    $3,%edx
  95         movl    %ecx,%ebx
  96         subl    %edx,%ebx
  97
  98         movl    %edx,%ecx               /* zero until word aligned */
  99         rep
 100         stosb
 101
 102         movl    %ebx,%ecx               /* zero by words */
 103         shrl    $2,%ecx
 104         rep
 105         stosl
 106
 107         movl    %ebx,%ecx
 108         andl    $3,%ecx                 /* zero remainder by bytes */
 109 L1:     rep
 110         stosb
 111
 112         popl    %ebx
 113         popl    %edi
 114         popl    %ebp
 115         ret
 116
 117         COMMPAGE_DESCRIPTOR(bzero_scalar,_COMM_PAGE_BZERO,0,kHasSSE2)