osfmk/ppc/commpage/pthread.s

   1 /*
   2  * Copyright (c) 2003 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. The rights granted to you under the License
  10  * may not be used to create, or enable the creation or redistribution of,
  11  * unlawful or unlicensed copies of an Apple operating system, or to
  12  * circumvent, violate, or enable the circumvention or violation of, any
  13  * terms of an Apple operating system software license agreement.
  14  *
  15  * Please obtain a copy of the License at
  16  * http://www.opensource.apple.com/apsl/ and read it before using this file.
  17  *
  18  * The Original Code and all software distributed under the License are
  19  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  20  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  21  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  22  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  23  * Please see the License for the specific language governing rights and
  24  * limitations under the License.
  25  *
  26  * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
  27  */
  28
  29 #include <sys/appleapiopts.h>
  30 #include <ppc/asm.h>                                    // EXT, LEXT
  31 #include <machine/cpu_capabilities.h>
  32 #include <machine/commpage.h>
  33
  34         .text
  35         .align  2
  36
  37 #define USER_SPRG3      259             // user-mode-readable encoding for SPRG3
  38
  39
  40 // ***********************************************************
  41 // * P T H R E A D _ G E T S P E C I F I C _ S P R G 3 _ 3 2 *
  42 // ***********************************************************
  43 //
  44 // For processors with user-readable SPRG3, in 32-bit mode.   Called with:
  45 //              r3 = word number
  46 //              r4 = offset to thread specific data (_PTHREAD_TSD_OFFSET)
  47
  48 pthread_getspecific_sprg3_32:
  49         slwi    r5,r3,2                         // convert word# to byte offset
  50         mfspr   r3,USER_SPRG3           // get per-thread cookie
  51         add             r5,r5,r4                        // add in offset to first word
  52         lwzx    r3,r3,r5                        // get the thread-specific word
  53         blr
  54
  55     COMMPAGE_DESCRIPTOR(pthread_getspecific_sprg3_32,_COMM_PAGE_PTHREAD_GETSPECIFIC,k64Bit,0,kCommPage32)
  56
  57
  58 // ***********************************************************
  59 // * P T H R E A D _ G E T S P E C I F I C _ S P R G 3 _ 6 4 *
  60 // ***********************************************************
  61 //
  62 // For processors with user-readable SPRG3, in 64-bit mode.  This may not be used
  63 // because the 64-bit ABI uses r13 for the thread-local-data pointer.  Called with:
  64 //              r3 = word number
  65 //              r4 = offset to thread specific data (_PTHREAD_TSD_OFFSET)
  66
  67 pthread_getspecific_sprg3_64:
  68         sldi    r5,r3,3                         // convert double-word# to byte offset
  69         mfspr   r3,USER_SPRG3           // get per-thread cookie
  70         add             r5,r5,r4                        // add in offset to first word
  71         ldx             r3,r3,r5                        // get the thread-specific doubleword
  72         blr
  73
  74     COMMPAGE_DESCRIPTOR(pthread_getspecific_sprg3_64,_COMM_PAGE_PTHREAD_GETSPECIFIC,k64Bit,0,kCommPage64)
  75
  76
  77 // ***************************************
  78 // * P T H R E A D _ S E L F _ S P R G 3 *
  79 // ***************************************
  80 //
  81 // For processors with user-readable SPRG3.  Useable both in 32 and 64-bit modes.
  82
  83 pthread_self_sprg3:
  84         mfspr   r3,USER_SPRG3           // get per-thread cookie
  85         blr
  86
  87     COMMPAGE_DESCRIPTOR(pthread_self_sprg3,_COMM_PAGE_PTHREAD_SELF,k64Bit,0,kCommPageBoth)
  88
  89
  90 // *******************************************************
  91 // * P T H R E A D _ G E T S P E C I F I C _ U F T R A P *
  92 // *******************************************************
  93 //
  94 // For processors that use the Ultra-Fast-Trap to get the thread-specific ptr.
  95 // Called with:
  96 //              r3 = word number
  97 //              r4 = offset to thread specific data (_PTHREAD_TSD_OFFSET)
  98
  99 pthread_getspecific_uftrap:
 100         slwi    r5,r3,2                         // convert word# to byte offset
 101         li              r0,0x7FF2                       // magic "pthread_self" ultra-fast trap code
 102         sc
 103         add             r5,r5,r4                        // add in offset to first word
 104         lwzx    r3,r3,r5                        // get the thread-specific word
 105         blr
 106
 107     COMMPAGE_DESCRIPTOR(pthread_getspecific_uftrap,_COMM_PAGE_PTHREAD_GETSPECIFIC,0,k64Bit,kCommPage32)
 108
 109
 110 // *****************************************
 111 // * P T H R E A D _ S E L F _ U F T R A P *
 112 // *****************************************
 113 //
 114 // For processors that use the Ultra-Fast-Trap to get the thread-specific ptr.
 115
 116 pthread_self_uftrap:
 117         li              r0,0x7FF2                       // magic "pthread_self" ultra-fast trap code
 118         sc                                                      // get r3==TLDP
 119         blr
 120
 121     COMMPAGE_DESCRIPTOR(pthread_self_uftrap,_COMM_PAGE_PTHREAD_SELF,0,k64Bit,kCommPage32)