i386/sys/_setjmp.s

   1 /*
   2  * Copyright (c) 1999 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23 /*
  24  * Copyright (c) 1995 NeXT Computer, Inc. All Rights Reserved
  25  *
  26  * HISTORY
  27  *  20-Apr-92    Bruce Martin (bmartin@next.com)
  28  *      Created from M68K sources.
  29  */
  30
  31 /*
  32  * C library -- _setjmp, _longjmp
  33  *
  34  *      _longjmp(a,v)
  35  * will generate a "return(v)" from
  36  * the last call to
  37  *      _setjmp(a)
  38  * by restoring registers from the stack,
  39  * The previous signal state is NOT restored.
  40  *
  41  */
  42
  43 #include <architecture/i386/asm_help.h>
  44
  45 // The FP control word is actually two bytes, but there's no harm in
  46 // using four bytes for it and keeping the struct aligned.
  47 #define JB_FPCW         0
  48 #define JB_MASK         4
  49 #define JB_MXCSR        8
  50 #define JB_EBX          12
  51 #define JB_ONSTACK      16
  52 #define JB_EDX          20
  53 #define JB_EDI          24
  54 #define JB_ESI          28
  55 #define JB_EBP          32
  56 #define JB_ESP          36
  57 #define JB_SS           40
  58 #define JB_EFLAGS       44
  59 #define JB_EIP          48
  60 #define JB_CS           52
  61 #define JB_DS           56
  62 #define JB_ES           60
  63 #define JB_FS           64
  64 #define JB_GS           68
  65
  66 LEAF(__setjmp, 0)
  67         movl    4(%esp), %ecx           // jmp_buf (struct sigcontext *)
  68
  69         // Build the jmp_buf
  70         fnstcw  JB_FPCW(%ecx)                   // Save the FP control word
  71         stmxcsr JB_MXCSR(%ecx)                  // Save the MXCSR
  72         movl    %ebx, JB_EBX(%ecx)
  73         movl    %edi, JB_EDI(%ecx)
  74         movl    %esi, JB_ESI(%ecx)
  75         movl    %ebp, JB_EBP(%ecx)
  76
  77         // EIP is set to the frame return address value
  78         movl    (%esp), %eax
  79         movl    %eax, JB_EIP(%ecx)
  80         // ESP is set to the frame return address plus 4
  81         leal    4(%esp), %eax
  82         movl    %eax, JB_ESP(%ecx)
  83
  84         // return 0
  85         xorl    %eax, %eax
  86         ret
  87
  88
  89 LEAF(__longjmp, 0)
  90         fninit                          // Clear all FP exceptions
  91         movl    4(%esp), %ecx           // jmp_buf (struct sigcontext *)
  92         movl    8(%esp), %eax           // return value
  93         testl   %eax, %eax
  94         jnz 1f
  95         incl    %eax
  96
  97         // general registers
  98 1:      movl    JB_EBX(%ecx), %ebx
  99         movl    JB_ESI(%ecx), %esi
 100         movl    JB_EDI(%ecx), %edi
 101         movl    JB_EBP(%ecx), %ebp
 102         movl    JB_ESP(%ecx), %esp
 103
 104         fldcw   JB_FPCW(%ecx)                   // Restore FP control word
 105         ldmxcsr JB_MXCSR(%ecx)                  // Restore the MXCSR
 106
 107         cld                                     // Make sure DF is reset
 108         jmp     *JB_EIP(%ecx)