arm/string/strchr.s

   1 /*
   2  * Copyright (c) 2010 Apple, Inc. All rights reserved.
   3  *
   4  * @APPLE_LICENSE_HEADER_START@
   5  *
   6  * This file contains Original Code and/or Modifications of Original Code
   7  * as defined in and that are subject to the Apple Public Source License
   8  * Version 2.0 (the 'License'). You may not use this file except in
   9  * compliance with the License. Please obtain a copy of the License at
  10  * http://www.opensource.apple.com/apsl/ and read it before using this
  11  * file.
  12  *
  13  * The Original Code and all software distributed under the License are
  14  * distributed on an 'AS IS' basis, WITHOUT WARRANTY OF ANY KIND, EITHER
  15  * EXPRESS OR IMPLIED, AND APPLE HEREBY DISCLAIMS ALL SUCH WARRANTIES,
  16  * INCLUDING WITHOUT LIMITATION, ANY WARRANTIES OF MERCHANTABILITY,
  17  * FITNESS FOR A PARTICULAR PURPOSE, QUIET ENJOYMENT OR NON-INFRINGEMENT.
  18  * Please see the License for the specific language governing rights and
  19  * limitations under the License.
  20  *
  21  * @APPLE_LICENSE_HEADER_END@
  22  */
  23
  24 //  char * strchr(const char *s, int c);
  25 //
  26 //  The strchr( ) function locates the first occurence of c (converted to a
  27 //  char) in the string s.  If c is '\0', the function locates the terminating
  28 //  '\0' byte.
  29
  30 .text
  31 .syntax unified
  32 .code 32
  33 .globl _strchr
  34
  35 .align 3
  36 _strchr:
  37 //  Setup a frame and convert c to a char.
  38     push   {r7,lr}
  39     mov     r7,         sp
  40     and     r1,     r1, #0xff
  41
  42 //  Basic character-by-character search for c; on each pass through the loop
  43 //  we load a byte from s and increment s.  We then check if this byte is equal
  44 //  to either c or to '\0'; if not, we continue the loop.
  45 0:  ldrb    r2,    [r0],#1
  46     cmp     r2,     r1
  47     tstne   r2,     r2
  48     bne     0b
  49
  50 //  Either we have found a match, or we have reached the end of the string (or
  51 //  both, if c == '\0').  Because we incremented s after loading the last
  52 //  character, we need to decrement the pointer by one to get a pointer to
  53 //  either the matching or terminating character.
  54     sub     r0,     r0, #1
  55
  56 //  Now compare the last character we loaded to the character that we're
  57 //  searching for.  If they don't match, the character was not found in the
  58 //  string, so return NULL.
  59     cmp     r2,     r1
  60     movne   r0,     #0
  61     pop    {r7,pc}