src/setjmp/arm/setjmp.s

   1 /*
   2  * Copyright (c) 1999 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23 /*
  24  * Copyright (c) 1998-2008 Apple Inc. All rights reserved.
  25  *
  26  *      File: sys/arm/setjmp.s
  27  *
  28  *      Implements sigsetjmp(), setjmp(), _setjmp()
  29  *
  30  */
  31
  32 #include <architecture/arm/asm_help.h>
  33 #include "_setjmp.h"
  34
  35 /*
  36  * setjmp  routines
  37  */
  38
  39 /*      int sigsetjmp(sigjmp_buf env, int savemask); */
  40
  41 ENTRY_POINT(_sigsetjmp)
  42         str     r1, [ r0, #JMP_SIGFLAG ]        // save sigflag
  43         cmp     r1, #0                          // test if r1 is 0
  44         beq     L__exit                         // if r1 == 0 do _setjmp()
  45         // else *** fall through ***  to setjmp()
  46
  47 /*      int setjmp(jmp_buf env); */
  48
  49 ENTRY_POINT(_setjmp)
  50         str     lr, [ r0, #JMP_lr ]
  51         str     r8, [ r0, #JMP_r8 ]
  52         mov     r8, r0                          // r8 = jmp_buf
  53
  54         // Get previous sigmask
  55         mov     r0, #1                          // r0 = SIG_BLOCK
  56         mov     r1, #0                          // r1 = NULL
  57         add     r2, r8, #JMP_sigmask            // r2 = address to put the sigmask in
  58         CALL_EXTERNAL(_sigprocmask)             // sigprocmask(SIGBLOCK, NULL, &old_mask);
  59
  60         // Get altstack status
  61         sub     sp, sp, #32 // Put a stack_t on the stack
  62         mov     r0, #0                  // r0 = ss = NULL
  63         mov     r1, sp                  // r1 = oss = the place on the stack where stack_t is located
  64         CALL_EXTERNAL(___sigaltstack) // sigaltstack(NULL, oss)
  65         ldr r0, [sp, STACK_SSFLAGS] // r0 = ss flags from stack_t
  66         str     r0, [r8, JMP_sigonstack] // *(r8 + JMP_sigonstack) = r0
  67         add     sp, sp, #32     // reset sp
  68
  69         // Do the remaining register stuff
  70         mov     r0, r8                          // restore jmp_buf ptr
  71         ldr     r8, [ r0,  #JMP_r8 ]
  72         ldr     lr, [ r0,  #JMP_lr ]
  73 L__exit:
  74         BRANCH_EXTERNAL(__setjmp)