JavaScriptCore.scons

   1 # The keys in sources are the paths to the directories
   2 # the values are an array of source files in those directories to compile
   3 sources = {}
   4 sources['API'] = [
   5     'API/JSBase.cpp',
   6     'API/JSCallbackConstructor.cpp',
   7     'API/JSCallbackFunction.cpp',
   8     'API/JSCallbackObject.cpp',
   9     'API/JSClassRef.cpp',
  10     'API/JSContextRef.cpp',
  11     'API/JSObjectRef.cpp',
  12     'API/JSProfilerPrivate.cpp',
  13     'API/JSStringRef.cpp',
  14     'API/JSValueRef.cpp',
  15     'API/OpaqueJSString.cpp',
  16 ]
  17 sources['bytecompiler'] = [
  18     'bytecompiler/BytecodeGenerator.cpp',
  19 ]
  20 sources['debugger'] = [
  21     'debugger/Debugger.cpp',
  22     'debugger/DebuggerActivation.cpp',
  23     'debugger/DebuggerCallFrame.cpp',
  24 ]
  25 sources['parser'] = [
  26     'parser/Lexer.cpp',
  27     'parser/Nodes.cpp',
  28     'parser/Parser.cpp',
  29 ]
  30 sources['pcre'] = [
  31     'pcre/pcre_compile.cpp',
  32     'pcre/pcre_exec.cpp',
  33     'pcre/pcre_tables.cpp',
  34     'pcre/pcre_ucp_searchfuncs.cpp',
  35     'pcre/pcre_xclass.cpp',
  36 ]
  37 sources['profiler'] = [
  38     'profiler/HeavyProfile.cpp',
  39     'profiler/Profile.cpp',
  40     'profiler/ProfileGenerator.cpp',
  41     'profiler/ProfileNode.cpp',
  42     'profiler/Profiler.cpp',
  43     'profiler/TreeProfile.cpp',
  44 ]
  45 sources['runtime'] = [
  46     'runtime/ArgList.cpp',
  47     'runtime/Arguments.cpp',
  48     'runtime/ArrayConstructor.cpp',
  49     'runtime/ArrayPrototype.cpp',
  50     'runtime/BooleanConstructor.cpp',
  51     'runtime/BooleanObject.cpp',
  52     'runtime/BooleanPrototype.cpp',
  53     'runtime/CallData.cpp',
  54     'runtime/Collector.cpp',
  55     'runtime/Completion.cpp',
  56     'runtime/CommonIdentifiers.cpp',
  57     'runtime/ConstructData.cpp',
  58     'runtime/DateConstructor.cpp',
  59     'runtime/DateInstance.cpp',
  60     'runtime/DateMath.cpp',
  61     'runtime/DatePrototype.cpp',
  62     'runtime/Error.cpp',
  63     'runtime/ErrorConstructor.cpp',
  64     'runtime/ErrorInstance.cpp',
  65     'runtime/ErrorPrototype.cpp',
  66     'runtime/ExceptionHelpers.cpp',
  67     'runtime/FunctionConstructor.cpp',
  68     'runtime/FunctionPrototype.cpp',
  69     'runtime/GetterSetter.cpp',
  70     'runtime/GlobalEvalFunction.cpp',
  71     'runtime/Identifier.cpp',
  72     'runtime/InitializeThreading.cpp',
  73     'runtime/InternalFunction.cpp',
  74     'runtime/JSActivation.cpp',
  75     'runtime/JSArray.cpp',
  76     'runtime/JSByteArray.cpp',
  77     'runtime/JSCell.cpp',
  78     'runtime/JSFunction.cpp',
  79     'runtime/JSGlobalData.cpp',
  80     'runtime/JSGlobalObject.cpp',
  81     'runtime/JSGlobalObjectFunctions.cpp',
  82     'runtime/JSImmediate.cpp',
  83     'runtime/JSLock.cpp',
  84     'runtime/JSNotAnObject.cpp',
  85     'runtime/JSNumberCell.cpp',
  86     'runtime/JSObject.cpp',
  87     'runtime/JSPropertyNameIterator.cpp',
  88     'runtime/JSStaticScopeObject.cpp',
  89     'runtime/JSString.cpp',
  90     'runtime/JSValue.cpp',
  91     'runtime/JSVariableObject.cpp',
  92     'runtime/JSWrapperObject.cpp',
  93     'runtime/Lookup.cpp',
  94     'runtime/MathObject.cpp',
  95     'runtime/NativeErrorConstructor.cpp',
  96     'runtime/NativeErrorPrototype.cpp',
  97     'runtime/NumberConstructor.cpp',
  98     'runtime/NumberObject.cpp',
  99     'runtime/NumberPrototype.cpp',
 100     'runtime/ObjectConstructor.cpp',
 101     'runtime/ObjectPrototype.cpp',
 102     'runtime/Operations.cpp',
 103     'runtime/PropertyNameArray.cpp',
 104     'runtime/PropertySlot.cpp',
 105     'runtime/PrototypeFunction.cpp',
 106     'runtime/RegExp.cpp',
 107     'runtime/RegExpConstructor.cpp',
 108     'runtime/RegExpObject.cpp',
 109     'runtime/RegExpPrototype.cpp',
 110     'runtime/ScopeChain.cpp',
 111     'runtime/SmallStrings.cpp',
 112     'runtime/StringConstructor.cpp',
 113     'runtime/StringObject.cpp',
 114     'runtime/StringPrototype.cpp',
 115     'runtime/Structure.cpp',
 116     'runtime/StructureChain.cpp',
 117     'runtime/UString.cpp',
 118 ]
 119 sources['bytecode'] = [
 120     'bytecode/CodeBlock.cpp',
 121     'bytecode/StructureStubInfo.cpp',
 122     'bytecode/JumpTable.cpp',
 123     'bytecode/Opcode.cpp',
 124     'bytecode/SamplingTool.cpp',
 125 ]
 126 sources['interpreter'] = [
 127     'interpreter/CallFrame.cpp',
 128     'interpreter/Interpreter.cpp',
 129     'interpreter/RegisterFile.cpp',
 130 ]
 131 sources['jit'] = [
 132     'jit/ExecutableAllocator.cpp',
 133     'jit/JIT.cpp',
 134 ]
 135 sources['wrec'] = [
 136     'wrec/CharacterClass.cpp',
 137     'wrec/CharacterClassConstructor.cpp',
 138     'wrec/WREC.cpp',
 139     'wrec/WRECFunctors.cpp',
 140     'wrec/WRECGenerator.cpp',
 141     'wrec/WRECParser.cpp',
 142 ]
 143 sources['wtf'] = [
 144     'wtf/Assertions.cpp',
 145     'wtf/ByteArray.cpp',
 146     'wtf/CurrentTime.cpp',
 147     'wtf/FastMalloc.cpp',
 148     'wtf/HashTable.cpp',
 149     'wtf/RandomNumber.cpp',
 150     'wtf/RefCountedLeakCounter.cpp',
 151     'wtf/Threading.cpp',
 152     'wtf/dtoa.cpp',
 153 ]
 154 sources['wtf/unicode'] = [
 155     'wtf/unicode/CollatorDefault.cpp',
 156     'wtf/unicode/UTF8.cpp',
 157 ]
 158 sources['wtf/unicode/icu'] = [
 159     'wtf/unicode/icu/CollatorICU.cpp',
 160 ]
 161
 162 env = Environment()
 163
 164 building_on_win32 = env['PLATFORM'] == 'win32' or env['PLATFORM'] == 'cygwin'
 165
 166 # Scons uses gcc when building under cygwin by default
 167 # We also have to manually force 8.0 or Scons will try and
 168 # look up what version to use using the registry and fail
 169 # due to lack of cygwin-python registry support
 170 if env['PLATFORM'] == 'cygwin':
 171     env['MSVS_VERSION'] = '8.0'
 172     # Some systems have PROGRAMFILES, some have ProgramFiles
 173     # Scons msvc tool only expects 'ProgramFiles'
 174     import os
 175     if os.getenv('PROGRAMFILES') and not os.getenv('ProgramFiles'):
 176         os.environ['ProgramFiles'] = os.getenv('PROGRAMFILES')
 177
 178     env.Tool('msvc')
 179     env.Tool('mslink')
 180     env.Tool('mslib')
 181
 182 # Scons is failing to carry the %PATH% value through correctly
 183 # Hack IncrediBuild into our path so cl.exe doesn't crash
 184 if env['PLATFORM'] == 'win32':
 185     env.AppendENVPath('PATH', 'c:/Program Files/Xoreax/IncrediBuild')
 186
 187 if env['PLATFORM'] == 'darwin':
 188     sources['API'].append('API/JSStringRefCF.cpp')
 189     sources['profiler'].append('profiler/ProfilerServer.mm')
 190     sources['wtf'].append('wtf/ThreadingPthreads.cpp')
 191     sources['wtf'].append('wtf/MainThread.cpp')
 192     sources['wtf/mac'] = ['wtf/mac/MainThreadMac.mm']
 193     sources['wtf'].append('wtf/TCSystemAlloc.cpp')
 194     sources['jit'].append('jit/ExecutableAllocatorPosix.cpp')
 195 elif building_on_win32:
 196     sources['wtf'].append('wtf/ThreadingNone.cpp')
 197     sources['jit'].append('jit/ExecutableAllocatorWin.cpp')
 198     env.Append(CPPDEFINES = ['ENABLE_JSC_MULTIPLE_THREADS=0'])
 199
 200 derived_sources_path = 'DerivedSources/JavaScriptCore/'
 201 def DerivedSources(path):
 202     return derived_sources_path + path
 203
 204 derived_sources_results = map(DerivedSources, [
 205     'ArrayPrototype.lut.h',
 206     'DatePrototype.lut.h',
 207     'MathObject.lut.h',
 208     'NumberConstructor.lut.h',
 209     'RegExpConstructor.lut.h',
 210     'RegExpObject.lut.h',
 211     'StringPrototype.lut.h'
 212     'chartables.c',
 213     'grammar.cpp',
 214     'grammar.h',
 215     'lexer.lut.h',
 216 ])
 217
 218 derived_sources_sources = [
 219     'runtime/ArrayPrototype.cpp',
 220     'runtime/DatePrototype.cpp',
 221     'runtime/MathObject.cpp',
 222     'runtime/NumberConstructor.cpp',
 223     'runtime/RegExpConstructor.cpp',
 224     'runtime/RegExpObject.cpp',
 225     'runtime/StringPrototype.cpp',
 226     'parser/Grammar.y',
 227     'parser/Lexer.cpp',
 228 ]
 229
 230 # Generate DerivedSources
 231 # Make sure Windows knows where bash (and all the other cygwin commands) live
 232 if env['PLATFORM'] == 'win32':
 233     env.AppendENVPath('PATH', 'C:/cygwin/bin')
 234 env.Command(derived_sources_results, derived_sources_sources, 'bash make-generated-sources.sh')
 235 sources[derived_sources_path] = [DerivedSources('Grammar.cpp')]
 236
 237 # Handle os-version specific build settings
 238 if env['PLATFORM'] == 'darwin':
 239     from subprocess import Popen, PIPE
 240     version_pieces = Popen(["sw_vers", "-productVersion"], stdout = PIPE).communicate()[0].split('.')
 241     if map(int, version_pieces)[:2] > (10, 5):
 242         # Dtrace doesn't exist in Tiger, and was broken in Leopard
 243         env.Command(DerivedSources('TracingDtrace.h'), 'runtime/Tracing.d', '/usr/sbin/dtrace -h -o $TARGET -s $SOURCE')
 244
 245 # This build file builds the Chromium port for now, support for
 246 # others could be added later.
 247 env.Append(CPPDEFINES = ['BUILDING_CHROMIUM__'])
 248
 249 # I'm not certain how many of these windows defines are actually required.
 250 if building_on_win32:
 251     env.Append(CPPDEFINES = ['_WIN32_WINNT=0x0600', 'WINVER=0x0600', 'WIN32', '_WINDOWS', 'NOMINMAX', 'UNICODE', '_UNICODE', '__STD_C', '_HAS_EXCEPTIONS=0'])
 252
 253 # Scons out-of-the-box only supports precompiled headers for MSVC
 254 # remove this when we fix Scons to understand GCC precompiled headers
 255 if env['CC'] == 'gcc':
 256     env['CCFLAGS'] = '-include JavaScriptCorePrefix.h'
 257 # Turns out the MSVC PCH support is badly broken
 258 # env['PCH'] = 'JavaScriptCorePrefix.h'
 259 # env['PCHSTOP'] = 'JavaScriptCorePrefix.h'
 260
 261 if env['PLATFORM'] == 'darwin':
 262     env['FRAMEWORKS'] = ['CoreFoundation', 'Foundation']
 263     env['LIBS'] = ['icucore']
 264     # Apple does not ship the ICU headers with Mac OS X, so WebKit includes a copy of 3.2 headers
 265     env.Append(CPPPATH = 'icu')
 266
 267 webkit_libraries_path = "../WebKitLibraries/win/"
 268 def WebKitLibraries(path):
 269     return webkit_libraries_path + path
 270
 271 include_paths = ['.', '..', 'ForwardingHeaders'] + sources.keys()
 272 env.Append(CPPPATH = include_paths)
 273 if building_on_win32:
 274     env.Append(CPPPATH = ['os-win32', WebKitLibraries('include')])
 275     env.Prepend(LIBPATH = [WebKitLibraries('lib')])
 276     env.Append(LIBS = ['icuin', 'icuuc', 'user32', 'winmm'])
 277
 278 # Save off a copy of the environment for use with jsc
 279 jsc_env = env.Clone()
 280
 281 if building_on_win32:
 282     env.StaticLibrary("JavaScriptCore", sources.values())
 283 else:
 284     env.SharedLibrary("JavaScriptCore", sources.values())
 285
 286
 287 env = jsc_env
 288
 289 # Build the jsc testing shell
 290 shell_sources = ['jsc.cpp']
 291 build_directory = '.' # This should be changed to point to wherever JavaScriptCore gets built to
 292
 293 # It's hacky to re-use the same environment from JavaScriptCore
 294 # but it makes building on windows easier for now
 295 env['CPPPATH'] = include_paths
 296 env['LIBS'] = ['JavaScriptCore']
 297 env['LIBPATH'] = [build_directory]
 298
 299 if env['PLATFORM'] == 'darwin':
 300     env.Append(LIBS = ['edit'])
 301     env.Append(CPPPATH = 'icu')
 302 elif building_on_win32:
 303     env.Append(CPPPATH = ['os-win32', WebKitLibraries('include')])
 304     env.Prepend(LIBPATH = [WebKitLibraries('lib')])
 305     env.Append(LIBS = ['icuin', 'icuuc', 'user32', 'winmm'])
 306
 307 env.Program('jsc', shell_sources)