JavaScriptCore.pro

   1 # JavaScriptCore - qmake build info
   2 CONFIG += building-libs
   3 include($$PWD/../WebKit.pri)
   4
   5 TEMPLATE = lib
   6 CONFIG += staticlib
   7 TARGET = JavaScriptCore
   8
   9 CONFIG += depend_includepath
  10
  11 contains(QT_CONFIG, embedded):CONFIG += embedded
  12
  13 CONFIG(QTDIR_build) {
  14     GENERATED_SOURCES_DIR = $$PWD/generated
  15     OLDDESTDIR = $$DESTDIR
  16     include($$QT_SOURCE_TREE/src/qbase.pri)
  17     INSTALLS =
  18     DESTDIR = $$OLDDESTDIR
  19     DEFINES *= NDEBUG
  20 }
  21
  22 isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = tmp
  23 GENERATED_SOURCES_DIR_SLASH = $${GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}
  24
  25 INCLUDEPATH += $$GENERATED_SOURCES_DIR
  26
  27 !CONFIG(QTDIR_build) {
  28     CONFIG(debug, debug|release) {
  29         OBJECTS_DIR = obj/debug
  30     } else { # Release
  31         OBJECTS_DIR = obj/release
  32     }
  33 }
  34
  35 CONFIG(release):!CONFIG(QTDIR_build) {
  36     contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
  37     unix:contains(QT_CONFIG, reduce_relocations):CONFIG += bsymbolic_functions
  38 }
  39
  40 linux-*: DEFINES += HAVE_STDINT_H
  41 freebsd-*: DEFINES += HAVE_PTHREAD_NP_H
  42
  43 DEFINES += BUILD_WEBKIT
  44
  45 win32-*: DEFINES += _HAS_TR1=0
  46
  47 # Pick up 3rdparty libraries from INCLUDE/LIB just like with MSVC
  48 win32-g++ {
  49     TMPPATH            = $$quote($$(INCLUDE))
  50     QMAKE_INCDIR_POST += $$split(TMPPATH,";")
  51     TMPPATH            = $$quote($$(LIB))
  52     QMAKE_LIBDIR_POST += $$split(TMPPATH,";")
  53 }
  54
  55 DEFINES += WTF_CHANGES=1
  56
  57 include(JavaScriptCore.pri)
  58
  59 QMAKE_EXTRA_TARGETS += generated_files
  60
  61 *-g++*:QMAKE_CXXFLAGS_RELEASE -= -O2
  62 *-g++*:QMAKE_CXXFLAGS_RELEASE += -O3