osfmk/arm64/cswitch.s

   1 /*
   2  * Copyright (c) 2007 Apple Inc. All rights reserved.
   3  *
   4  * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. The rights granted to you under the License
  10  * may not be used to create, or enable the creation or redistribution of,
  11  * unlawful or unlicensed copies of an Apple operating system, or to
  12  * circumvent, violate, or enable the circumvention or violation of, any
  13  * terms of an Apple operating system software license agreement.
  14  *
  15  * Please obtain a copy of the License at
  16  * http://www.opensource.apple.com/apsl/ and read it before using this file.
  17  *
  18  * The Original Code and all software distributed under the License are
  19  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  20  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  21  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  22  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  23  * Please see the License for the specific language governing rights and
  24  * limitations under the License.
  25  *
  26  * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
  27  */
  28 #include <machine/asm.h>
  29 #include <arm64/machine_machdep.h>
  30 #include <arm64/machine_routines_asm.h>
  31 #include <arm64/proc_reg.h>
  32 #include "assym.s"
  33
  34 /*
  35  * save_general_registers
  36  *
  37  * Saves variable registers to kernel PCB.
  38  *   arg0 - thread_kernel_state pointer
  39  *   arg1 - Scratch register
  40  */
  41
  42 .macro  save_general_registers
  43 /* AAPCS-64 Page 14
  44  *
  45  * A subroutine invocation must preserve the contents of the registers r19-r29
  46  * and SP. We also save IP0 and IP1, as machine_idle uses IP0 for saving the LR.
  47  */
  48         stp             x16, x17, [$0, SS64_X16]
  49         stp             x19, x20, [$0, SS64_X19]
  50         stp             x21, x22, [$0, SS64_X21]
  51         stp             x23, x24, [$0, SS64_X23]
  52         stp             x25, x26, [$0, SS64_X25]
  53         stp             x27, x28, [$0, SS64_X27]
  54         stp             fp, lr, [$0, SS64_FP]
  55 #ifdef HAS_APPLE_PAC
  56         stp             x0, x1, [sp, #-16]!
  57         stp             x2, x3, [sp, #-16]!
  58         stp             x4, x5, [sp, #-16]!
  59
  60         /*
  61          * Arg0: The ARM context pointer
  62          * Arg1: PC value to sign
  63          * Arg2: CPSR value to sign
  64          * Arg3: LR to sign
  65          */
  66         mov             x0, $0
  67         ldr             x1, [x0, SS64_PC]
  68         ldr             w2, [x0, SS64_CPSR]
  69         mov             x3, lr
  70         mov             x4, x16
  71         mov             x5, x17
  72         bl              EXT(ml_sign_thread_state)
  73
  74         ldp             x4, x5, [sp], #16
  75         ldp             x2, x3, [sp], #16
  76         ldp             x0, x1, [sp], #16
  77         ldp             fp, lr, [$0, SS64_FP]
  78 #endif /* defined(HAS_APPLE_PAC) */
  79         mov             $1, sp
  80         str             $1, [$0, SS64_SP]
  81
  82 /* AAPCS-64 Page 14
  83  *
  84  * Registers d8-d15 (s8-s15) must be preserved by a callee across subroutine
  85  * calls; the remaining registers (v0-v7, v16-v31) do not need to be preserved
  86  * (or should be preserved by the caller).
  87  */
  88         str             d8,     [$0, NS64_D8]
  89         str             d9,     [$0, NS64_D9]
  90         str             d10,[$0, NS64_D10]
  91         str             d11,[$0, NS64_D11]
  92         str             d12,[$0, NS64_D12]
  93         str             d13,[$0, NS64_D13]
  94         str             d14,[$0, NS64_D14]
  95         str             d15,[$0, NS64_D15]
  96 .endmacro
  97
  98 /*
  99  * load_general_registers
 100  *
 101  * Loads variable registers from kernel PCB.
 102  *   arg0 - thread_kernel_state pointer
 103  *   arg1 - Scratch register
 104  */
 105 .macro  load_general_registers
 106         mov             x20, x0
 107         mov             x21, x1
 108         mov             x22, x2
 109
 110         mov             x0, $0
 111         AUTH_THREAD_STATE_IN_X0 x23, x24, x25, x26, x27
 112
 113         mov             x0, x20
 114         mov             x1, x21
 115         mov             x2, x22
 116
 117         // Skip x16, x17 - already loaded + authed by AUTH_THREAD_STATE_IN_X0
 118         ldp             x19, x20, [$0, SS64_X19]
 119         ldp             x21, x22, [$0, SS64_X21]
 120         ldp             x23, x24, [$0, SS64_X23]
 121         ldp             x25, x26, [$0, SS64_X25]
 122         ldp             x27, x28, [$0, SS64_X27]
 123         ldr             fp, [$0, SS64_FP]
 124         // Skip lr - already loaded + authed by AUTH_THREAD_STATE_IN_X0
 125         ldr             $1, [$0, SS64_SP]
 126         mov             sp, $1
 127
 128         ldr             d8,     [$0, NS64_D8]
 129         ldr             d9,     [$0, NS64_D9]
 130         ldr             d10,[$0, NS64_D10]
 131         ldr             d11,[$0, NS64_D11]
 132         ldr             d12,[$0, NS64_D12]
 133         ldr             d13,[$0, NS64_D13]
 134         ldr             d14,[$0, NS64_D14]
 135         ldr             d15,[$0, NS64_D15]
 136 .endmacro
 137
 138
 139 /*
 140  * set_thread_registers
 141  *
 142  * Updates thread registers during context switch
 143  *  arg0 - New thread pointer
 144  *  arg1 - Scratch register
 145  *  arg2 - Scratch register
 146  */
 147 .macro  set_thread_registers
 148         msr             TPIDR_EL1, $0                                           // Write new thread pointer to TPIDR_EL1
 149         ldr             $1, [$0, TH_CTH_SELF]                           // Get cthread pointer
 150         mrs             $2, TPIDRRO_EL0                                         // Extract cpu number from TPIDRRO_EL0
 151         and             $2, $2, #(MACHDEP_CPUNUM_MASK)
 152         orr             $2, $1, $2                                                      // Save new cthread/cpu to TPIDRRO_EL0
 153         msr             TPIDRRO_EL0, $2
 154         msr             TPIDR_EL0, xzr
 155         /* ARM64_TODO Reserve x18 until we decide what to do with it */
 156         mov             x18, $1                                                         // ... and trash reserved x18
 157 .endmacro
 158
 159 #if defined(HAS_APPLE_PAC)
 160 /*
 161  * set_process_dependent_keys
 162  *
 163  * Updates process dependent keys during context switch if necessary
 164  *  Per CPU Data rop_key is initialized in arm_init() for bootstrap processor
 165  *  and in cpu_data_init for slave processors
 166  *
 167  *  arg0 - New thread pointer/Current CPU key
 168  *  arg1 - Scratch register: New Thread Key
 169  *  arg2 - Scratch register: Current CPU Data pointer
 170  */
 171 .macro set_process_dependent_keys
 172         ldr             $1, [$0, TH_ROP_PID]
 173         ldr             $2, [$0, ACT_CPUDATAP]
 174         ldr             $0, [$2, CPU_ROP_KEY]
 175         cmp             $0, $1
 176         b.eq    1f
 177         str             $1, [$2, CPU_ROP_KEY]
 178         msr             APIBKeyLo_EL1, $1
 179         add             $1, $1, #1
 180         msr             APIBKeyHi_EL1, $1
 181         add             $1, $1, #1
 182         msr             APDBKeyLo_EL1, $1
 183         add             $1, $1, #1
 184         msr             APDBKeyHi_EL1, $1
 185         isb     sy
 186 1:
 187 .endmacro
 188 #endif /* defined(HAS_APPLE_PAC) */
 189
 190 /*
 191  * void     machine_load_context(thread_t        thread)
 192  *
 193  * Load the context for the first thread to run on a
 194  * cpu, and go.
 195  */
 196         .text
 197         .align 2
 198         .globl  EXT(machine_load_context)
 199
 200 LEXT(machine_load_context)
 201         set_thread_registers    x0, x1, x2
 202         ldr             x1, [x0, TH_KSTACKPTR]                          // Get top of kernel stack
 203         load_general_registers  x1, x2
 204 #ifdef HAS_APPLE_PAC
 205         set_process_dependent_keys      x0, x1, x2
 206 #endif
 207         mov             x0, #0                                                          // Clear argument to thread_continue
 208         ret
 209
 210 /*
 211  *  typedef void (*thread_continue_t)(void *param, wait_result_t)
 212  *
 213  *      void Call_continuation( thread_continue_t continuation,
 214  *                                      void *param,
 215  *                                          wait_result_t wresult,
 216  *                          bool enable interrupts)
 217  */
 218         .text
 219         .align  5
 220         .globl  EXT(Call_continuation)
 221
 222 LEXT(Call_continuation)
 223         mrs             x4, TPIDR_EL1                                           // Get the current thread pointer
 224
 225         /* ARM64_TODO arm loads the kstack top instead of arg4. What should we use? */
 226         ldr             x5, [x4, TH_KSTACKPTR]                          // Get the top of the kernel stack
 227         mov             sp, x5                                                          // Set stack pointer
 228         mov             fp, #0                                                          // Clear the frame pointer
 229
 230 #if defined(HAS_APPLE_PAC)
 231         set_process_dependent_keys      x4, x5, x6
 232 #endif
 233
 234     mov x20, x0  //continuation
 235     mov x21, x1  //continuation parameter
 236     mov x22, x2  //wait result
 237
 238     cbz x3, 1f
 239     mov x0, #1
 240     bl EXT(ml_set_interrupts_enabled)
 241 1:
 242
 243         mov             x0, x21                                                         // Set the first parameter
 244         mov             x1, x22                                                         // Set the wait result arg
 245 #ifdef HAS_APPLE_PAC
 246         blraaz  x20                                                                     // Branch to the continuation
 247 #else
 248         blr             x20                                                                     // Branch to the continuation
 249 #endif
 250         mrs             x0, TPIDR_EL1                                           // Get the current thread pointer
 251         b               EXT(thread_terminate)                           // Kill the thread
 252
 253
 254 /*
 255  *      thread_t Switch_context(thread_t        old,
 256  *                              void            (*cont)(void),
 257  *                              thread_t        new)
 258  */
 259         .text
 260         .align 5
 261         .globl  EXT(Switch_context)
 262
 263 LEXT(Switch_context)
 264         cbnz    x1, Lswitch_threads                                     // Skip saving old state if blocking on continuation
 265         ldr             x3, [x0, TH_KSTACKPTR]                          // Get the old kernel stack top
 266         save_general_registers  x3, x4
 267 Lswitch_threads:
 268         set_thread_registers    x2, x3, x4
 269         ldr             x3, [x2, TH_KSTACKPTR]
 270         load_general_registers  x3, x4
 271 #if defined(HAS_APPLE_PAC)
 272         set_process_dependent_keys      x2, x3, x4
 273 #endif
 274         ret
 275
 276 /*
 277  *      thread_t Shutdown_context(void (*doshutdown)(processor_t), processor_t processor)
 278  *
 279  */
 280         .text
 281         .align 5
 282         .globl  EXT(Shutdown_context)
 283
 284 LEXT(Shutdown_context)
 285         mrs             x10, TPIDR_EL1                                                  // Get thread pointer
 286         ldr             x11, [x10, TH_KSTACKPTR]                                // Get the top of the kernel stack
 287         save_general_registers  x11, x12
 288         msr             DAIFSet, #(DAIFSC_FIQF | DAIFSC_IRQF)   // Disable interrupts
 289         ldr             x11, [x10, ACT_CPUDATAP]                                // Get current cpu
 290         ldr             x12, [x11, CPU_ISTACKPTR]                               // Switch to interrupt stack
 291         mov             sp, x12
 292         b               EXT(cpu_doshutdown)
 293
 294 /*
 295  *      thread_t Idle_context(void)
 296  *
 297  */
 298         .text
 299         .align 5
 300         .globl  EXT(Idle_context)
 301
 302 LEXT(Idle_context)
 303         mrs             x0, TPIDR_EL1                                           // Get thread pointer
 304         ldr             x1, [x0, TH_KSTACKPTR]                          // Get the top of the kernel stack
 305         save_general_registers  x1, x2
 306         ldr             x1, [x0, ACT_CPUDATAP]                          // Get current cpu
 307         ldr             x2, [x1, CPU_ISTACKPTR]                         // Switch to interrupt stack
 308         mov             sp, x2
 309         b               EXT(cpu_idle)
 310
 311 /*
 312  *      thread_t Idle_context(void)
 313  *
 314  */
 315         .text
 316         .align 5
 317         .globl  EXT(Idle_load_context)
 318
 319 LEXT(Idle_load_context)
 320         mrs             x0, TPIDR_EL1                                           // Get thread pointer
 321         ldr             x1, [x0, TH_KSTACKPTR]                          // Get the top of the kernel stack
 322         load_general_registers  x1, x2
 323 #ifdef HAS_APPLE_PAC
 324         set_process_dependent_keys      x0, x1, x2
 325 #endif
 326         ret
 327
 328         .align  2
 329         .globl  EXT(machine_set_current_thread)
 330 LEXT(machine_set_current_thread)
 331         set_thread_registers x0, x1, x2
 332         ret
 333
 334