i386/sys/_setjmp.s

   1 /*
   2  * Copyright (c) 1999 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23 /*
  24  * Copyright (c) 1995 NeXT Computer, Inc. All Rights Reserved
  25  *
  26  * HISTORY
  27  *  20-Apr-92    Bruce Martin (bmartin@next.com)
  28  *      Created from M68K sources.
  29  */
  30
  31 /*
  32  * C library -- _setjmp, _longjmp
  33  *
  34  *      _longjmp(a,v)
  35  * will generate a "return(v)" from
  36  * the last call to
  37  *      _setjmp(a)
  38  * by restoring registers from the stack,
  39  * The previous signal state is NOT restored.
  40  *
  41  */
  42
  43 #include <architecture/i386/asm_help.h>
  44
  45 #define JB_ONSTACK      0
  46 #define JB_MASK         4
  47 #define JB_EAX          8
  48 #define JB_EBX          12
  49 #define JB_ECX          16
  50 #define JB_EDX          20
  51 #define JB_EDI          24
  52 #define JB_ESI          28
  53 #define JB_EBP          32
  54 #define JB_ESP          36
  55 #define JB_SS           40
  56 #define JB_EFLAGS       44
  57 #define JB_EIP          48
  58 #define JB_CS           52
  59 #define JB_DS           56
  60 #define JB_ES           60
  61 #define JB_FS           64
  62 #define JB_GS           68
  63
  64
  65 LEAF(__setjmp, 0)
  66         movl    4(%esp), %ecx           // jmp_buf (struct sigcontext *)
  67
  68         // now build sigcontext
  69         movl    %ebx, JB_EBX(%ecx)
  70         movl    %edi, JB_EDI(%ecx)
  71         movl    %esi, JB_ESI(%ecx)
  72         movl    %ebp, JB_EBP(%ecx)
  73
  74         // EIP is set to the frame return address value
  75         movl    (%esp), %eax
  76         movl    %eax, JB_EIP(%ecx)
  77         // ESP is set to the frame return address plus 4
  78         movl    %esp, %eax
  79         addl    $4, %eax
  80         movl    %eax, JB_ESP(%ecx)
  81
  82 #if SAVE_SEG_REGS
  83         // segment registers
  84         mov     %ss, JB_SS(%ecx)
  85         mov     %cs, JB_CS(%ecx)
  86         mov     %ds, JB_DS(%ecx)
  87         mov     %es, JB_ES(%ecx)
  88         mov     %fs, JB_FS(%ecx)
  89         mov     %gs, JB_GS(%ecx)
  90 #endif
  91
  92         // save eflags - you can't use movl
  93         pushf
  94         popl    %eax
  95         movl    %eax, JB_EFLAGS(%ecx)
  96
  97         // return 0
  98         xorl    %eax, %eax
  99         ret
 100
 101
 102 LEAF(__longjmp, 0)
 103         subl    $2,%esp
 104         fnstcw  (%esp)                  // save FP control word
 105         fninit                          // reset FP coprocessor
 106         fldcw   (%esp)                  // restore FP control word
 107         addl    $2,%esp
 108
 109         movl    4(%esp), %ecx           // jmp_buf (struct sigcontext *)
 110         movl    8(%esp), %eax           // return value
 111         testl   %eax, %eax
 112         jnz 1f
 113         incl %eax
 114
 115         // general registers
 116 1:      movl    JB_EBX(%ecx), %ebx
 117         movl    JB_ESI(%ecx), %esi
 118         movl    JB_EDI(%ecx), %edi
 119         movl    JB_EBP(%ecx), %ebp
 120         movl    JB_ESP(%ecx), %esp
 121
 122 #if SAVE_SEG_REGS
 123         // segment registers
 124         mov     JB_SS(%ecx), %ss
 125         mov     JB_CS(%ecx), %cs
 126         mov     JB_DS(%ecx), %ds
 127         mov     JB_ES(%ecx), %es
 128         mov     JB_FS(%ecx), %fs
 129         mov     JB_GS(%ecx), %gs
 130 #endif
 131
 132         // eflags
 133         pushl   JB_EFLAGS(%ecx)
 134         popf
 135
 136         jmp     *JB_EIP(%ecx)