i386/sys/_sigtramp.s

   1 /*
   2  * Copyright (c) 2007, 2011 Apple Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23
  24 #include <sys/syscall.h>
  25
  26 #if defined(__DYNAMIC__)
  27         .globl ___in_sigtramp
  28         .data
  29         .align 2
  30 ___in_sigtramp:
  31         .space 4
  32 #endif
  33
  34 #define UC_TRAD                 1
  35 #define UC_FLAVOR               30
  36
  37 /* Structure fields for ucontext and mcontext.  */
  38 #define UCONTEXT_UC_MCONTEXT    28
  39
  40 #define MCONTEXT_ES_EXCEPTION   0
  41 #define MCONTEXT_SS_EAX         12
  42 #define MCONTEXT_SS_EBX         16
  43 #define MCONTEXT_SS_ECX         20
  44 #define MCONTEXT_SS_EDX         24
  45 #define MCONTEXT_SS_EDI         28
  46 #define MCONTEXT_SS_ESI         32
  47 #define MCONTEXT_SS_EBP         36
  48 #define MCONTEXT_SS_ESP         40
  49 #define MCONTEXT_SS_EFLAGS      48
  50 #define MCONTEXT_SS_EIP         52
  51
  52 /* register use:
  53         %ebp    frame pointer
  54         %ebx    Address of "L00000000001$pb"
  55         %esi    uctx
  56
  57 void
  58 _sigtramp(
  59         union __sigaction_u __sigaction_u,
  60         int                     sigstyle,
  61         int                     sig,
  62         siginfo_t               *sinfo,
  63         ucontext_t              *uctx
  64 )
  65 */
  66
  67         .globl __sigtramp
  68         .text
  69         .align 4,0x90
  70 __sigtramp:
  71 Lstart:
  72         /* Although this routine does not need any stack frame, various parts
  73            of the OS can't analyse the stack without them.  */
  74         pushl   %ebp
  75         movl    %esp, %ebp
  76         subl    $24, %esp
  77         movl    8(%ebp), %ecx   # get '__sigaction_u'
  78 #if defined(__DYNAMIC__)
  79         call    0f
  80 "L00000000001$pb":
  81 0:
  82         popl    %ebx
  83         incl    ___in_sigtramp-"L00000000001$pb"(%ebx)
  84 #endif
  85         movl    16(%ebp), %edx  # get 'sig'
  86         movl    20(%ebp), %eax  # get 'sinfo'
  87         movl    24(%ebp), %esi  # get 'uctx'
  88         /* Call the signal handler.
  89            Some variants are not supposed to get the last two parameters,
  90            but the test to prevent this is more expensive than just passing
  91            them.  */
  92         movl    %esi, 8(%esp)
  93         movl    %eax, 4(%esp)
  94         movl    %edx, (%esp)
  95         call    *%ecx
  96 #if defined(__DYNAMIC__)
  97         decl    ___in_sigtramp-"L00000000001$pb"(%ebx)
  98 #endif
  99         movl    %esi, 4(%esp)
 100         movl    $ UC_FLAVOR, 8(%esp)
 101         movl    $ SYS_sigreturn, %eax
 102         int     $0x80
 103 Lend:
 104
 105 /* DWARF unwind table #defines.  */
 106 #define DW_CFA_advance_loc_4 0x44
 107 #define DW_CFA_def_cfa 0x0c
 108 #define DW_CFA_def_cfa_expression 0x0F
 109 #define DW_CFA_expression 0x10
 110 #define DW_CFA_val_expression 0x16
 111 #define DW_CFA_offset(column) 0x80+(column)
 112
 113 /* DWARF expression #defines.  */
 114 #define DW_OP_deref 0x06
 115 #define DW_OP_const1u 0x08
 116 #define DW_OP_dup 0x12
 117 #define DW_OP_drop 0x13
 118 #define DW_OP_over 0x14
 119 #define DW_OP_pick 0x15
 120 #define DW_OP_swap 0x16
 121 #define DW_OP_rot 0x17
 122 #define DW_OP_abs 0x19
 123 #define DW_OP_and 0x1a
 124 #define DW_OP_div 0x1b
 125 #define DW_OP_minus 0x1c
 126 #define DW_OP_mod 0x1d
 127 #define DW_OP_mul 0x1e
 128 #define DW_OP_neg 0x1f
 129 #define DW_OP_not 0x20
 130 #define DW_OP_or 0x21
 131 #define DW_OP_plus 0x22
 132 #define DW_OP_plus_uconst 0x23
 133 #define DW_OP_shl 0x24
 134 #define DW_OP_shr 0x25
 135 #define DW_OP_shra 0x26
 136 #define DW_OP_xor 0x27
 137 #define DW_OP_skip 0x2f
 138 #define DW_OP_bra 0x28
 139 #define DW_OP_eq 0x29
 140 #define DW_OP_ge 0x2A
 141 #define DW_OP_gt 0x2B
 142 #define DW_OP_le 0x2C
 143 #define DW_OP_lt 0x2D
 144 #define DW_OP_ne 0x2E
 145 #define DW_OP_lit(n) 0x30+(n)
 146 #define DW_OP_breg(n) 0x70+(n)
 147 #define DW_OP_deref_size 0x94
 148
 149 /* The location expression we'll use.  */
 150
 151 #define loc_expr_for_reg(regno, offs)                           \
 152         .byte DW_CFA_expression, regno, 5 /* block length */,   \
 153          DW_OP_breg(6), UCONTEXT_UC_MCONTEXT, DW_OP_deref,      \
 154          DW_OP_plus_uconst, offs
 155
 156         /* Unwind tables.  */
 157         .section __TEXT,__eh_frame,coalesced,no_toc+strip_static_syms+live_support
 158 EH_frame1:
 159         .set L$set$0,LECIE1-LSCIE1
 160         .long L$set$0   # Length of Common Information Entry
 161 LSCIE1:
 162         .long   0       # CIE Identifier Tag
 163         .byte   0x1     # CIE Version
 164         .ascii "zRS\0"  # CIE Augmentation
 165         .byte   0x1     # uleb128 0x1; CIE Code Alignment Factor
 166         .byte   0x7c    # sleb128 -4; CIE Data Alignment Factor
 167         .byte   0x8     # CIE RA Column
 168         .byte   0x1     # uleb128 0x1; Augmentation size
 169         .byte   0x10    # FDE Encoding (pcrel)
 170         .byte   DW_CFA_def_cfa
 171         .byte   0x5     # uleb128 0x5
 172         .byte   0x4     # uleb128 0x4
 173         .byte   DW_CFA_offset(8)
 174         .byte   0x1     # uleb128 0x1
 175         .byte   DW_CFA_offset(8)        // double DW_CFA_offset (eip, -4) tells linker to not make compact unwind
 176         .byte   0x1     # uleb128 0x1
 177         .align 2
 178 LECIE1:
 179         .globl _sigtramp.eh
 180 _sigtramp.eh:
 181 LSFDE1:
 182         .set L$set$1,LEFDE1-LASFDE1
 183         .long L$set$1   # FDE Length
 184 LASFDE1:
 185         .long   LASFDE1-EH_frame1       # FDE CIE offset
 186         .long   Lstart-.        # FDE initial location
 187         .set L$set$2,Lend-Lstart
 188         .long   L$set$2 # FDE address range
 189         .byte   0x0     # uleb128 0x0; Augmentation size
 190
 191         /* Now for the expressions, which all compute
 192            uctx->uc_mcontext->register
 193            for each register.
 194
 195            Describe even the registers that are not call-saved because they
 196            might be being used in the prologue to save other registers.
 197            Only integer registers are described at present.    */
 198
 199         loc_expr_for_reg (0, MCONTEXT_SS_EAX)
 200         loc_expr_for_reg (1, MCONTEXT_SS_ECX)
 201         loc_expr_for_reg (2, MCONTEXT_SS_EDX)
 202         loc_expr_for_reg (3, MCONTEXT_SS_EBX)
 203         loc_expr_for_reg (4, MCONTEXT_SS_EBP) # note that GCC switches
 204         loc_expr_for_reg (5, MCONTEXT_SS_ESP) # DWARF registers 4 & 5
 205         loc_expr_for_reg (6, MCONTEXT_SS_ESI)
 206         loc_expr_for_reg (7, MCONTEXT_SS_EDI)
 207         loc_expr_for_reg (9, MCONTEXT_SS_EFLAGS)
 208
 209         /* The Intel architecture classifies exceptions into three categories,
 210            'faults' which put the address of the faulting instruction
 211            in EIP, 'traps' which put the following instruction in EIP,
 212            and 'aborts' which don't typically report the instruction
 213            causing the exception.
 214
 215            The traps are #BP and #OF.  */
 216
 217         .byte DW_CFA_val_expression, 8
 218         .set L$set$3,Lpc_end-Lpc_start
 219         .byte L$set$3
 220 Lpc_start:
 221         /* Push the mcontext address twice.  */
 222         .byte DW_OP_breg(6), UCONTEXT_UC_MCONTEXT, DW_OP_deref, DW_OP_dup
 223         /* Find the value of EIP.  */
 224         .byte   DW_OP_plus_uconst, MCONTEXT_SS_EIP, DW_OP_deref, DW_OP_swap
 225         /* Determine the exception type.  */
 226         .byte   DW_OP_plus_uconst, MCONTEXT_ES_EXCEPTION, DW_OP_deref
 227         /* Check whether it is #BP (3) or #OF (4).  */
 228         .byte   DW_OP_dup, DW_OP_lit(3), DW_OP_ne
 229         .byte    DW_OP_swap, DW_OP_lit(4), DW_OP_ne, DW_OP_and
 230         /* If it is, then add 1 to the instruction address, so as to point
 231            within or past the faulting instruction.  */
 232         .byte   DW_OP_plus
 233 Lpc_end:
 234
 235         /* The CFA will have been saved as the value of ESP (it is not
 236            ESP+4).  */
 237         .byte DW_CFA_def_cfa_expression
 238         .set L$set$4,Lcfa_end-Lcfa_start
 239         .byte L$set$4
 240 Lcfa_start:
 241         .byte DW_OP_breg(6), UCONTEXT_UC_MCONTEXT, DW_OP_deref
 242         .byte  DW_OP_plus_uconst, MCONTEXT_SS_ESP, DW_OP_deref
 243 Lcfa_end:
 244
 245         .align 2
 246 LEFDE1:
 247
 248         .subsections_via_symbols