pcre/pcre.pri

   1 # Perl Compatible Regular Expressions - Qt4 build info
   2 VPATH += $$PWD
   3 INCLUDEPATH += $$PWD $$OUTPUT_DIR/JavaScriptCore/kjs/tmp
   4 DEPENDPATH += $$PWD
   5
   6 isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = tmp
   7
   8 SOURCES += \
   9     pcre_compile.cpp \
  10     pcre_exec.cpp \
  11     pcre_tables.cpp \
  12     pcre_ucp_searchfuncs.cpp \
  13     pcre_xclass.cpp
  14
  15 !CONFIG(QTDIR_build) {
  16     defineTest(addExtraCompiler) {
  17         QMAKE_EXTRA_COMPILERS += $$1
  18         generated_files.depends += compiler_$${1}_make_all
  19         export(QMAKE_EXTRA_COMPILERS)
  20         export(generated_files.depends)
  21         return(true)
  22     }
  23 }
  24
  25 # GENERATOR: "chartables.c": compile and execute the chartables generator (and add it to sources)
  26 DFTABLES = $$PWD/dftables
  27 ctgen.input = DFTABLES
  28 ctgen.output = $$GENERATED_SOURCES_DIR/chartables.c
  29 ctgen.commands = perl $$DFTABLES ${QMAKE_FILE_OUT}
  30 ctgen.CONFIG += target_predeps no_link
  31 ctgen.variable_out = GENERATED_SOURCES
  32 ctgen.dependency_type = TYPE_C
  33 ctgen.clean = ${QMAKE_FILE_OUT} ${QMAKE_VAR_GENERATED_SOURCES_DIR}${QMAKE_FILE_BASE}
  34 addExtraCompiler(ctgen)