JavaScriptCore.pri

   1 # -------------------------------------------------------------------
   2 # This file contains shared rules used both when building
   3 # JavaScriptCore itself, and by targets that use JavaScriptCore.
   4 #
   5 # See 'Tools/qmake/README' for an overview of the build system
   6 # -------------------------------------------------------------------
   7
   8 SOURCE_DIR = $${ROOT_WEBKIT_DIR}/Source/JavaScriptCore
   9
  10 JAVASCRIPTCORE_GENERATED_SOURCES_DIR = $${ROOT_BUILD_DIR}/Source/JavaScriptCore/$${GENERATED_SOURCES_DESTDIR}
  11
  12 INCLUDEPATH += \
  13     $$SOURCE_DIR \
  14     $$SOURCE_DIR/.. \
  15     $$SOURCE_DIR/../WTF \
  16     $$SOURCE_DIR/assembler \
  17     $$SOURCE_DIR/bytecode \
  18     $$SOURCE_DIR/bytecompiler \
  19     $$SOURCE_DIR/heap \
  20     $$SOURCE_DIR/dfg \
  21     $$SOURCE_DIR/debugger \
  22     $$SOURCE_DIR/disassembler \
  23     $$SOURCE_DIR/interpreter \
  24     $$SOURCE_DIR/jit \
  25     $$SOURCE_DIR/llint \
  26     $$SOURCE_DIR/parser \
  27     $$SOURCE_DIR/profiler \
  28     $$SOURCE_DIR/runtime \
  29     $$SOURCE_DIR/tools \
  30     $$SOURCE_DIR/yarr \
  31     $$SOURCE_DIR/API \
  32     $$SOURCE_DIR/ForwardingHeaders \
  33     $$JAVASCRIPTCORE_GENERATED_SOURCES_DIR
  34
  35 # Pick up the right version of LLIntAssembly.h
  36 macx: INCLUDEPATH += $$JAVASCRIPTCORE_GENERATED_SOURCES_DIR/$$targetSubDir()
  37
  38 win32-*: LIBS += -lwinmm
  39
  40 wince* {
  41     INCLUDEPATH += $$SOURCE_DIR/os-win32
  42 }
  43
  44 linux-*:if(isEqual(QT_ARCH, "i386")|isEqual(QT_ARCH, "x86_64")) {
  45     INCLUDEPATH += $$SOURCE_DIR/disassembler/udis86
  46 }