icuSources/data/translit/es_es_FONIPA.txt

   1 # ***************************************************************************
   2 # *
   3 # *  Copyright (C) 2004-2010, International Business Machines
   4 # *  Corporation; Unicode, Inc.; and others.  All Rights Reserved.
   5 # *
   6 # ***************************************************************************
   7 # File: es_es_FONIPA.txt
   8 # Generated from CLDR
   9 #
  10 $bow = [-\ $] ;  # Beginning of word.
  11 $consonant = [bβdðfgɣʝklʎmnŋɲθprɾstʧx] ;
  12 $syll = '.' ;    # Syllable boundary.
  13 ::NFC;
  14 ::Lower;
  15 $bow { ct → | t ;  # ctónico (?)
  16 $bow { cz → | z ;  # czar
  17 $bow { gn → | n ;  # gnomo
  18 $bow { mn → | n ;  # mnemotécnico
  19 $bow { ps → | s ;  # psicología
  20 $bow { pt → | t ;  # pterodáctilo
  21 $bow { x  → | s ;  # xilófono
  22 $bow       { i                 → i ;
  23 $consonant { i } [ aáeé  oóuú] → j ;
  24 [aeo]      { i } [^aáeé  oóuú] → i\u032F ;
  25 i } [ aáeé  oóuú] → ʝ ;
  26 i                 → i ;
  27 [aeo]      { y } [^aáeéiíoóuú] → i\u032F ;
  28 y } [ aáeéiíoóuú] → ʝ ;
  29 y                 → i ;
  30 [aeo]      { u } [^aáeéiíoó  ] → u\u032F ;
  31 u } [ aáeéiíoó  ] → w ;
  32 ü } [   eéií    ] → w ;
  33 u                 → u ;
  34 ü                 → u ;  # Should not be needed, but just in case.
  35 [aá] → a ;
  36 [eé] → e ;
  37 í    → i ;
  38 [oó] → o ;
  39 ú    → u ;
  40 b → β ;
  41 cch → ʧ ;
  42 ch → ʧ ;
  43 cc } [^eéií] → k ;
  44 c } [eéií] → θ ;
  45 c → k ;
  46 d → ð ;
  47 f → f;
  48 gu } [eéiíy] → ɣ ;
  49 g } [eéiíy] → x ;
  50 g → ɣ ;
  51 hi } [aáeéoóuú] → ʝ ;
  52 h → $syll ;
  53 j → x ;
  54 k → k ;
  55 ll → ʎ ;
  56 l → l ;
  57 m → m ;
  58 n → n ;
  59 ñ → ɲ ;
  60 p → p ;
  61 qu } [eéiíy] → k ;
  62 q → k ;
  63 [-\ lns$] { r → r ;
  64 rr → r ;
  65 r → ɾ ;
  66 ss → s ;
  67 s → s ;
  68 tx → ʧ ;  # for loanwords from Basque, Catalan
  69 t → t ;
  70 v → β ;
  71 w → $syll w ;
  72 x } h?[aáeéiíoóuú$] → ks ;
  73 x } [^aáeéiíoóuú$] → s ;
  74 x → ks ;
  75 z → θ ;
  76 ::Null;
  77 [-\ ] → ;
  78 [mnɲŋ  $] { β → b ;
  79 [mnɲŋlʎ$] { ð → d ;
  80 [mnɲŋ  $] { ɣ → g ;
  81 n } [gɣk] → ŋ ;
  82 ::NFC;