JavaScriptCore.pri

   1 # JavaScriptCore - Qt4 build info
   2 VPATH += $$PWD
   3
   4 CONFIG(debug, debug|release) {
   5     isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = generated$${QMAKE_DIR_SEP}debug
   6     OBJECTS_DIR = obj/debug
   7 } else { # Release
   8     isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = generated$${QMAKE_DIR_SEP}release
   9     OBJECTS_DIR = obj/release
  10 }
  11
  12 INCLUDEPATH += $$GENERATED_SOURCES_DIR \
  13                $$PWD \
  14                $$PWD/parser \
  15                $$PWD/bytecompiler \
  16                $$PWD/debugger \
  17                $$PWD/runtime \
  18                $$PWD/wtf \
  19                $$PWD/wtf/unicode \
  20                $$PWD/interpreter \
  21                $$PWD/jit \
  22                $$PWD/profiler \
  23                $$PWD/wrec \
  24                $$PWD/yarr \
  25                $$PWD/API \
  26                $$PWD/.. \
  27                $$PWD/ForwardingHeaders \
  28                $$PWD/bytecode \
  29                $$PWD/assembler \
  30
  31 DEFINES += BUILDING_QT__ BUILDING_JavaScriptCore BUILDING_WTF
  32
  33 GENERATED_SOURCES_DIR_SLASH = $${GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}
  34 win32-* {
  35     LIBS += -lwinmm
  36 }
  37
  38 # Default rules to turn JIT on/off
  39 !contains(DEFINES, ENABLE_JIT=.) {
  40     isEqual(QT_ARCH,i386)|isEqual(QT_ARCH,windows) {
  41         # Require gcc >= 4.1
  42         CONFIG(release):linux-g++*:greaterThan(QT_GCC_MAJOR_VERSION,3):greaterThan(QT_GCC_MINOR_VERSION,0) {
  43             DEFINES += ENABLE_JIT=1
  44         }
  45         win32-msvc* {
  46             DEFINES += ENABLE_JIT=1
  47         }
  48     }
  49 }
  50
  51 # Rules when JIT enabled
  52 contains(DEFINES, ENABLE_JIT=1) {
  53     !contains(DEFINES, ENABLE_YARR=.): DEFINES += ENABLE_YARR=1
  54     !contains(DEFINES, ENABLE_YARR_JIT=.): DEFINES += ENABLE_YARR_JIT=1
  55     !contains(DEFINES, ENABLE_JIT_OPTIMIZE_CALL=.): DEFINES += ENABLE_JIT_OPTIMIZE_CALL=1
  56     !contains(DEFINES, ENABLE_JIT_OPTIMIZE_PROPERTY_ACCESS=.): DEFINES += ENABLE_JIT_OPTIMIZE_PROPERTY_ACCESS=1
  57     !contains(DEFINES, ENABLE_JIT_OPTIMIZE_ARITHMETIC=.): DEFINES += ENABLE_JIT_OPTIMIZE_ARITHMETIC=1
  58     linux-g++* {
  59         !contains(DEFINES, WTF_USE_JIT_STUB_ARGUMENT_VA_LIST=.): DEFINES += WTF_USE_JIT_STUB_ARGUMENT_VA_LIST=1
  60         QMAKE_CXXFLAGS += -fno-stack-protector
  61         QMAKE_CFLAGS += -fno-stack-protector
  62     }
  63     win32-msvc* {
  64         !contains(DEFINES, WTF_USE_JIT_STUB_ARGUMENT_REGISTER=.): DEFINES += WTF_USE_JIT_STUB_ARGUMENT_REGISTER=1
  65     }
  66 }
  67
  68 include(pcre/pcre.pri)
  69
  70 LUT_FILES += \
  71     runtime/DatePrototype.cpp \
  72     runtime/JSONObject.cpp \
  73     runtime/NumberConstructor.cpp \
  74     runtime/StringPrototype.cpp \
  75     runtime/ArrayPrototype.cpp \
  76     runtime/MathObject.cpp \
  77     runtime/RegExpConstructor.cpp \
  78     runtime/RegExpObject.cpp
  79
  80 KEYWORDLUT_FILES += \
  81     parser/Keywords.table
  82
  83 JSCBISON += \
  84     parser/Grammar.y
  85
  86 SOURCES += \
  87     wtf/Assertions.cpp \
  88     wtf/ByteArray.cpp \
  89     wtf/HashTable.cpp \
  90     wtf/MainThread.cpp \
  91     wtf/RandomNumber.cpp \
  92     wtf/RefCountedLeakCounter.cpp \
  93     wtf/TypeTraits.cpp \
  94     wtf/unicode/CollatorDefault.cpp \
  95     wtf/unicode/icu/CollatorICU.cpp \
  96     wtf/unicode/UTF8.cpp \
  97     API/JSBase.cpp \
  98     API/JSCallbackConstructor.cpp \
  99     API/JSCallbackFunction.cpp \
 100     API/JSCallbackObject.cpp \
 101     API/JSClassRef.cpp \
 102     API/JSContextRef.cpp \
 103     API/JSObjectRef.cpp \
 104     API/JSStringRef.cpp \
 105     API/JSValueRef.cpp \
 106     API/OpaqueJSString.cpp \
 107     runtime/InitializeThreading.cpp \
 108     runtime/JSGlobalData.cpp \
 109     runtime/JSGlobalObject.cpp \
 110     runtime/JSStaticScopeObject.cpp \
 111     runtime/JSVariableObject.cpp \
 112     runtime/JSActivation.cpp \
 113     runtime/JSNotAnObject.cpp \
 114     runtime/JSONObject.cpp \
 115     runtime/LiteralParser.cpp \
 116     runtime/TimeoutChecker.cpp \
 117     bytecode/CodeBlock.cpp \
 118     bytecode/StructureStubInfo.cpp \
 119     bytecode/JumpTable.cpp \
 120     jit/JIT.cpp \
 121     jit/JITCall.cpp \
 122     jit/JITArithmetic.cpp \
 123     jit/JITOpcodes.cpp \
 124     jit/JITPropertyAccess.cpp \
 125     jit/ExecutableAllocator.cpp \
 126     jit/JITStubs.cpp \
 127     bytecompiler/BytecodeGenerator.cpp \
 128     runtime/ExceptionHelpers.cpp \
 129     runtime/JSPropertyNameIterator.cpp \
 130     interpreter/Interpreter.cpp \
 131     bytecode/Opcode.cpp \
 132     bytecode/SamplingTool.cpp \
 133     yarr/RegexCompiler.cpp \
 134     yarr/RegexInterpreter.cpp \
 135     yarr/RegexJIT.cpp \
 136     interpreter/RegisterFile.cpp
 137
 138 win32-*: SOURCES += jit/ExecutableAllocatorWin.cpp
 139 else: SOURCES += jit/ExecutableAllocatorPosix.cpp
 140
 141 # AllInOneFile.cpp helps gcc analize and optimize code
 142 # Other compilers may be able to do this at link time
 143 SOURCES += \
 144     runtime/ArgList.cpp \
 145     runtime/Arguments.cpp \
 146     runtime/ArrayConstructor.cpp \
 147     runtime/ArrayPrototype.cpp \
 148     runtime/BooleanConstructor.cpp \
 149     runtime/BooleanObject.cpp \
 150     runtime/BooleanPrototype.cpp \
 151     runtime/CallData.cpp \
 152     runtime/Collector.cpp \
 153     runtime/CommonIdentifiers.cpp \
 154     runtime/ConstructData.cpp \
 155     wtf/CurrentTime.cpp \
 156     runtime/DateConstructor.cpp \
 157     runtime/DateConversion.cpp \
 158     runtime/DateInstance.cpp \
 159     runtime/DatePrototype.cpp \
 160     debugger/Debugger.cpp \
 161     debugger/DebuggerCallFrame.cpp \
 162     debugger/DebuggerActivation.cpp \
 163     wtf/dtoa.cpp \
 164     runtime/Error.cpp \
 165     runtime/ErrorConstructor.cpp \
 166     runtime/ErrorInstance.cpp \
 167     runtime/ErrorPrototype.cpp \
 168     interpreter/CallFrame.cpp \
 169     runtime/FunctionConstructor.cpp \
 170     runtime/FunctionPrototype.cpp \
 171     runtime/GetterSetter.cpp \
 172     runtime/GlobalEvalFunction.cpp \
 173     runtime/Identifier.cpp \
 174     runtime/InternalFunction.cpp \
 175     runtime/Completion.cpp \
 176     runtime/JSArray.cpp \
 177     runtime/JSAPIValueWrapper.cpp \
 178     runtime/JSByteArray.cpp \
 179     runtime/JSCell.cpp \
 180     runtime/JSFunction.cpp \
 181     runtime/JSGlobalObjectFunctions.cpp \
 182     runtime/JSImmediate.cpp \
 183     runtime/JSLock.cpp \
 184     runtime/JSNumberCell.cpp \
 185     runtime/JSObject.cpp \
 186     runtime/JSString.cpp \
 187     runtime/JSValue.cpp \
 188     runtime/JSWrapperObject.cpp \
 189     parser/Lexer.cpp \
 190     runtime/Lookup.cpp \
 191     runtime/MathObject.cpp \
 192     runtime/NativeErrorConstructor.cpp \
 193     runtime/NativeErrorPrototype.cpp \
 194     parser/Nodes.cpp \
 195     runtime/NumberConstructor.cpp \
 196     runtime/NumberObject.cpp \
 197     runtime/NumberPrototype.cpp \
 198     runtime/ObjectConstructor.cpp \
 199     runtime/ObjectPrototype.cpp \
 200     runtime/Operations.cpp \
 201     parser/Parser.cpp \
 202     parser/ParserArena.cpp \
 203     runtime/PropertyNameArray.cpp \
 204     runtime/PropertySlot.cpp \
 205     runtime/PrototypeFunction.cpp \
 206     runtime/RegExp.cpp \
 207     runtime/RegExpConstructor.cpp \
 208     runtime/RegExpObject.cpp \
 209     runtime/RegExpPrototype.cpp \
 210     runtime/ScopeChain.cpp \
 211     runtime/SmallStrings.cpp \
 212     runtime/StringConstructor.cpp \
 213     runtime/StringObject.cpp \
 214     runtime/StringPrototype.cpp \
 215     runtime/Structure.cpp \
 216     runtime/StructureChain.cpp \
 217     runtime/UString.cpp \
 218     profiler/HeavyProfile.cpp \
 219     profiler/Profile.cpp \
 220     profiler/ProfileGenerator.cpp \
 221     profiler/ProfileNode.cpp \
 222     profiler/Profiler.cpp \
 223     profiler/TreeProfile.cpp \
 224     wtf/DateMath.cpp \
 225     wtf/FastMalloc.cpp \
 226     wtf/Threading.cpp \
 227     wtf/qt/MainThreadQt.cpp
 228
 229 !contains(DEFINES, ENABLE_SINGLE_THREADED=1) {
 230     SOURCES += wtf/qt/ThreadingQt.cpp
 231 } else {
 232     DEFINES += ENABLE_JSC_MULTIPLE_THREADS=0
 233     SOURCES += wtf/ThreadingNone.cpp
 234 }
 235
 236 # GENERATOR 1-A: LUT creator
 237 lut.output = $${GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}${QMAKE_FILE_BASE}.lut.h
 238 lut.commands = perl $$PWD/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
 239 lut.depend = ${QMAKE_FILE_NAME}
 240 lut.input = LUT_FILES
 241 lut.CONFIG += no_link
 242 addExtraCompiler(lut)
 243
 244 # GENERATOR 1-B: particular LUT creator (for 1 file only)
 245 keywordlut.output = $${GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}Lexer.lut.h
 246 keywordlut.commands = perl $$PWD/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}
 247 keywordlut.depend = ${QMAKE_FILE_NAME}
 248 keywordlut.input = KEYWORDLUT_FILES
 249 keywordlut.CONFIG += no_link
 250 addExtraCompiler(keywordlut)
 251
 252 # GENERATOR 2: bison grammar
 253 jscbison.output = $${GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}${QMAKE_FILE_BASE}.cpp
 254 jscbison.commands = bison -d -p jscyy ${QMAKE_FILE_NAME} -o $${GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}${QMAKE_FILE_BASE}.tab.c && $(MOVE) $${GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}${QMAKE_FILE_BASE}.tab.c ${QMAKE_FILE_OUT} && $(MOVE) $${GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}${QMAKE_FILE_BASE}.tab.h $${GENERATED_SOURCES_DIR}$${QMAKE_DIR_SEP}${QMAKE_FILE_BASE}.h
 255 jscbison.depend = ${QMAKE_FILE_NAME}
 256 jscbison.input = JSCBISON
 257 jscbison.variable_out = GENERATED_SOURCES
 258 jscbison.dependency_type = TYPE_C
 259 jscbison.CONFIG = target_predeps
 260 addExtraCompilerWithHeader(jscbison)
 261