src/setjmp/i386/_setjmp.s

   1 /*
   2  * Copyright (c) 1999-2018 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23 /*
  24  * Copyright (c) 1995 NeXT Computer, Inc. All Rights Reserved
  25  *
  26  * HISTORY
  27  *  20-Apr-92    Bruce Martin (bmartin@next.com)
  28  *      Created from M68K sources.
  29  */
  30
  31 /*
  32  * C library -- _setjmp, _longjmp
  33  *
  34  *      _longjmp(a,v)
  35  * will generate a "return(v)" from
  36  * the last call to
  37  *      _setjmp(a)
  38  * by restoring registers from the stack,
  39  * The previous signal state is NOT restored.
  40  *
  41  */
  42
  43 #include <architecture/i386/asm_help.h>
  44 #include <os/tsd.h>
  45
  46 // The FP control word is actually two bytes, but there's no harm in
  47 // using four bytes for it and keeping the struct aligned.
  48 #define JB_FPCW         0
  49 #define JB_MASK         4
  50 #define JB_MXCSR        8
  51 #define JB_EBX          12
  52 #define JB_ONSTACK      16
  53 #define JB_EDX          20
  54 #define JB_EDI          24
  55 #define JB_ESI          28
  56 #define JB_EBP          32
  57 #define JB_ESP          36
  58 #define JB_SS           40
  59 #define JB_EFLAGS       44
  60 #define JB_EIP          48
  61 #define JB_CS           52
  62 #define JB_DS           56
  63 #define JB_ES           60
  64 #define JB_FS           64
  65 #define JB_GS           68
  66
  67 LEAF(__setjmp, 0)
  68         movl    4(%esp), %ecx           // jmp_buf (struct sigcontext *)
  69
  70         // Build the jmp_buf
  71         fnstcw  JB_FPCW(%ecx)                   // Save the FP control word
  72         stmxcsr JB_MXCSR(%ecx)                  // Save the MXCSR
  73         movl    %ebx, JB_EBX(%ecx)
  74         movl    %edi, JB_EDI(%ecx)
  75         movl    %esi, JB_ESI(%ecx)
  76         movl    %ebp, %eax
  77         _OS_PTR_MUNGE(%eax)
  78         movl    %eax, JB_EBP(%ecx)
  79
  80         // EIP is set to the frame return address value
  81         movl    (%esp), %eax
  82         _OS_PTR_MUNGE(%eax)
  83         movl    %eax, JB_EIP(%ecx)
  84         // ESP is set to the frame return address plus 4
  85         leal    4(%esp), %eax
  86         _OS_PTR_MUNGE(%eax)
  87         movl    %eax, JB_ESP(%ecx)
  88
  89         // return 0
  90         xorl    %eax, %eax
  91         ret
  92
  93
  94 LEAF(__longjmp, 0)
  95         fninit                                          // Clear all FP exceptions
  96         movl    4(%esp), %ecx           // jmp_buf (struct sigcontext *)
  97         movl    8(%esp), %edx           // return value
  98         xorl    %eax, %eax
  99         incl    %eax
 100         testl   %edx, %edx
 101         cmovnel %edx, %eax
 102
 103         // general registers
 104         movl    JB_EBX(%ecx), %ebx
 105         movl    JB_ESI(%ecx), %esi
 106         movl    JB_EDI(%ecx), %edi
 107         movl    JB_EBP(%ecx), %edx
 108         _OS_PTR_UNMUNGE(%edx)
 109         movl    %edx, %ebp
 110         movl    JB_ESP(%ecx), %edx
 111         _OS_PTR_UNMUNGE(%edx)
 112         movl    %edx, %esp
 113         movl    JB_EIP(%ecx), %edx
 114         _OS_PTR_UNMUNGE(%edx)
 115
 116         fldcw   JB_FPCW(%ecx)                   // Restore FP control word
 117         ldmxcsr JB_MXCSR(%ecx)                  // Restore the MXCSR
 118
 119         cld                                                             // Make sure DF is reset
 120         jmp             *%edx