i386/sys/_setjmp.s

   1 /*
   2  * Copyright (c) 1999 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23 /*
  24  * Copyright (c) 1995 NeXT Computer, Inc. All Rights Reserved
  25  *
  26  * HISTORY
  27  *  20-Apr-92    Bruce Martin (bmartin@next.com)
  28  *      Created from M68K sources.
  29  */
  30
  31 /*
  32  * C library -- _setjmp, _longjmp
  33  *
  34  *      _longjmp(a,v)
  35  * will generate a "return(v)" from
  36  * the last call to
  37  *      _setjmp(a)
  38  * by restoring registers from the stack,
  39  * The previous signal state is NOT restored.
  40  *
  41  */
  42
  43 #include <architecture/i386/asm_help.h>
  44
  45 #define JB_ONSTACK      0
  46 #define JB_MASK         4
  47 #define JB_EAX          8
  48 #define JB_EBX          12
  49 #define JB_ECX          16
  50 #define JB_EDX          20
  51 #define JB_EDI          24
  52 #define JB_ESI          28
  53 #define JB_EBP          32
  54 #define JB_ESP          36
  55 #define JB_SS           40
  56 #define JB_EFLAGS       44
  57 #define JB_EIP          48
  58 #define JB_CS           52
  59 #define JB_DS           56
  60 #define JB_ES           60
  61 #define JB_FS           64
  62 #define JB_GS           68
  63
  64 #define SAVE_SEG_REGS   1
  65
  66 LEAF(__setjmp, 0)
  67         movl    4(%esp), %ecx           // jmp_buf (struct sigcontext *)
  68
  69         // now build sigcontext
  70         movl    %ebx, JB_EBX(%ecx)
  71         movl    %edi, JB_EDI(%ecx)
  72         movl    %esi, JB_ESI(%ecx)
  73         movl    %ebp, JB_EBP(%ecx)
  74
  75         // EIP is set to the frame return address value
  76         movl    (%esp), %eax
  77         movl    %eax, JB_EIP(%ecx)
  78         // ESP is set to the frame return address plus 4
  79         movl    %esp, %eax
  80         addl    $4, %eax
  81         movl    %eax, JB_ESP(%ecx)
  82
  83 #if SAVE_SEG_REGS
  84         // segment registers
  85         mov     %ss, JB_SS(%ecx)
  86         mov     %cs, JB_CS(%ecx)
  87         mov     %ds, JB_DS(%ecx)
  88         mov     %es, JB_ES(%ecx)
  89         mov     %fs, JB_FS(%ecx)
  90         mov     %gs, JB_GS(%ecx)
  91 #endif
  92
  93         // save eflags - you can't use movl
  94         pushf
  95         popl    %eax
  96         movl    %eax, JB_EFLAGS(%ecx)
  97
  98         // return 0
  99         xorl    %eax, %eax
 100         ret
 101
 102
 103 LEAF(__longjmp, 0)
 104         subl    $2,%esp
 105         fnstcw  (%esp)                  // save FP control word
 106         fninit                          // reset FP coprocessor
 107         fldcw   (%esp)                  // restore FP control word
 108         addl    $2,%esp
 109
 110         movl    4(%esp), %ecx           // jmp_buf (struct sigcontext *)
 111         movl    8(%esp), %eax           // return value
 112         testl   %eax, %eax
 113         jnz 1f
 114         incl %eax
 115
 116         // general registers
 117 1:      movl    JB_EBX(%ecx), %ebx
 118         movl    JB_ESI(%ecx), %esi
 119         movl    JB_EDI(%ecx), %edi
 120         movl    JB_EBP(%ecx), %ebp
 121         movl    JB_ESP(%ecx), %esp
 122
 123 #if SAVE_SEG_REGS
 124         // segment registers
 125         mov     JB_SS(%ecx), %ss
 126         // mov  JB_CS(%ecx), %cs                // can't set cs?
 127         mov     JB_DS(%ecx), %ds
 128         mov     JB_ES(%ecx), %es
 129         mov     JB_FS(%ecx), %fs
 130         mov     JB_GS(%ecx), %gs
 131 #endif
 132
 133         // eflags
 134         pushl   JB_EFLAGS(%ecx)
 135         popf
 136
 137         jmp     *JB_EIP(%ecx)