osfmk/i386/cswitch.s

   1 /*
   2  * Copyright (c) 2000-2006 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. The rights granted to you under the License
  10  * may not be used to create, or enable the creation or redistribution of,
  11  * unlawful or unlicensed copies of an Apple operating system, or to
  12  * circumvent, violate, or enable the circumvention or violation of, any
  13  * terms of an Apple operating system software license agreement.
  14  *
  15  * Please obtain a copy of the License at
  16  * http://www.opensource.apple.com/apsl/ and read it before using this file.
  17  *
  18  * The Original Code and all software distributed under the License are
  19  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  20  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  21  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  22  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  23  * Please see the License for the specific language governing rights and
  24  * limitations under the License.
  25  *
  26  * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
  27  */
  28 /*
  29  * @OSF_COPYRIGHT@
  30  */
  31 /*
  32  * Mach Operating System
  33  * Copyright (c) 1991,1990 Carnegie Mellon University
  34  * All Rights Reserved.
  35  *
  36  * Permission to use, copy, modify and distribute this software and its
  37  * documentation is hereby granted, provided that both the copyright
  38  * notice and this permission notice appear in all copies of the
  39  * software, derivative works or modified versions, and any portions
  40  * thereof, and that both notices appear in supporting documentation.
  41  *
  42  * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
  43  * CONDITION.  CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR
  44  * ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
  45  *
  46  * Carnegie Mellon requests users of this software to return to
  47  *
  48  *  Software Distribution Coordinator  or  Software.Distribution@CS.CMU.EDU
  49  *  School of Computer Science
  50  *  Carnegie Mellon University
  51  *  Pittsburgh PA 15213-3890
  52  *
  53  * any improvements or extensions that they make and grant Carnegie Mellon
  54  * the rights to redistribute these changes.
  55  */
  56 /*
  57  */
  58
  59 #include <platforms.h>
  60
  61 #include <i386/asm.h>
  62 #include <i386/proc_reg.h>
  63 #include <assym.s>
  64
  65 #ifdef  SYMMETRY
  66 #include <sqt/asm_macros.h>
  67 #endif
  68
  69 #if     AT386
  70 #include <i386/mp.h>
  71 #endif  /* AT386 */
  72
  73 #define CX(addr, reg)   addr(,reg,4)
  74
  75         .text
  76 /*
  77  * Context switch routines for i386.
  78  */
  79
  80 Entry(Load_context)
  81         movl    S_ARG0,%ecx                     /* get thread */
  82         movl    TH_KERNEL_STACK(%ecx),%ecx      /* get kernel stack */
  83         lea     -IKS_SIZE-IEL_SIZE(%ecx),%edx
  84         add     EXT(kernel_stack_size),%edx             /* point to stack top */
  85         movl    %ecx,%gs:CPU_ACTIVE_STACK       /* store stack address */
  86         movl    %edx,%gs:CPU_KERNEL_STACK       /* store stack top */
  87
  88         movl    %edx,%esp
  89         movl    %edx,%ebp
  90
  91         subl    $12, %esp                       /* align stack */
  92         xorl    %eax,%eax                       /* return zero (no old thread) */
  93         pushl   %eax
  94         call    EXT(thread_continue)
  95
  96 /*
  97  *      This has to save registers only
  98  *      when there is no explicit continuation.
  99  */
 100
 101 Entry(Switch_context)
 102         popl    %eax                            /* pop return PC */
 103
 104         /* Test for a continuation and skip all state saving if so... */
 105         cmpl    $0,4(%esp)
 106         jne     5f
 107         movl    %gs:CPU_KERNEL_STACK,%ecx       /* get old kernel stack top */
 108         movl    %ebx,KSS_EBX(%ecx)              /* save registers */
 109         movl    %ebp,KSS_EBP(%ecx)
 110         movl    %edi,KSS_EDI(%ecx)
 111         movl    %esi,KSS_ESI(%ecx)
 112         movl    %eax,KSS_EIP(%ecx)              /* save return PC */
 113         movl    %esp,KSS_ESP(%ecx)              /* save SP */
 114 5:
 115         movl    0(%esp),%eax                    /* return old thread */
 116         movl    8(%esp),%ecx                    /* get new thread */
 117         movl    %ecx,%gs:CPU_ACTIVE_THREAD      /* new thread is active */
 118         movl    TH_KERNEL_STACK(%ecx),%ebx      /* get its kernel stack */
 119         lea     -IKS_SIZE-IEL_SIZE(%ebx),%ecx
 120         add     EXT(kernel_stack_size),%ecx
 121                                                 /* point to stack top */
 122
 123         movl    %ebx,%gs:CPU_ACTIVE_STACK       /* set current stack */
 124         movl    %ecx,%gs:CPU_KERNEL_STACK       /* set stack top */
 125
 126
 127         movl    KSS_ESP(%ecx),%esp              /* switch stacks */
 128         movl    KSS_ESI(%ecx),%esi              /* restore registers */
 129         movl    KSS_EDI(%ecx),%edi
 130         movl    KSS_EBP(%ecx),%ebp
 131         movl    KSS_EBX(%ecx),%ebx
 132         jmp     *KSS_EIP(%ecx)                  /* return old thread */
 133
 134 Entry(Thread_continue)
 135         subl    $12, %esp                       /* align stack */
 136         pushl   %eax                            /* push the thread argument */
 137         xorl    %ebp,%ebp                       /* zero frame pointer */
 138         call    *%ebx                           /* call real continuation */
 139
 140 /*
 141  * thread_t Shutdown_context(thread_t thread,
 142  *                       void (*routine)(processor_t),
 143  *                       processor_t processor)
 144  *
 145  * saves the kernel context of the thread,
 146  * switches to the interrupt stack,
 147  * continues the thread (with thread_continue),
 148  * then runs routine on the interrupt stack.
 149  *
 150  */
 151 Entry(Shutdown_context)
 152         movl    %gs:CPU_KERNEL_STACK,%ecx /* get old kernel stack */
 153         movl    %ebx,KSS_EBX(%ecx)              /* save registers */
 154         movl    %ebp,KSS_EBP(%ecx)
 155         movl    %edi,KSS_EDI(%ecx)
 156         movl    %esi,KSS_ESI(%ecx)
 157         popl    KSS_EIP(%ecx)                   /* save return PC */
 158         movl    %esp,KSS_ESP(%ecx)              /* save SP */
 159
 160         movl    %gs:CPU_ACTIVE_STACK,%ecx       /* get old stack */
 161         movl    0(%esp),%eax                    /* get old thread */
 162         movl    %ecx,TH_KERNEL_STACK(%eax)      /* save old stack */
 163         movl    4(%esp),%ebx                    /* get routine to run next */
 164         movl    8(%esp),%esi                    /* get its argument */
 165
 166         movl    %gs:CPU_INT_STACK_TOP,%esp      /* switch to interrupt stack */
 167
 168         subl    $12, %esp                       /* align stack */
 169         pushl   %esi                            /* push argument */
 170         call    *%ebx                           /* call routine to run */
 171         hlt                                     /* (should never return) */