JavaScriptCore.pro

   1 # JavaScriptCore - qmake build info
   2 CONFIG += building-libs
   3 include($$PWD/../WebKit.pri)
   4
   5 TEMPLATE = lib
   6 CONFIG += staticlib
   7 TARGET = JavaScriptCore
   8
   9 CONFIG += depend_includepath
  10
  11 contains(QT_CONFIG, embedded):CONFIG += embedded
  12
  13 CONFIG(QTDIR_build) {
  14     GENERATED_SOURCES_DIR = $$PWD/generated
  15     OLDDESTDIR = $$DESTDIR
  16     include($$QT_SOURCE_TREE/src/qbase.pri)
  17     INSTALLS =
  18     DESTDIR = $$OLDDESTDIR
  19     PRECOMPILED_HEADER = $$PWD/../WebKit/qt/WebKit_pch.h
  20     DEFINES *= NDEBUG
  21 }
  22
  23 isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = tmp
  24 GENERATED_SOURCES_DIR_SLASH = $$GENERATED_SOURCES_DIR/
  25 win32-*: GENERATED_SOURCES_DIR_SLASH ~= s|/|\|
  26
  27 INCLUDEPATH += $$GENERATED_SOURCES_DIR
  28
  29 !CONFIG(QTDIR_build) {
  30      OBJECTS_DIR = tmp
  31 }
  32
  33 include($$OUTPUT_DIR/config.pri)
  34
  35 CONFIG -= warn_on
  36 *-g++*:QMAKE_CXXFLAGS += -Wreturn-type -fno-strict-aliasing
  37 #QMAKE_CXXFLAGS += -Wall -Wno-undef -Wno-unused-parameter
  38
  39 CONFIG(release):!CONFIG(QTDIR_build) {
  40     contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
  41     unix:contains(QT_CONFIG, reduce_relocations):CONFIG += bsymbolic_functions
  42 }
  43
  44 linux-*: DEFINES += HAVE_STDINT_H
  45 freebsd-*: DEFINES += HAVE_PTHREAD_NP_H
  46
  47 DEFINES += BUILD_WEBKIT
  48
  49 win32-*: DEFINES += _HAS_TR1=0
  50
  51 # Pick up 3rdparty libraries from INCLUDE/LIB just like with MSVC
  52 win32-g++ {
  53     TMPPATH            = $$quote($$(INCLUDE))
  54     QMAKE_INCDIR_POST += $$split(TMPPATH,";")
  55     TMPPATH            = $$quote($$(LIB))
  56     QMAKE_LIBDIR_POST += $$split(TMPPATH,";")
  57 }
  58
  59 DEFINES += WTF_USE_JAVASCRIPTCORE_BINDINGS=1
  60
  61 DEFINES += WTF_CHANGES=1
  62
  63 include(JavaScriptCore.pri)
  64
  65 QMAKE_EXTRA_TARGETS += generated_files
  66
  67 qt-port: lessThan(QT_MINOR_VERSION, 4) {
  68     DEFINES += QT_BEGIN_NAMESPACE="" QT_END_NAMESPACE=""
  69 }
  70
  71 *-g++*:QMAKE_CXXFLAGS_RELEASE -= -O2
  72 *-g++*:QMAKE_CXXFLAGS_RELEASE += -O3