osfmk/i386/commpage/commpage_mach_absolute_time.s

   1 /*
   2  * Copyright (c) 2003-2006 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. The rights granted to you under the License
  10  * may not be used to create, or enable the creation or redistribution of,
  11  * unlawful or unlicensed copies of an Apple operating system, or to
  12  * circumvent, violate, or enable the circumvention or violation of, any
  13  * terms of an Apple operating system software license agreement.
  14  *
  15  * Please obtain a copy of the License at
  16  * http://www.opensource.apple.com/apsl/ and read it before using this file.
  17  *
  18  * The Original Code and all software distributed under the License are
  19  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  20  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  21  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  22  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  23  * Please see the License for the specific language governing rights and
  24  * limitations under the License.
  25  *
  26  * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
  27  */
  28
  29 #include <sys/appleapiopts.h>
  30 #include <machine/cpu_capabilities.h>
  31 #include <machine/commpage.h>
  32 #include <i386/asm.h>
  33
  34 #include <assym.s>
  35
  36         .text
  37         .align  2, 0x90
  38
  39 Lmach_absolute_time:
  40         int     $0x3
  41         ret
  42
  43         COMMPAGE_DESCRIPTOR(mach_absolute_time,_COMM_PAGE_ABSOLUTE_TIME,0,0)
  44
  45 /* Nanotime is being moved out of the way of bcopy in the commpage.
  46  * First we put it in both places, old and new.  Then, when all the build
  47  * trains have rebuilt libSystem, we can remove the deprecated instance.
  48  */
  49
  50 /* return nanotime in %edx:%eax */
  51 Lold_nanotime:
  52 Lnanotime:
  53         push    %ebp
  54         mov     %esp,%ebp
  55         push    %esi
  56         push    %edi
  57         push    %ebx
  58
  59 0:
  60         mov     _COMM_PAGE_NT_TSC_BASE,%esi
  61         mov     _COMM_PAGE_NT_TSC_BASE+4,%edi
  62
  63         rdtsc
  64         sub     %esi,%eax
  65         sbb     %edi,%edx
  66
  67         mov     _COMM_PAGE_NT_SCALE,%ecx
  68
  69         mov     %edx,%ebx
  70         mull    %ecx
  71         mov     %ebx,%eax
  72         mov     %edx,%ebx
  73         mull    %ecx
  74         add     %ebx,%eax
  75         adc     $0,%edx
  76
  77         add     _COMM_PAGE_NT_NS_BASE,%eax
  78         adc     _COMM_PAGE_NT_NS_BASE+4,%edx
  79
  80         cmp     _COMM_PAGE_NT_TSC_BASE,%esi
  81         jne     0b
  82         cmp     _COMM_PAGE_NT_TSC_BASE+4,%edi
  83         jne     0b
  84
  85         pop     %ebx
  86         pop     %edi
  87         pop     %esi
  88         pop     %ebp
  89         ret
  90
  91         COMMPAGE_DESCRIPTOR(nanotime,_COMM_PAGE_NANOTIME,0,0)
  92         COMMPAGE_DESCRIPTOR(old_nanotime,_COMM_PAGE_OLD_NANOTIME,0,0)
  93
  94
  95 /* The 64-bit version.  We return the 64-bit nanotime in %rax,
  96  * and by convention we must preserve %r9, %r10, and %r11.
  97  */
  98         .text
  99         .align  2
 100         .code64
 101 Lold_nanotime_64:
 102 Lnanotime_64:                           // NB: must preserve r9, r10, and r11
 103         pushq   %rbp                    // set up a frame for backtraces
 104         movq    %rsp,%rbp
 105         movq    $_COMM_PAGE_32_TO_64(_COMM_PAGE_NT_TSC_BASE),%rsi
 106 1:
 107         movq    _NT_TSC_BASE(%rsi),%r8  // r8  := base_tsc
 108         rdtsc                           // edx:eax := tsc
 109         shlq    $32,%rdx                // rax := ((edx << 32) | eax), ie 64-bit tsc
 110         orq     %rdx,%rax
 111         subq    %r8, %rax               // rax := (tsc - base_tsc)
 112         movl    _NT_SCALE(%rsi),%ecx
 113         mulq    %rcx                    // rdx:rax := (tsc - base_tsc) * scale
 114         shrdq   $32,%rdx,%rax           // _COMM_PAGE_NT_SHIFT is always 32
 115         addq    _NT_NS_BASE(%rsi),%rax  // (((tsc - base_tsc) * scale) >> 32) + ns_base
 116
 117         cmpq    _NT_TSC_BASE(%rsi),%r8  // did the data change during computation?
 118         jne     1b
 119         popq    %rbp
 120         ret
 121
 122         COMMPAGE_DESCRIPTOR(nanotime_64,_COMM_PAGE_NANOTIME,0,0)
 123         COMMPAGE_DESCRIPTOR(old_nanotime_64,_COMM_PAGE_OLD_NANOTIME,0,0)