i386/sys/i386_gettimeofday_asm.s

   1 /*
   2  * Copyright (c) 2003-2007 Apple Inc. All rights reserved.
   3  *
   4  * @APPLE_OSREFERENCE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. The rights granted to you under the License
  10  * may not be used to create, or enable the creation or redistribution of,
  11  * unlawful or unlicensed copies of an Apple operating system, or to
  12  * circumvent, violate, or enable the circumvention or violation of, any
  13  * terms of an Apple operating system software license agreement.
  14  *
  15  * Please obtain a copy of the License at
  16  * http://www.opensource.apple.com/apsl/ and read it before using this file.
  17  *
  18  * The Original Code and all software distributed under the License are
  19  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  20  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  21  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  22  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  23  * Please see the License for the specific language governing rights and
  24  * limitations under the License.
  25  *
  26  * @APPLE_OSREFERENCE_LICENSE_HEADER_END@
  27  */
  28
  29 #include <sys/appleapiopts.h>
  30 #include <machine/cpu_capabilities.h>
  31
  32 #define NSEC_PER_SEC    1000*1000*1000
  33 #define NSEC_PER_USEC   1000
  34
  35         .align  4
  36         .private_extern ___commpage_gettimeofday
  37 ___commpage_gettimeofday:
  38         push    %ebp
  39         mov     %esp,%ebp
  40         push    %esi
  41         push    %ebx
  42
  43 0:
  44         movl    _COMM_PAGE_GTOD_GENERATION,%esi /* get generation (0 if disabled) */
  45         testl   %esi,%esi                       /* disabled? */
  46         jz      4f
  47
  48         call    _mach_absolute_time             /* get nanotime in %edx:%eax */
  49
  50         sub     _COMM_PAGE_GTOD_NS_BASE,%eax
  51         sbb     _COMM_PAGE_GTOD_NS_BASE+4,%edx
  52         mov     _COMM_PAGE_GTOD_SEC_BASE,%ebx   /* load all the data before checking generation */
  53         mov     $ NSEC_PER_SEC,%ecx
  54
  55         cmpl    _COMM_PAGE_GTOD_GENERATION,%esi /* has time data changed out from under us? */
  56         jne     0b
  57
  58         div     %ecx
  59         add     %eax,%ebx
  60
  61         mov     $ NSEC_PER_USEC,%ecx
  62         mov     %edx,%eax
  63         xor     %edx,%edx
  64         div     %ecx
  65
  66         mov     8(%ebp),%ecx
  67         mov     %ebx,(%ecx)
  68         mov     %eax,4(%ecx)
  69         xor     %eax,%eax
  70
  71 3:
  72         pop     %ebx
  73         pop     %esi
  74         pop     %ebp
  75         ret
  76 4:                              /* fail */
  77         movl    $1,%eax
  78         jmp     3b