ppc/string/strcat.s

   1 /*
   2  * Copyright (c) 2002 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * Copyright (c) 1999-2003 Apple Computer, Inc.  All Rights Reserved.
   7  *
   8  * This file contains Original Code and/or Modifications of Original Code
   9  * as defined in and that are subject to the Apple Public Source License
  10  * Version 2.0 (the 'License'). You may not use this file except in
  11  * compliance with the License. Please obtain a copy of the License at
  12  * http://www.opensource.apple.com/apsl/ and read it before using this
  13  * file.
  14  *
  15  * The Original Code and all software distributed under the License are
  16  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  17  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  18  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  19  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  20  * Please see the License for the specific language governing rights and
  21  * limitations under the License.
  22  *
  23  * @APPLE_LICENSE_HEADER_END@
  24  */
  25 #define ASSEMBLER
  26 #include <mach/ppc/asm.h>
  27 #undef  ASSEMBLER
  28
  29 #define __APPLE_API_PRIVATE
  30 #include <machine/cpu_capabilities.h>
  31 #undef  __APPLE_API_PRIVATE
  32
  33 /* We use mode-independent "g" opcodes such as "srgi".  These expand
  34  * into word operations when targeting __ppc__, and into doubleword
  35  * operations when targeting __ppc64__.
  36  */
  37 #include <architecture/ppc/mode_independent_asm.h>
  38
  39
  40 // ***************
  41 // * S T R C A T *
  42 // ***************
  43 //
  44 // char*        strcat(const char *dst, const char *src);
  45 //
  46 // We optimize the move by doing it word parallel.  This introduces
  47 // a complication: if we blindly did word load/stores until finding
  48 // a 0, we might get a spurious page fault by touching bytes past it.
  49 // To avoid this, we never do a load that crosses a page boundary,
  50 // and never store a byte we don't have to.
  51 //
  52 // The test for 0s relies on the following inobvious but very efficient
  53 // word-parallel test:
  54 //              x =  dataWord + 0xFEFEFEFF
  55 //              y = ~dataWord & 0x80808080
  56 //              if (x & y) == 0 then no zero found
  57 // The test maps any non-zero byte to zero, and any zero byte to 0x80,
  58 // with one exception: 0x01 bytes preceeding the first zero are also
  59 // mapped to 0x80.
  60 //
  61 // In 64-bit mode, this algorithm is doubleword parallel.
  62
  63         .text
  64         .globl  EXT(strcat)
  65
  66         .align  5
  67 LEXT(strcat)                        // char*    strcat(const char *s, const char *append);
  68         clrrgi  r9,r3,LOG2_GPR_BYTES// align pointer by zeroing right LOG2_GPR_BYTES bits
  69         li              r10,-1                          // get 0xFFs
  70         lg              r8,0(r9)                        // get word or doubleword with 1st operand byte
  71         rlwinm  r11,r3,3,(GPR_BYTES-1)*8 // get starting bit position of operand
  72 #if defined(__ppc__)
  73         lis             r6,hi16(0xFEFEFEFF)     // start to generate 32-bit magic constants
  74         lis             r7,hi16(0x80808080)
  75         srw             r10,r10,r11                     // create a mask of 0xFF bytes for operand in r8
  76         ori             r6,r6,lo16(0xFEFEFEFF)
  77         ori             r7,r7,lo16(0x80808080)
  78 #else
  79         ld              r6,_COMM_PAGE_MAGIC_FE(0)       // get 0xFEFEFEFE FEFEFEFF from commpage
  80         ld              r7,_COMM_PAGE_MAGIC_80(0)       // get 0x80808080 80808080 from commpage
  81         srd             r10,r10,r11                     // create a mask of 0xFF bytes for operand in r8
  82 #endif
  83         orc     r8,r8,r10           // make sure bytes preceeding operand are nonzero
  84         b       Lword0loopEnter
  85
  86 // Loop over words or doublewords looking for 0-byte marking end of dest.
  87 //              r4 = source ptr (unaligned)
  88 //              r6 = 0xFEFEFEFF
  89 //              r7 = 0x80808080
  90 //              r9 = dest ptr (aligned)
  91
  92         .align  5                                       // align inner loops for speed
  93 Lword0loop:
  94         lgu             r8,GPR_BYTES(r9)    // r8 <- next dest word or doubleword
  95 Lword0loopEnter:                    // initial entry
  96         add             r10,r8,r6                       // r10 <-  word + 0xFEFEFEFF
  97         andc    r12,r7,r8                       // r12 <- ~word & 0x80808080
  98         and.    r11,r10,r12                     // r11 <- nonzero iff word has a 0-byte
  99         beq             Lword0loop                      // loop until 0 found
 100
 101 // Now we know one of the bytes in r8 is zero, we just have to figure out which one.
 102 // We have mapped 0 bytes to 0x80, and nonzero bytes to 0x00, with one exception:
 103 // 0x01 bytes preceeding the first zero are also mapped to 0x80.   So we have to mask
 104 // out the 0x80s caused by 0x01s before searching for the 0x80 byte.  Once the 0 is
 105 // found, we can start appending source.  We align the source, which allows us to
 106 // avoid worrying about spurious page faults.
 107 //              r4 = source ptr (unaligned)
 108 //              r6 = 0xFEFEFEFF
 109 //              r7 = 0x80808080
 110 //      r8 = word or doubleword with a 0-byte
 111 //              r9 = ptr to the word or doubleword in r8 (aligned)
 112 //     r11 = mapped word or doubleword
 113
 114         slgi    r10,r8,7            // move 0x01 bits (false hits) into 0x80 position
 115         andi.   r0,r4,GPR_BYTES-1   // is source aligned?
 116         andc    r11,r11,r10                     // mask out false hits
 117         cntlzg  r10,r11                         // find 0 byte (r0 = 0, 8, 16, or 24)
 118         subfic  r0,r0,GPR_BYTES     // get #bytes to align r4
 119         srwi    r10,r10,3           // now r0 = 0, 1, 2, or 3
 120         add             r9,r9,r10                       // now r9 points to the 0-byte in dest
 121         beq             LwordloopEnter          // skip if source is already aligned
 122
 123         mtctr   r0                                      // set up loop
 124
 125 // Loop over bytes.
 126 //              r4 = source ptr (unaligned)
 127 //              r6 = 0xFEFEFEFF
 128 //              r7 = 0x80808080
 129 //              r9 = dest ptr (unaligned)
 130 //         ctr = byte count
 131
 132 Lbyteloop:
 133         lbz             r8,0(r4)                        // r8 <- next source byte
 134         addi    r4,r4,1
 135         cmpwi   r8,0                            // 0 ?
 136         stb             r8,0(r9)                        // pack into dest
 137         addi    r9,r9,1
 138         bdnzf   eq,Lbyteloop            // loop until (ctr==0) | (r8==0)
 139
 140         bne             LwordloopEnter          // 0-byte not found, so enter word loop
 141         blr                                                     // 0-byte found, done
 142
 143 // Word loop: move a word or doubleword at a time until 0-byte found.
 144 //              r4 = source ptr (aligned)
 145 //              r6 = 0xFEFEFEFF
 146 //              r7 = 0x80808080
 147 //              r9 = dest ptr (unaligned)
 148
 149         .align  5                                       // align inner loop, which is 8 words ling
 150 Lwordloop:
 151         stg             r8,0(r9)                        // pack word or doubleword into destination
 152         addi    r9,r9,GPR_BYTES
 153 LwordloopEnter:
 154         lg              r8,0(r4)                        // r8 <- next 4 or 8 source bytes
 155         addi    r4,r4,GPR_BYTES
 156         add             r10,r8,r6                       // r10 <-  word + 0xFEFEFEFF
 157         andc    r12,r7,r8                       // r12 <- ~word & 0x80808080
 158         and.    r0,r10,r12                      // r0 <- nonzero iff word has a 0-byte
 159         beq             Lwordloop                       // loop if no 0-byte
 160
 161 // Found a 0-byte.  Store last word up to and including the 0, a byte at a time.
 162 //              r8 = last word or doubleword, known to have a 0-byte
 163 //              r9 = dest ptr
 164
 165 Lstorelastbytes:
 166         srgi.   r0,r8,GPR_BYTES*8-8 // shift leftmost byte into bottom so we can "stb"
 167         slgi    r8,r8,8             // move on to next
 168         stb             r0,0(r9)                        // pack into dest
 169         addi    r9,r9,1
 170         bne             Lstorelastbytes         // loop until 0 stored
 171
 172         blr
 173