osfmk/x86_64/bcopy.s

   1 /*
   2  * Copyright (c) 2000 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. The rights granted to you under the License
  10  * may not be used to create, or enable the creation or redistribution of,
  11  * unlawful or unlicensed copies of an Apple operating system, or to
  12  * circumvent, violate, or enable the circumvention or violation of, any
  13  * terms of an Apple operating system software license agreement.
  14  *
  15  * Please obtain a copy of the License at
  16  * http://www.opensource.apple.com/apsl/ and read it before using this file.
  17  *
  18  * The Original Code and all software distributed under the License are
  19  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  20  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  21  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  22  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  23  * Please see the License for the specific language governing rights and
  24  * limitations under the License.
  25  *
  26  * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
  27  */
  28 /*
  29  * @OSF_COPYRIGHT@
  30  */
  31 /*
  32  * Mach Operating System
  33  * Copyright (c) 1991,1990 Carnegie Mellon University
  34  * All Rights Reserved.
  35  *
  36  * Permission to use, copy, modify and distribute this software and its
  37  * documentation is hereby granted, provided that both the copyright
  38  * notice and this permission notice appear in all copies of the
  39  * software, derivative works or modified versions, and any portions
  40  * thereof, and that both notices appear in supporting documentation.
  41  *
  42  * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
  43  * CONDITION.  CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND FOR
  44  * ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
  45  *
  46  * Carnegie Mellon requests users of this software to return to
  47  *
  48  *  Software Distribution Coordinator  or  Software.Distribution@CS.CMU.EDU
  49  *  School of Computer Science
  50  *  Carnegie Mellon University
  51  *  Pittsburgh PA 15213-3890
  52  *
  53  * any improvements or extensions that they make and grant Carnegie Mellon
  54  * the rights to redistribute these changes.
  55  */
  56 /*
  57  */
  58
  59 #include <i386/asm.h>
  60
  61 /* void *memcpy((void *) to, (const void *) from, (size_t) bcount) */
  62 /*                      rdi,                 rsi,             rdx   */
  63 /*
  64  * Note: memcpy does not support overlapping copies
  65  */
  66 ENTRY(memcpy)
  67         movq    %rdi, %rax                      /* return destination */
  68         movq    %rdx,%rcx
  69         shrq    $3,%rcx                         /* copy by 64-bit words */
  70         cld                                     /* copy forwards */
  71         rep
  72         movsq
  73         movq    %rdx,%rcx
  74         andq    $7,%rcx                         /* any bytes left? */
  75         rep
  76         movsb
  77         ret
  78
  79 /* void bcopy((const char *) from, (char *) to, (unsigned int) count) */
  80 /*                            rdi,         rsi,                  rdx  */
  81
  82 ENTRY(bcopy_no_overwrite)
  83         xchgq   %rsi,%rdi
  84         jmp     EXT(memcpy)
  85
  86 /*
  87  * bcopy(src, dst, cnt)
  88  *       rdi, rsi, rdx
  89  *  ws@tools.de     (Wolfgang Solfrank, TooLs GmbH) +49-228-985800
  90  */
  91 ENTRY(bcopy)
  92         xchgq   %rsi,%rdi
  93         movq    %rdx,%rcx
  94
  95         movq    %rdi,%rax
  96         subq    %rsi,%rax
  97         cmpq    %rcx,%rax                       /* overlapping && src < dst? */
  98         jb      1f
  99
 100         shrq    $3,%rcx                         /* copy by 64-bit words */
 101         cld                                     /* nope, copy forwards */
 102         rep
 103         movsq
 104         movq    %rdx,%rcx
 105         andq    $7,%rcx                         /* any bytes left? */
 106         rep
 107         movsb
 108         ret
 109
 110         /* ALIGN_TEXT */
 111 1:
 112         addq    %rcx,%rdi                       /* copy backwards */
 113         addq    %rcx,%rsi
 114         decq    %rdi
 115         decq    %rsi
 116         andq    $7,%rcx                         /* any fractional bytes? */
 117         std
 118         rep
 119         movsb
 120         movq    %rdx,%rcx                       /* copy remainder by 32-bit words */
 121         shrq    $3,%rcx
 122         subq    $7,%rsi
 123         subq    $7,%rdi
 124         rep
 125         movsq
 126         cld
 127         ret