ppc/sys/setjmp.s

   1 /*
   2  * Copyright (c) 1999 Apple Computer, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23 /*
  24  * Copyright (c) 1998 Apple Computer, Inc. All rights reserved.
  25  *
  26  *      File: sys/ppc/setjmp.s
  27  *
  28  *      Implements sigsetjmp(), setjmp(), _setjmp()
  29  *
  30  *      NOTE:   Scatterloading this file will BREAK the functions.
  31  *
  32  *      History:
  33  *      30-Aug-1998     Umesh Vaishampayan      (umeshv@apple.com)
  34  *              Created. Derived from _setjmp.s, setjmp.c and setjmp.s
  35  */
  36
  37 /* We use mode-independent "g" opcodes such as "stg", and/or
  38  * mode-independent macros such as MI_GET_ADDRESS.  These expand
  39  * into word operations when targeting __ppc__, and into doubleword
  40  * operations when targeting __ppc64__.
  41  */
  42 #include <architecture/ppc/mode_independent_asm.h>
  43
  44 #include "_setjmp.h"
  45
  46 /*
  47  * setjmp  routines
  48  */
  49
  50 /*      int sigsetjmp(sigjmp_buf env, int savemask); */
  51
  52 MI_ENTRY_POINT(_sigsetjmp)
  53         cmpgi   cr1,r4,0                ; this changes cr1 which is volatile
  54         stg     r4, JMP_SIGFLAG(r3)     ; save the sigflag for use by siglongjmp()
  55         beq--   cr1, L__exit            ; if r4 == 0 do _setjmp()
  56         ; else *** fall through ***  to setjmp()
  57
  58 /*      int setjmp(jmp_buf env); */
  59
  60 MI_ENTRY_POINT(_setjmp)
  61         mflr    r0
  62         stg     r31, JMP_r31(r3)
  63         stg     r0, JMP_lr(r3)
  64         mr      r31, r3                 ; save ptr to jmpbuf across calls
  65
  66         /* call sigprocmask() to get signal mask */
  67
  68         li      r3, 1                   ; get the previous signal mask
  69         li      r4, 0
  70         la      r5, JMP_sig(r31)        ; get address where previous mask needs to be
  71         MI_CALL_EXTERNAL(_sigprocmask)  ; make a syscall to get mask
  72
  73         /* call sigaltstack() to get SS_ONSTACK flag */
  74
  75         li      r3,0                    ; ss is NULL
  76         la      r4,JMP_vr_base_addr(r31); oss is a temp buffer in jmp_buf
  77         MI_CALL_EXTERNAL(_sigaltstack)  ; make a syscall to get current stack state
  78         la      r4,JMP_vr_base_addr(r31); recreate temp buffer ptr
  79         lwz     r5,2*GPR_BYTES(r4)      ; get ss_flags (an int) from stack_t
  80         stw     r5,JMP_ss_flags(r31)    ; save ss_flags in jmp_buf
  81
  82         mr      r3, r31                 ; restore jmp_buf ptr
  83         lg      r0, JMP_lr(r31)
  84         lg      r31, JMP_r31(r31)
  85         mtlr    r0
  86 L__exit:
  87         MI_BRANCH_EXTERNAL(__setjmp)