JavaScriptCore.vcxproj/copy-files.cmd

   1 @echo off
   2
   3 set PublicHeadersDirectory=%CONFIGURATIONBUILDDIR%\include\JavaScriptCore
   4 set PrivateHeadersDirectory=%CONFIGURATIONBUILDDIR%\include\private\JavaScriptCore
   5 set ResourcesDirectory=%CONFIGURATIONBUILDDIR%\bin%PlatformArchitecture%\JavaScriptCore.resources
   6 set DerivedSourcesDirectory=%CONFIGURATIONBUILDDIR%\obj%PlatformArchitecture%\JavaScriptCore\DerivedSources
   7
   8 if "%1" EQU "clean" goto :clean
   9 if "%1" EQU "rebuild" call :clean
  10
  11 echo Copying public headers...
  12 @mkdir "%PublicHeadersDirectory%" 2>NUL
  13 for %%f in (
  14     APICast.h
  15     APIShims.h
  16     JSBase.h
  17     JSClassRef.h
  18     JSContextRef.h
  19     JSContextRefPrivate.h
  20         JSCTestRunnerUtils.h
  21     JSObjectRef.h
  22     JSObjectRefPrivate.h
  23     JSRetainPtr.h
  24     JSRetainPtr.h
  25     JSStringRef.h
  26     JSStringRefBSTR.h
  27     JSStringRefCF.h
  28     JSValueRef.h
  29     JSWeakObjectMapRefInternal.h
  30     JSWeakObjectMapRefPrivate.h
  31     JavaScript.h
  32     JavaScriptCore.h
  33     OpaqueJSString.h
  34     WebKitAvailability.h
  35 ) do (
  36     @xcopy /y /d ..\API\%%f "%PublicHeadersDirectory%" >NUL
  37 )
  38
  39 echo Copying private headers...
  40 mkdir "%PrivateHeadersDirectory%" 2>NUL
  41 for %%d in (
  42     assembler
  43     bindings
  44     bytecode
  45     builtins
  46     dfg
  47     disassembler
  48     heap
  49     debugger
  50     inspector
  51     inspector\agents
  52     interpreter
  53     jit
  54     llint
  55     parser
  56     profiler
  57     replay
  58     runtime
  59     yarr
  60 ) do (
  61     @xcopy /y /d ..\%%d\*.h "%PrivateHeadersDirectory%" >NUL
  62 )
  63
  64 echo Copying Inspector scripts as if they were private headers...
  65 for %%d in (
  66     inspector\scripts
  67         inspector\scripts\codegen
  68 ) do (
  69     @xcopy /y /d ..\%%d\* "%PrivateHeadersDirectory%" >NUL
  70 )
  71
  72 echo Copying Inspector generated files as if they were private headers...
  73 @xcopy /y "%DerivedSourcesDirectory%\CombinedDomains.json" "%PrivateHeadersDirectory%" >NUL
  74 @xcopy /y "%DerivedSourcesDirectory%\InspectorProtocolObjects.h" "%PrivateHeadersDirectory%" >NUL
  75 @xcopy /y "%DerivedSourcesDirectory%\InspectorBackendDispatchers.h" "%PrivateHeadersDirectory%" >NUL
  76 @xcopy /y "%DerivedSourcesDirectory%\InspectorFrontendDispatchers.h" "%PrivateHeadersDirectory%" >NUL
  77 @xcopy /y "%DerivedSourcesDirectory%\InspectorBackendCommands.js" "%PrivateHeadersDirectory%" >NUL
  78
  79 echo Copying Web Replay scripts as if they were private headers...
  80 for %%d in (
  81     replay\scripts
  82 ) do (
  83     @xcopy /y /d ..\%%d\* "%PrivateHeadersDirectory%" >NUL
  84 )
  85
  86 echo Copying Web Replay generated headers as if they were private headers...
  87 @xcopy /y "%DerivedSourcesDirectory%\JSReplayInputs.h" "%PrivateHeadersDirectory%" >NUL
  88
  89 echo Copying Web Replay specification files as if they were private headers...
  90 @xcopy /y /d ..\replay\*.json "%PrivateHeadersDirectory%" >NUL
  91
  92 echo Copying builtins header as if it were a private header...
  93 @xcopy /y "%DerivedSourcesDirectory%\JSCBuiltins.h" "%PrivateHeadersDirectory%" >NUL
  94 @xcopy /y "%DerivedSourcesDirectory%\Bytecodes.h" "%PrivateHeadersDirectory%" >NUL
  95
  96 echo Copying resources...
  97 @mkdir "%ResourcesDirectory%" 2>NUL
  98 @xcopy /y /d JavaScriptCore.resources\* "%ResourcesDirectory%" >NUL
  99
 100 goto :EOF
 101
 102 :clean
 103
 104 echo Deleting copied files...
 105 @if exist "%PublicHeadersDirectory%" rmdir /s /q "%PublicHeadersDirectory%" >NUL 2>NUL
 106 @if exist "%PrivateHeadersDirectory%" rmdir /s /q "%PrivateHeadersDirectory%" >NUL 2>NUL
 107 @if exist "%ResourcesDirectory%" rmdir /s /q "%ResourcesDirectory%" >NUL 2>NUL