icuSources/data/brkitr/rules/line_loose.txt

   1 # Copyright (C) 2016 and later: Unicode, Inc. and others.
   2 # License & terms of use: http://www.unicode.org/copyright.html
   3 # Copyright (c) 2002-2016  International Business Machines Corporation and
   4 # others. All Rights Reserved.
   5 #
   6 #  file:  line_loose.txt
   7 #
   8 #         Line Breaking Rules
   9 #         Implement default line breaking as defined by
  10 #         Unicode Standard Annex #14 Revision 37 for Unicode 9.0
  11 #         http://www.unicode.org/reports/tr14/
  12 #
  13 #         Includes extensions to the handling of emoji ZWJ sequences from
  14 #         https://goo.gl/cluFCn
  15 #
  16 #         tailored as noted in 2nd paragraph below.
  17 #
  18 #         TODO:  Rule LB 8 remains as it was in Unicode 5.2
  19 #         This is only because of a limitation of ICU break engine implementation,
  20 #         not because the older behavior is desirable.
  21 #
  22 #         This tailors the line break behavior to correspond to CSS
  23 #         line-break=loose (BCP47 -u-lb-loose) as defined for languages other than
  24 #         Chinese & Japanese.
  25 #         It sets characters of class CJ to behave like ID.
  26 #         In addition, it allows breaks:
  27 #         * before iteration marks 3005, 303B, 309D, 309E, 30FD, 30FE (all NS)
  28 #         * between characters of LineBreak class IN
  29
  30 #
  31 #  Character Classes defined by TR 14.
  32 #
  33
  34 !!chain;
  35
  36 $AI = [:LineBreak =  Ambiguous:];
  37 $AL = [:LineBreak =  Alphabetic:];
  38 $BA = [:LineBreak =  Break_After:];
  39 $BB = [:LineBreak =  Break_Before:];
  40 $BK = [:LineBreak =  Mandatory_Break:];
  41 $B2 = [:LineBreak =  Break_Both:];
  42 $CB = [:LineBreak =  Contingent_Break:];
  43 $CJ = [:LineBreak =  Conditional_Japanese_Starter:];
  44 $CL = [:LineBreak =  Close_Punctuation:];
  45 # $CM = [:LineBreak =  Combining_Mark:];
  46 $CP = [:LineBreak =  Close_Parenthesis:];
  47 $CR = [:LineBreak =  Carriage_Return:];
  48 $EB = [[:LineBreak =  EB:] \U0001F46A-\U0001F46D\U0001F46F\U0001F91D\U0001F93C];
  49 $EM = [:LineBreak =  EM:];
  50 $EX = [:LineBreak =  Exclamation:];
  51 $GL = [:LineBreak =  Glue:];
  52 $HL = [:LineBreak =  Hebrew_Letter:];
  53 $HY = [:LineBreak =  Hyphen:];
  54 $H2 = [:LineBreak =  H2:];
  55 $H3 = [:LineBreak =  H3:];
  56 # CSS Loose tailoring: CJ resolves to ID
  57 $ID = [[:LineBreak =  Ideographic:] $CJ];
  58 $IN = [:LineBreak =  Inseperable:];
  59 $IS = [:LineBreak =  Infix_Numeric:];
  60 $JL = [:LineBreak =  JL:];
  61 $JV = [:LineBreak =  JV:];
  62 $JT = [:LineBreak =  JT:];
  63 $LF = [:LineBreak =  Line_Feed:];
  64 $NL = [:LineBreak =  Next_Line:];
  65 $NSX = [\u3005 \u303B \u309D \u309E \u30FD \u30FE];
  66 $NS = [[:LineBreak =  Nonstarter:] - $NSX];
  67 $NU = [:LineBreak =  Numeric:];
  68 $OP = [:LineBreak =  Open_Punctuation:];
  69 $PO = [:LineBreak =  Postfix_Numeric:];
  70 $PR = [:LineBreak =  Prefix_Numeric:];
  71 $QU = [:LineBreak =  Quotation:];
  72 $RI = [:LineBreak =  Regional_Indicator:];
  73 $SA = [:LineBreak =  Complex_Context:];
  74 $SG = [:LineBreak =  Surrogate:];
  75 $SP = [:LineBreak =  Space:];
  76 $SY = [:LineBreak =  Break_Symbols:];
  77 $WJ = [:LineBreak =  Word_Joiner:];
  78 $XX = [:LineBreak =  Unknown:];
  79 $ZW = [:LineBreak =  ZWSpace:];
  80 $ZWJ = [:LineBreak = ZWJ:];
  81
  82 $EmojiNRK = [[\p{Emoji}] - [$RI \u002a\u00230-9©®™〰〽]];
  83 # Data for Extended Pictographic scraped from CLDR common/properties/ExtendedPictographic.txt, r13267
  84 $Extended_Pict = [\U0001F774-\U0001F77F\U00002700-\U00002701\U00002703-\U00002704\U0000270E\U00002710-\U00002711\U00002765-\U00002767\U0001F030-\U0001F093\U0001F094-\U0001F09F\U0001F10D-\U0001F10F\U0001F12F\U0001F16C-\U0001F16F\U0001F1AD-\U0001F1E5\U0001F260-\U0001F265\U0001F203-\U0001F20F\U0001F23C-\U0001F23F\U0001F249-\U0001F24F\U0001F252-\U0001F25F\U0001F266-\U0001F2FF\U0001F7D5-\U0001F7FF\U0001F000-\U0001F003\U0001F005-\U0001F02B\U0001F02C-\U0001F02F\U0001F322-\U0001F323\U0001F394-\U0001F395\U0001F398\U0001F39C-\U0001F39D\U0001F3F1-\U0001F3F2\U0001F3F6\U0001F4FE\U0001F53E-\U0001F548\U0001F54F\U0001F568-\U0001F56E\U0001F571-\U0001F572\U0001F57B-\U0001F586\U0001F588-\U0001F589\U0001F58E-\U0001F58F\U0001F591-\U0001F594\U0001F597-\U0001F5A3\U0001F5A6-\U0001F5A7\U0001F5A9-\U0001F5B0\U0001F5B3-\U0001F5BB\U0001F5BD-\U0001F5C1\U0001F5C5-\U0001F5D0\U0001F5D4-\U0001F5DB\U0001F5DF-\U0001F5E0\U0001F5E2\U0001F5E4-\U0001F5E7\U0001F5E9-\U0001F5EE\U0001F5F0-\U0001F5F2\U0001F5F4-\U0001F5F9\U00002605\U00002607-\U0000260D\U0000260F-\U00002610\U00002612\U00002616-\U00002617\U00002619-\U0000261C\U0000261E-\U0000261F\U00002621\U00002624-\U00002625\U00002627-\U00002629\U0000262B-\U0000262D\U00002630-\U00002637\U0000263B-\U00002647\U00002654-\U0000265F\U00002661-\U00002662\U00002664\U00002667\U00002669-\U0000267A\U0000267C-\U0000267E\U00002680-\U00002691\U00002695\U00002698\U0000269A\U0000269D-\U0000269F\U000026A2-\U000026A9\U000026AC-\U000026AF\U000026B2-\U000026BC\U000026BF-\U000026C3\U000026C6-\U000026C7\U000026C9-\U000026CD\U000026D0\U000026D2\U000026D5-\U000026E8\U000026EB-\U000026EF\U000026F6\U000026FB-\U000026FC\U000026FE-\U000026FF\U00002388\U0001FA00-\U0001FFFD\U0001F0A0-\U0001F0AE\U0001F0B1-\U0001F0BF\U0001F0C1-\U0001F0CF\U0001F0D1-\U0001F0F5\U0001F0AF-\U0001F0B0\U0001F0C0\U0001F0D0\U0001F0F6-\U0001F0FF\U0001F80C-\U0001F80F\U0001F848-\U0001F84F\U0001F85A-\U0001F85F\U0001F888-\U0001F88F\U0001F8AE-\U0001F8FF\U0001F900-\U0001F90B\U0001F91F\U0001F928-\U0001F92F\U0001F931-\U0001F932\U0001F94C\U0001F95F-\U0001F96B\U0001F992-\U0001F997\U0001F9D0-\U0001F9E6\U0001F90C-\U0001F90F\U0001F93F\U0001F94D-\U0001F94F\U0001F96C-\U0001F97F\U0001F998-\U0001F9BF\U0001F9C1-\U0001F9CF\U0001F9E7-\U0001F9FF\U0001F6C6-\U0001F6CA\U0001F6D3-\U0001F6D4\U0001F6E6-\U0001F6E8\U0001F6EA\U0001F6F1-\U0001F6F2\U0001F6F7-\U0001F6F8\U0001F6D5-\U0001F6DF\U0001F6ED-\U0001F6EF\U0001F6F9-\U0001F6FF];
  85
  86 # By LB9, a ZWJ also behaves as a CM. Including it in the definition of CM avoids having to explicitly
  87 #         list it in the numerous rules that use CM.
  88 # By LB1, SA characters with general categor of Mn or Mc also resolve to CM.
  89
  90 $CM = [[:LineBreak = Combining_Mark:] $ZWJ [$SA & [[:Mn:][:Mc:]]]];
  91
  92 #   Dictionary character set, for triggering language-based break engines. Currently
  93 #   limited to LineBreak=Complex_Context (SA).
  94
  95 $dictionary = [$SA];
  96
  97 #
  98 #  Rule LB1.  By default, treat AI  (characters with ambiguous east Asian width),
  99 #                               SA  (Dictionary chars, excluding Mn and Mc)
 100 #                               SG  (Unpaired Surrogates)
 101 #                               XX  (Unknown, unassigned)
 102 #                         as $AL  (Alphabetic)
 103 #
 104 $ALPlus = [$AL $AI $SG $XX [$SA-[[:Mn:][:Mc:]]]];
 105
 106
 107 ## -------------------------------------------------
 108
 109 !!forward;
 110
 111 #
 112 # CAN_CM  is the set of characters that may combine with CM combining chars.
 113 #         Note that Linebreak UAX 14's concept of a combining char and the rules
 114 #         for what they can combine with are _very_ different from the rest of Unicode.
 115 #
 116 #         Note that $CM itself is left out of this set.  If CM is needed as a base
 117 #         it must be listed separately in the rule.
 118 #
 119 $CAN_CM  = [^$SP $BK $CR $LF $NL $ZW $CM];       # Bases that can   take CMs
 120 $CANT_CM = [ $SP $BK $CR $LF $NL $ZW $CM];       # Bases that can't take CMs
 121
 122 #
 123 # AL_FOLLOW  set of chars that can unconditionally follow an AL
 124 #            Needed in rules where stand-alone $CM s are treated as AL.
 125 #
 126 $AL_FOLLOW      = [$BK $CR $LF $NL $ZW $SP $CL $CP $EX $HL $IS $SY $WJ $GL $OP $QU $BA $HY $NS $IN $NU $PR $PO $ALPlus];
 127
 128
 129 #
 130 #  Rule LB 4, 5    Mandatory (Hard) breaks.
 131 #
 132 $LB4Breaks    = [$BK $CR $LF $NL];
 133 $LB4NonBreaks = [^$BK $CR $LF $NL $CM];
 134 $CR $LF {100};
 135
 136 #
 137 #  LB 6    Do not break before hard line breaks.
 138 #
 139 $LB4NonBreaks?  $LB4Breaks {100};    # LB 5  do not break before hard breaks.
 140 $CAN_CM $CM*    $LB4Breaks {100};
 141 ^$CM+           $LB4Breaks {100};
 142
 143 # LB 7         x SP
 144 #              x ZW
 145 $LB4NonBreaks [$SP $ZW];
 146 $CAN_CM $CM*  [$SP $ZW];
 147 ^$CM+         [$SP $ZW];
 148
 149 #
 150 # LB 8         Break after zero width space
 151 #              TODO:  ZW SP* <break>
 152 #              An engine change is required to write the reverse rule for this.
 153 #              For now, leave the Unicode 5.2 rule, ZW <break>
 154 #
 155 $LB8Breaks    = [$LB4Breaks $ZW];
 156 $LB8NonBreaks = [[$LB4NonBreaks] - [$ZW]];
 157
 158 # LB 8a        ZWJ x (ID | Extended_Pict | EmojiNRK)   Emoji ZWJ sequences.
 159 #
 160 $ZWJ ($ID | $Extended_Pict | $EmojiNRK);
 161
 162 # LB 9     Combining marks.      X   $CM needs to behave like X, where X is not $SP, $BK $CR $LF $NL
 163 #                                $CM not covered by the above needs to behave like $AL
 164 #                                See definition of $CAN_CM.
 165
 166 $CAN_CM $CM+;                   #  Stick together any combining sequences that don't match other rules.
 167 ^$CM+;
 168
 169 #
 170 # LB 11  Do not break before or after WORD JOINER & related characters.
 171 #
 172 $CAN_CM $CM*  $WJ;
 173 $LB8NonBreaks $WJ;
 174 ^$CM+         $WJ;
 175
 176 $WJ $CM* .;
 177
 178 #
 179 # LB 12  Do not break after NBSP and related characters.
 180 #         GL  x
 181 #
 182 $GL $CM* .;
 183
 184 #
 185 # LB 12a  Do not break before NBSP and related characters ...
 186 #            [^SP BA HY] x GL
 187 #
 188 [[$LB8NonBreaks] - [$SP $BA $HY]] $CM* $GL;
 189 ^$CM+ $GL;
 190
 191
 192
 193 #
 194 # LB 13   Don't break before ']' or '!' or ';' or '/', even after spaces.
 195 #
 196 $LB8NonBreaks $CL;
 197 $CAN_CM $CM*  $CL;
 198 ^$CM+         $CL;              # by rule 10, stand-alone CM behaves as AL
 199
 200 $LB8NonBreaks $CP;
 201 $CAN_CM $CM*  $CP;
 202 ^$CM+         $CP;              # by rule 10, stand-alone CM behaves as AL
 203
 204 $LB8NonBreaks $EX;
 205 $CAN_CM $CM*  $EX;
 206 ^$CM+         $EX;              # by rule 10, stand-alone CM behaves as AL
 207
 208 $LB8NonBreaks $IS;
 209 $CAN_CM $CM*  $IS;
 210 ^$CM+         $IS;              # by rule 10, stand-alone CM behaves as AL
 211
 212 $LB8NonBreaks $SY;
 213 $CAN_CM $CM*  $SY;
 214 ^$CM+         $SY;              # by rule 10, stand-alone CM behaves as AL
 215
 216
 217 #
 218 # LB 14  Do not break after OP, even after spaces
 219 #
 220 $OP $CM* $SP* .;
 221
 222 $OP $CM* $SP+ $CM+ $AL_FOLLOW?;    # by rule 10, stand-alone CM behaves as AL
 223                                    # by rule 8, CM following a SP is stand-alone.
 224
 225 # LB 15
 226 $QU $CM* $SP* $OP;
 227
 228 # LB 16
 229 # Do not break between closing punctuation and $NS, even with intervening spaces
 230 # But DO allow a break between closing punctuation and $NSX, don't include it here
 231 ($CL | $CP) $CM* $SP* $NS;
 232
 233 # LB 17
 234 $B2 $CM* $SP* $B2;
 235
 236 #
 237 # LB 18  Break after spaces.
 238 #
 239 $LB18NonBreaks = [$LB8NonBreaks - [$SP]];
 240 $LB18Breaks    = [$LB8Breaks $SP];
 241
 242
 243 # LB 19
 244 #         x QU
 245 $LB18NonBreaks $CM* $QU;
 246 ^$CM+               $QU;
 247
 248 #         QU  x
 249 $QU $CM* .;
 250
 251
 252 # LB 20
 253 #        <break>  $CB
 254 #        $CB   <break>
 255
 256 $LB20NonBreaks = [$LB18NonBreaks - $CB];
 257
 258 # LB 21        x   (BA | HY | NS)
 259 #           BB x
 260 #
 261 # DO allow breaks here before NSX, so don't include it
 262 $LB20NonBreaks $CM* ($BA | $HY | $NS);
 263 ^$CM+ ($BA | $HY | $NS);
 264
 265 $BB $CM* [^$CB];                                  #  $BB  x
 266 $BB $CM* $LB20NonBreaks;
 267
 268 # LB 21a Don't break after Hebrew + Hyphen
 269 #   HL (HY | BA) x
 270 #
 271 $HL $CM* ($HY | $BA) $CM* [^$CB]?;
 272
 273 # LB 21b (forward) Don't break between SY and HL
 274 # (break between HL and SY already disallowed by LB 13 above)
 275 $SY $CM* $HL;
 276
 277 # LB 22
 278 ($ALPlus | $HL) $CM* $IN;
 279 ^$CM+    $IN;     #  by rule 10, any otherwise unattached CM behaves as AL
 280 $EX $CM*    $IN;
 281 ($ID | $EB | $EM) $CM*  $IN;
 282 # $IN $CM*    $IN;  # delete this rule for CSS loose
 283 $NU $CM*    $IN;
 284
 285
 286 # $LB 23
 287 #
 288 ($ALPlus | $HL) $CM* $NU;
 289 ^$CM+  $NU;       # Rule 10, any otherwise unattached CM behaves as AL
 290 $NU $CM* ($ALPlus | $HL);
 291
 292 # LB 23a
 293 #
 294 $PR $CM* ($ID | $EB | $EM);
 295 ($ID | $EB | $EM) $CM*  $PO;
 296
 297
 298 #
 299 # LB 24
 300 #
 301 ($PR | $PO) $CM* ($ALPlus | $HL);
 302 ($ALPlus | $HL) $CM* ($PR | $PO);
 303 ^$CM+ ($PR | $PO);       # Rule 10, any otherwise unattached CM behaves as AL
 304
 305 #
 306 # LB 25   Numbers.
 307 #
 308 (($PR | $PO) $CM*)? (($OP | $HY) $CM*)? $NU ($CM* ($NU | $SY | $IS))*
 309     ($CM* ($CL | $CP))? ($CM* ($PR | $PO))?;
 310
 311 # LB 26  Do not break a Korean syllable
 312 #
 313 $JL $CM* ($JL | $JV | $H2 | $H3);
 314 ($JV | $H2) $CM* ($JV | $JT);
 315 ($JT | $H3) $CM* $JT;
 316
 317 # LB 27  Treat korean Syllable Block the same as ID  (don't break it)
 318 ($JL | $JV | $JT | $H2 | $H3) $CM* $IN;
 319 ($JL | $JV | $JT | $H2 | $H3) $CM* $PO;
 320 $PR $CM* ($JL | $JV | $JT | $H2 | $H3);
 321
 322
 323 # LB 28   Do not break between alphabetics
 324 #
 325 ($ALPlus | $HL) $CM* ($ALPlus | $HL);
 326 ^$CM+ ($ALPlus | $HL);      # The $CM+ is from rule 10, an unattached CM is treated as AL
 327
 328 # LB 29
 329 $IS $CM* ($ALPlus | $HL);
 330
 331 # LB 30
 332 ($ALPlus | $HL | $NU) $CM* $OP;
 333 ^$CM+ $OP;         # The $CM+ is from rule 10, an unattached CM is treated as AL.
 334 $CP $CM* ($ALPlus | $HL | $NU);
 335
 336 # LB 30a  Do not break between regional indicators. Break after pairs of them.
 337 #         Tricky interaction with LB8a: ZWJ x ID
 338 $RI $CM* $RI                / [[^$BK $CR $LF $NL $SP $ZW $WJ $CL $CP $EX $IS $SY $GL $QU $BA $HY $NS $CM] {eof}];
 339 $RI $CM* $RI $CM*  $ZWJ     / [[^$BK $CR $LF $NL $SP $ZW $WJ $CL $CP $EX $IS $SY $GL $QU $BA $HY $NS $CM $ID $Extended_Pict $EmojiNRK] {eof}];
 340 $RI $CM* $RI $CM* [$CM-$ZWJ] / [[^$BK $CR $LF $NL $SP $ZW $WJ $CL $CP $EX $IS $SY $GL $QU $BA $HY $NS $CM] {eof}];
 341
 342 $RI $CM* $RI $CM* [$BK $CR $LF $NL $SP $ZW $WJ $CL $CP $EX $IS $SY $GL $QU $BA $HY $NS {eof}];
 343 $RI $CM* $RI $CM* $ZWJ ($ID | $Extended_Pict | $EmojiNRK);
 344
 345 # LB 30b Do not break between an Emoji Base and an Emoji Modifier
 346 $EB $CM* $EM;
 347
 348 #
 349 #  Reverse Rules.
 350 #
 351 ## -------------------------------------------------
 352
 353 !!reverse;
 354
 355 #  LB 9 Combining Marks.
 356 #  Stick together any combining sequences that don't match other rules.
 357
 358 ^$CM+ $CAN_CM?;
 359
 360 #
 361 #  Sequences of the form  (shown forwards)
 362 #      [CANT_CM]  <break>  [CM]  [whatever]
 363 #  The CM needs to behave as an AL
 364 #
 365 $AL_FOLLOW $CM+ / (
 366           [$BK $CR $LF $NL $ZW {eof}] |
 367           $SP+ $CM+ $SP |
 368           $SP+ $CM* ([^$OP $CM $SP] | [$AL {eof}]));   # if LB 14 will match, need to surpress this break.
 369                                                #  LB14 says    OP SP* x .
 370                                                #    becomes    OP SP* x AL
 371                                                #    becomes    OP SP* x CM+ AL_FOLLOW
 372                                                #
 373                                                # Further note:  the $AL in [$AL {eof}] is only to work around
 374                                                #                a rule compiler bug which complains about
 375                                                #                empty sets otherwise.
 376
 377
 378 # LB 4, 5, 6
 379
 380 $LB4Breaks [$LB4NonBreaks-$CM];
 381 $LB4Breaks $CM+ $CAN_CM;
 382 $LF $CR;
 383
 384
 385 # LB 7         x SP
 386 #              x ZW
 387 [$SP $ZW] [$LB4NonBreaks-$CM];
 388 [$SP $ZW] $CM+ $CAN_CM;
 389
 390 # LB 8 ZW SP* <break>
 391 #     TODO: to implement this, we need more than one look-ahead hard break in play at a time.
 392 #           Requires an engine enhancement.
 393 #   / $SP* $ZW
 394
 395 # LB 8a        ZWJ x (ID | Extended_Pict | EmojiNRK)
 396 #
 397 ($ID | $Extended_Pict | $EmojiNRK) $ZWJ $CM* $CAN_CM?;
 398
 399
 400 # LB 9,10  Combining marks.
 401 #    X   $CM needs to behave like X, where X is not $SP or controls.
 402 #    $CM not covered by the above needs to behave like $AL
 403 # Stick together any combining sequences that don't match other rules.
 404 ^$CM+ $CAN_CM;
 405
 406
 407 # LB 11
 408 #
 409 $WJ $CM* $CAN_CM;
 410 $WJ      [$LB8NonBreaks-$CM];
 411
 412      $CANT_CM $CM* $WJ;
 413 $CAN_CM  $CM* $WJ;
 414
 415 # LB 12a
 416 #      [^SP BA HY] x GL
 417 #
 418 $GL $CM* [$LB8NonBreaks-[$CM $SP $BA $HY]];
 419
 420 # LB 12
 421 #     GL  x
 422 #
 423 $CANT_CM $CM* $GL;
 424 $CAN_CM $CM* $GL;
 425
 426
 427 # LB 13
 428 $CL $CM+ $CAN_CM;
 429 $CP $CM+ $CAN_CM;
 430 $EX $CM+ $CAN_CM;
 431 $IS $CM+ $CAN_CM;
 432 $SY $CM+ $CAN_CM;
 433
 434 $CL [$LB8NonBreaks-$CM];
 435 $CP [$LB8NonBreaks-$CM];
 436 $EX [$LB8NonBreaks-$CM];
 437 $IS [$LB8NonBreaks-$CM];
 438 $SY [$LB8NonBreaks-$CM];
 439
 440
 441 # LB 14    OP SP* x
 442 #
 443 .   $SP* $CM* $OP;
 444 $AL_FOLLOW? $CM+ $SP+ $CM* $OP;     #  by LB 10, behaves like $AL_FOLLOW? $AL $SP+ $CM* $OP
 445
 446
 447 # LB 15
 448 $OP $SP* $CM* $QU;
 449
 450 # LB 16
 451 # Don't include $NSX here
 452 $NS $SP* $CM* ($CL | $CP);
 453
 454 # LB 17
 455 $B2 $SP* $CM* $B2;
 456
 457 # LB 18  break after spaces
 458 #        Nothing explicit needed here.
 459
 460
 461 #
 462 # LB 19
 463 #
 464 $QU $CM* $CAN_CM;                                #   . x QU
 465 $QU      $LB18NonBreaks;
 466
 467
 468 $CAN_CM  $CM* $QU;                               #   QU x .
 469      $CANT_CM $CM* $QU;
 470
 471 #
 472 #  LB 20  Break before and after CB.
 473 #         nothing needed here.
 474 #
 475
 476 # LB 21
 477 # Don't include $NSX here
 478 ($BA | $HY | $NS) $CM* [$LB20NonBreaks-$CM];     #  . x (BA | HY | NS)
 479
 480 [$LB20NonBreaks-$CM] $CM* $BB;                   #  BB x .
 481 [^$CB] $CM* $BB;                                      #
 482
 483 # LB21a
 484 [^$CB] $CM* ($HY | $BA) $CM* $HL;
 485
 486 # LB21b (reverse)
 487 $HL $CM* $SY;
 488
 489 # LB 22
 490 $IN $CM* ($ALPlus | $HL);
 491 $IN $CM* $EX;
 492 $IN $CM* ($ID | $EB | $EM);
 493 # $IN $CM* $IN; # delete this rule for CSS loose
 494 $IN $CM* $NU;
 495
 496 # LB 23
 497 $NU $CM* ($ALPlus | $HL);
 498 ($ALPlus | $HL) $CM* $NU;
 499
 500 # LB23a
 501 ($ID | $EB | $EM) $CM* $PR;
 502 $PO $CM* ($ID | $EB | $EM);
 503
 504 # LB 24
 505 ($ALPlus | $HL) $CM* ($PR | $PO);
 506 ($PR | $PO) $CM* ($ALPlus | $HL);
 507
 508
 509 # LB 25
 510 ($CM* ($PR | $PO))? ($CM* ($CL | $CP))? ($CM* ($NU | $IS | $SY))* $CM* $NU ($CM* ($OP | $HY))? ($CM* ($PR | $PO))?;
 511
 512 # LB 26
 513 ($H3 | $H2 | $JV | $JL) $CM* $JL;
 514 ($JT | $JV) $CM* ($H2 | $JV);
 515 $JT $CM* ($H3 | $JT);
 516
 517 # LB 27
 518 $IN $CM* ($H3 | $H2 | $JT | $JV | $JL);
 519 $PO $CM* ($H3 | $H2 | $JT | $JV | $JL);
 520  ($H3 | $H2 | $JT | $JV | $JL) $CM* $PR;
 521
 522 # LB 28
 523 ($ALPlus | $HL) $CM* ($ALPlus | $HL);
 524
 525
 526 # LB 29
 527 ($ALPlus | $HL) $CM* $IS;
 528
 529 # LB 30
 530 $OP $CM* ($ALPlus | $HL | $NU);
 531 ($ALPlus | $HL | $NU) $CM* $CP;
 532
 533 # LB 30a
 534 #    Pairs of Regional Indicators.
 535 #    The following two rules are nearly identical. The first matches only sequences with an odd number of adjacent RIs,
 536 #    the second with an even number. Stripping away the cruft they look like
 537 #         [^RI] RI / (RI RI)+ ^RI;
 538 #         [^RI] RI RI / (RI RI)+ ^RI;
 539 #
 540 # Line Loose tailoring: Don't include NSX here.
 541 [{bof} $NS $HY $BA $QU $CL $CP $EX $IS $SY $WJ $GL $ZW $SP $BK $CR $LF $NL $ZWJ] $CM* $RI / ($CM* $RI $CM* $RI)+ $CM* [{eof}[^$RI $CM]];
 542 [{bof} $NS $HY $BA $QU $CL $CP $EX $IS $SY $WJ $GL $ZW $SP $BK $CR $LF $NL $ZWJ] $CM* $RI $CM* $RI / ($CM* $RI $CM* $RI)+ $CM* [{eof}[^$RI $CM]];
 543
 544 # In general, adjacent RIs stay together. The hard-break rules, above, overide this, forcing in the boundaries between pairs.
 545 $RI $CM* $RI;
 546
 547 #    WJ, GL, QU, etc. are classes with rules like "WJ x "   which includes "WJ x RI".
 548 $RI $CM* ([$WJ $GL $QU $BB] |  (($HY | $BA)$CM* $HL));
 549
 550
 551 # LB 30b Do not break between an Emoji Base and an Emoji Modifier
 552 $EM $CM* $EB;
 553
 554
 555 ## -------------------------------------------------
 556
 557 !!safe_reverse;
 558
 559 # LB 9
 560 ^$CM+ [^$CM $BK $CR $LF $NL $ZW $SP];
 561 ^$CM+ $SP / .;
 562
 563 # LB 14
 564 $SP+ $CM* $OP;
 565
 566 # LB 15
 567 $SP+ $CM* $QU;
 568
 569 # LB 16
 570 $SP+ $CM* ($CL | $CP);
 571
 572 # LB 17
 573 $SP+ $CM* $B2;
 574
 575 # LB 21
 576 $CM* ($HY | $BA) $CM* $HL;
 577
 578 # LB 25
 579 ($CM* ($IS | $SY))+ $CM* $NU;
 580 ($CL | $CP) $CM* ($NU | $IS | $SY);
 581
 582 #  LB 30
 583 ($CM* $RI)+;
 584
 585 # For dictionary-based break
 586 $dictionary $dictionary;
 587
 588 ## -------------------------------------------------
 589
 590 !!safe_forward;
 591
 592 # Skip forward over all character classes that are involved in
 593 #   rules containing patterns with possibly more than one char
 594 #   of context.
 595 #
 596 #  It might be slightly more efficient to have specific rules
 597 #  instead of one generic one, but only if we could
 598 #  turn off rule chaining.  We don't want to move more
 599 #  than necessary.
 600 #
 601 ^[$CM $OP $QU $CL $CP $B2 $PR $HY $BA $SP $RI $ZWJ $dictionary]+ [^$CM $OP $QU $CL $CP $B2 $PR $HY $BA $RI $ZWJ $dictionary];
 602 $dictionary $dictionary;
 603