icuSources/data/brkitr/rules/line.txt

   1 # Copyright (C) 2016 and later: Unicode, Inc. and others.
   2 # License & terms of use: http://www.unicode.org/copyright.html
   3 # Copyright (c) 2002-2016  International Business Machines Corporation and
   4 # others. All Rights Reserved.
   5 #
   6 #  file:  line.txt
   7 #
   8 #         Line Breaking Rules
   9 #         Implement default line breaking as defined by
  10 #         Unicode Standard Annex #14 Revision 37 for Unicode 9.0
  11 #         http://www.unicode.org/reports/tr14/
  12 #
  13 #         Includes extensions to the handling of emoji ZWJ sequences from
  14 #         https://goo.gl/cluFCn
  15 #
  16 #         TODO:  Rule LB 8 remains as it was in Unicode 5.2
  17 #         This is only because of a limitation of ICU break engine implementation,
  18 #         not because the older behavior is desirable.
  19 #
  20 #         This corresponds to CSS line-break=strict (BCP47 -u-lb-strict).
  21 #         It sets characters of class CJ to behave like NS.
  22
  23 #
  24 #  Character Classes defined by TR 14.
  25 #
  26
  27 !!chain;
  28
  29 $AI = [:LineBreak =  Ambiguous:];
  30 $AL = [:LineBreak =  Alphabetic:];
  31 $BA = [:LineBreak =  Break_After:];
  32 $BB = [:LineBreak =  Break_Before:];
  33 $BK = [:LineBreak =  Mandatory_Break:];
  34 $B2 = [:LineBreak =  Break_Both:];
  35 $CB = [:LineBreak =  Contingent_Break:];
  36 $CJ = [:LineBreak =  Conditional_Japanese_Starter:];
  37 $CL = [:LineBreak =  Close_Punctuation:];
  38 # $CM = [:LineBreak =  Combining_Mark:];
  39 $CP = [:LineBreak =  Close_Parenthesis:];
  40 $CR = [:LineBreak =  Carriage_Return:];
  41 $EB = [[:LineBreak =  EB:] \U0001F46A-\U0001F46D\U0001F46F\U0001F91D\U0001F93C];
  42 $EM = [:LineBreak =  EM:];
  43 $EX = [:LineBreak =  Exclamation:];
  44 $GL = [:LineBreak =  Glue:];
  45 $HL = [:LineBreak =  Hebrew_Letter:];
  46 $HY = [:LineBreak =  Hyphen:];
  47 $H2 = [:LineBreak =  H2:];
  48 $H3 = [:LineBreak =  H3:];
  49 $ID = [:LineBreak =  Ideographic:];
  50 $IN = [:LineBreak =  Inseperable:];
  51 $IS = [:LineBreak =  Infix_Numeric:];
  52 $JL = [:LineBreak =  JL:];
  53 $JV = [:LineBreak =  JV:];
  54 $JT = [:LineBreak =  JT:];
  55 $LF = [:LineBreak =  Line_Feed:];
  56 $NL = [:LineBreak =  Next_Line:];
  57 # NS includes CJ for CSS strict line breaking.
  58 $NS = [[:LineBreak =  Nonstarter:] $CJ];
  59 $NU = [:LineBreak =  Numeric:];
  60 $OP = [:LineBreak =  Open_Punctuation:];
  61 $PO = [:LineBreak =  Postfix_Numeric:];
  62 $PR = [:LineBreak =  Prefix_Numeric:];
  63 $QU = [:LineBreak =  Quotation:];
  64 $RI = [:LineBreak =  Regional_Indicator:];
  65 $SA = [:LineBreak =  Complex_Context:];
  66 $SG = [:LineBreak =  Surrogate:];
  67 $SP = [:LineBreak =  Space:];
  68 $SY = [:LineBreak =  Break_Symbols:];
  69 $WJ = [:LineBreak =  Word_Joiner:];
  70 $XX = [:LineBreak =  Unknown:];
  71 $ZW = [:LineBreak =  ZWSpace:];
  72 $ZWJ = [:LineBreak = ZWJ:];
  73
  74 $EmojiNRK = [[\p{Emoji}] - [$RI \u002a\u00230-9©®™〰〽]];
  75 # Data for Extended Pictographic scraped from CLDR common/properties/ExtendedPictographic.txt, r13267
  76 $Extended_Pict = [\U0001F774-\U0001F77F\U00002700-\U00002701\U00002703-\U00002704\U0000270E\U00002710-\U00002711\U00002765-\U00002767\U0001F030-\U0001F093\U0001F094-\U0001F09F\U0001F10D-\U0001F10F\U0001F12F\U0001F16C-\U0001F16F\U0001F1AD-\U0001F1E5\U0001F260-\U0001F265\U0001F203-\U0001F20F\U0001F23C-\U0001F23F\U0001F249-\U0001F24F\U0001F252-\U0001F25F\U0001F266-\U0001F2FF\U0001F7D5-\U0001F7FF\U0001F000-\U0001F003\U0001F005-\U0001F02B\U0001F02C-\U0001F02F\U0001F322-\U0001F323\U0001F394-\U0001F395\U0001F398\U0001F39C-\U0001F39D\U0001F3F1-\U0001F3F2\U0001F3F6\U0001F4FE\U0001F53E-\U0001F548\U0001F54F\U0001F568-\U0001F56E\U0001F571-\U0001F572\U0001F57B-\U0001F586\U0001F588-\U0001F589\U0001F58E-\U0001F58F\U0001F591-\U0001F594\U0001F597-\U0001F5A3\U0001F5A6-\U0001F5A7\U0001F5A9-\U0001F5B0\U0001F5B3-\U0001F5BB\U0001F5BD-\U0001F5C1\U0001F5C5-\U0001F5D0\U0001F5D4-\U0001F5DB\U0001F5DF-\U0001F5E0\U0001F5E2\U0001F5E4-\U0001F5E7\U0001F5E9-\U0001F5EE\U0001F5F0-\U0001F5F2\U0001F5F4-\U0001F5F9\U00002605\U00002607-\U0000260D\U0000260F-\U00002610\U00002612\U00002616-\U00002617\U00002619-\U0000261C\U0000261E-\U0000261F\U00002621\U00002624-\U00002625\U00002627-\U00002629\U0000262B-\U0000262D\U00002630-\U00002637\U0000263B-\U00002647\U00002654-\U0000265F\U00002661-\U00002662\U00002664\U00002667\U00002669-\U0000267A\U0000267C-\U0000267E\U00002680-\U00002691\U00002695\U00002698\U0000269A\U0000269D-\U0000269F\U000026A2-\U000026A9\U000026AC-\U000026AF\U000026B2-\U000026BC\U000026BF-\U000026C3\U000026C6-\U000026C7\U000026C9-\U000026CD\U000026D0\U000026D2\U000026D5-\U000026E8\U000026EB-\U000026EF\U000026F6\U000026FB-\U000026FC\U000026FE-\U000026FF\U00002388\U0001FA00-\U0001FFFD\U0001F0A0-\U0001F0AE\U0001F0B1-\U0001F0BF\U0001F0C1-\U0001F0CF\U0001F0D1-\U0001F0F5\U0001F0AF-\U0001F0B0\U0001F0C0\U0001F0D0\U0001F0F6-\U0001F0FF\U0001F80C-\U0001F80F\U0001F848-\U0001F84F\U0001F85A-\U0001F85F\U0001F888-\U0001F88F\U0001F8AE-\U0001F8FF\U0001F900-\U0001F90B\U0001F91F\U0001F928-\U0001F92F\U0001F931-\U0001F932\U0001F94C\U0001F95F-\U0001F96B\U0001F992-\U0001F997\U0001F9D0-\U0001F9E6\U0001F90C-\U0001F90F\U0001F93F\U0001F94D-\U0001F94F\U0001F96C-\U0001F97F\U0001F998-\U0001F9BF\U0001F9C1-\U0001F9CF\U0001F9E7-\U0001F9FF\U0001F6C6-\U0001F6CA\U0001F6D3-\U0001F6D4\U0001F6E6-\U0001F6E8\U0001F6EA\U0001F6F1-\U0001F6F2\U0001F6F7-\U0001F6F8\U0001F6D5-\U0001F6DF\U0001F6ED-\U0001F6EF\U0001F6F9-\U0001F6FF];
  77
  78 # By LB9, a ZWJ also behaves as a CM. Including it in the definition of CM avoids having to explicitly
  79 #         list it in the numerous rules that use CM.
  80 # By LB1, SA characters with general categor of Mn or Mc also resolve to CM.
  81
  82 $CM = [[:LineBreak = Combining_Mark:] $ZWJ [$SA & [[:Mn:][:Mc:]]]];
  83
  84 #   Dictionary character set, for triggering language-based break engines. Currently
  85 #   limited to LineBreak=Complex_Context (SA).
  86
  87 $dictionary = [$SA];
  88
  89 #
  90 #  Rule LB1.  By default, treat AI  (characters with ambiguous east Asian width),
  91 #                               SA  (Dictionary chars, excluding Mn and Mc)
  92 #                               SG  (Unpaired Surrogates)
  93 #                               XX  (Unknown, unassigned)
  94 #                         as $AL  (Alphabetic)
  95 #
  96 $ALPlus = [$AL $AI $SG $XX [$SA-[[:Mn:][:Mc:]]]];
  97
  98
  99 ## -------------------------------------------------
 100
 101 !!forward;
 102
 103 #
 104 # CAN_CM  is the set of characters that may combine with CM combining chars.
 105 #         Note that Linebreak UAX 14's concept of a combining char and the rules
 106 #         for what they can combine with are _very_ different from the rest of Unicode.
 107 #
 108 #         Note that $CM itself is left out of this set.  If CM is needed as a base
 109 #         it must be listed separately in the rule.
 110 #
 111 $CAN_CM  = [^$SP $BK $CR $LF $NL $ZW $CM];       # Bases that can   take CMs
 112 $CANT_CM = [ $SP $BK $CR $LF $NL $ZW $CM];       # Bases that can't take CMs
 113
 114 #
 115 # AL_FOLLOW  set of chars that can unconditionally follow an AL
 116 #            Needed in rules where stand-alone $CM s are treated as AL.
 117 #
 118 $AL_FOLLOW      = [$BK $CR $LF $NL $ZW $SP $CL $CP $EX $HL $IS $SY $WJ $GL $OP $QU $BA $HY $NS $IN $NU $PR $PO $ALPlus];
 119
 120
 121 #
 122 #  Rule LB 4, 5    Mandatory (Hard) breaks.
 123 #
 124 $LB4Breaks    = [$BK $CR $LF $NL];
 125 $LB4NonBreaks = [^$BK $CR $LF $NL $CM];
 126 $CR $LF {100};
 127
 128 #
 129 #  LB 6    Do not break before hard line breaks.
 130 #
 131 $LB4NonBreaks?  $LB4Breaks {100};    # LB 5  do not break before hard breaks.
 132 $CAN_CM $CM*    $LB4Breaks {100};
 133 ^$CM+           $LB4Breaks {100};
 134
 135 # LB 7         x SP
 136 #              x ZW
 137 $LB4NonBreaks [$SP $ZW];
 138 $CAN_CM $CM*  [$SP $ZW];
 139 ^$CM+         [$SP $ZW];
 140
 141 #
 142 # LB 8         Break after zero width space
 143 #              TODO:  ZW SP* <break>
 144 #              An engine change is required to write the reverse rule for this.
 145 #              For now, leave the Unicode 5.2 rule, ZW <break>
 146 #
 147 $LB8Breaks    = [$LB4Breaks $ZW];
 148 $LB8NonBreaks = [[$LB4NonBreaks] - [$ZW]];
 149
 150 # LB 8a        ZWJ x (ID | Extended_Pict | EmojiNRK)   Emoji ZWJ sequences.
 151 #
 152 $ZWJ ($ID | $Extended_Pict | $EmojiNRK);
 153
 154 # LB 9     Combining marks.      X   $CM needs to behave like X, where X is not $SP, $BK $CR $LF $NL
 155 #                                $CM not covered by the above needs to behave like $AL
 156 #                                See definition of $CAN_CM.
 157
 158 $CAN_CM $CM+;                   #  Stick together any combining sequences that don't match other rules.
 159 ^$CM+;
 160
 161 #
 162 # LB 11  Do not break before or after WORD JOINER & related characters.
 163 #
 164 $CAN_CM $CM*  $WJ;
 165 $LB8NonBreaks $WJ;
 166 ^$CM+         $WJ;
 167
 168 $WJ $CM* .;
 169
 170 #
 171 # LB 12  Do not break after NBSP and related characters.
 172 #         GL  x
 173 #
 174 $GL $CM* .;
 175
 176 #
 177 # LB 12a  Do not break before NBSP and related characters ...
 178 #            [^SP BA HY] x GL
 179 #
 180 [[$LB8NonBreaks] - [$SP $BA $HY]] $CM* $GL;
 181 ^$CM+ $GL;
 182
 183
 184
 185 #
 186 # LB 13   Don't break before ']' or '!' or ';' or '/', even after spaces.
 187 #
 188 $LB8NonBreaks $CL;
 189 $CAN_CM $CM*  $CL;
 190 ^$CM+         $CL;              # by rule 10, stand-alone CM behaves as AL
 191
 192 $LB8NonBreaks $CP;
 193 $CAN_CM $CM*  $CP;
 194 ^$CM+         $CP;              # by rule 10, stand-alone CM behaves as AL
 195
 196 $LB8NonBreaks $EX;
 197 $CAN_CM $CM*  $EX;
 198 ^$CM+         $EX;              # by rule 10, stand-alone CM behaves as AL
 199
 200 $LB8NonBreaks $IS;
 201 $CAN_CM $CM*  $IS;
 202 ^$CM+         $IS;              # by rule 10, stand-alone CM behaves as AL
 203
 204 $LB8NonBreaks $SY;
 205 $CAN_CM $CM*  $SY;
 206 ^$CM+         $SY;              # by rule 10, stand-alone CM behaves as AL
 207
 208
 209 #
 210 # LB 14  Do not break after OP, even after spaces
 211 #
 212 $OP $CM* $SP* .;
 213
 214 $OP $CM* $SP+ $CM+ $AL_FOLLOW?;    # by rule 10, stand-alone CM behaves as AL
 215                                    # by rule 8, CM following a SP is stand-alone.
 216
 217 # LB 15
 218 $QU $CM* $SP* $OP;
 219
 220 # LB 16
 221 ($CL | $CP) $CM* $SP* $NS;
 222
 223 # LB 17
 224 $B2 $CM* $SP* $B2;
 225
 226 #
 227 # LB 18  Break after spaces.
 228 #
 229 $LB18NonBreaks = [$LB8NonBreaks - [$SP]];
 230 $LB18Breaks    = [$LB8Breaks $SP];
 231
 232
 233 # LB 19
 234 #         x QU
 235 $LB18NonBreaks $CM* $QU;
 236 ^$CM+               $QU;
 237
 238 #         QU  x
 239 $QU $CM* .;
 240
 241
 242 # LB 20
 243 #        <break>  $CB
 244 #        $CB   <break>
 245
 246 $LB20NonBreaks = [$LB18NonBreaks - $CB];
 247
 248 # LB 21        x   (BA | HY | NS)
 249 #           BB x
 250 #
 251 $LB20NonBreaks $CM* ($BA | $HY | $NS);
 252 ^$CM+ ($BA | $HY | $NS);
 253
 254 $BB $CM* [^$CB];                                  #  $BB  x
 255 $BB $CM* $LB20NonBreaks;
 256
 257 # LB 21a Don't break after Hebrew + Hyphen
 258 #   HL (HY | BA) x
 259 #
 260 $HL $CM* ($HY | $BA) $CM* [^$CB]?;
 261
 262 # LB 21b (forward) Don't break between SY and HL
 263 # (break between HL and SY already disallowed by LB 13 above)
 264 $SY $CM* $HL;
 265
 266 # LB 22
 267 ($ALPlus | $HL) $CM* $IN;
 268 ^$CM+    $IN;     #  by rule 10, any otherwise unattached CM behaves as AL
 269 $EX $CM*    $IN;
 270 ($ID | $EB | $EM) $CM*  $IN;
 271 $IN $CM*    $IN;
 272 $NU $CM*    $IN;
 273
 274
 275 # $LB 23
 276 #
 277 ($ALPlus | $HL) $CM* $NU;
 278 ^$CM+  $NU;       # Rule 10, any otherwise unattached CM behaves as AL
 279 $NU $CM* ($ALPlus | $HL);
 280
 281 # LB 23a
 282 #
 283 $PR $CM* ($ID | $EB | $EM);
 284 ($ID | $EB | $EM) $CM*  $PO;
 285
 286
 287 #
 288 # LB 24
 289 #
 290 ($PR | $PO) $CM* ($ALPlus | $HL);
 291 ($ALPlus | $HL) $CM* ($PR | $PO);
 292 ^$CM+ ($PR | $PO);       # Rule 10, any otherwise unattached CM behaves as AL
 293
 294 #
 295 # LB 25   Numbers.
 296 #
 297 (($PR | $PO) $CM*)? (($OP | $HY) $CM*)? $NU ($CM* ($NU | $SY | $IS))*
 298     ($CM* ($CL | $CP))? ($CM* ($PR | $PO))?;
 299
 300 # LB 26  Do not break a Korean syllable
 301 #
 302 $JL $CM* ($JL | $JV | $H2 | $H3);
 303 ($JV | $H2) $CM* ($JV | $JT);
 304 ($JT | $H3) $CM* $JT;
 305
 306 # LB 27  Treat korean Syllable Block the same as ID  (don't break it)
 307 ($JL | $JV | $JT | $H2 | $H3) $CM* $IN;
 308 ($JL | $JV | $JT | $H2 | $H3) $CM* $PO;
 309 $PR $CM* ($JL | $JV | $JT | $H2 | $H3);
 310
 311
 312 # LB 28   Do not break between alphabetics
 313 #
 314 ($ALPlus | $HL) $CM* ($ALPlus | $HL);
 315 ^$CM+ ($ALPlus | $HL);      # The $CM+ is from rule 10, an unattached CM is treated as AL
 316
 317 # LB 29
 318 $IS $CM* ($ALPlus | $HL);
 319
 320 # LB 30
 321 ($ALPlus | $HL | $NU) $CM* $OP;
 322 ^$CM+ $OP;         # The $CM+ is from rule 10, an unattached CM is treated as AL.
 323 $CP $CM* ($ALPlus | $HL | $NU);
 324
 325 # LB 30a  Do not break between regional indicators. Break after pairs of them.
 326 #         Tricky interaction with LB8a: ZWJ x ID
 327 $RI $CM* $RI                / [[^$BK $CR $LF $NL $SP $ZW $WJ $CL $CP $EX $IS $SY $GL $QU $BA $HY $NS $CM] {eof}];
 328 $RI $CM* $RI $CM*  $ZWJ     / [[^$BK $CR $LF $NL $SP $ZW $WJ $CL $CP $EX $IS $SY $GL $QU $BA $HY $NS $CM $ID $Extended_Pict $EmojiNRK] {eof}];
 329 $RI $CM* $RI $CM* [$CM-$ZWJ] / [[^$BK $CR $LF $NL $SP $ZW $WJ $CL $CP $EX $IS $SY $GL $QU $BA $HY $NS $CM] {eof}];
 330
 331 $RI $CM* $RI $CM* [$BK $CR $LF $NL $SP $ZW $WJ $CL $CP $EX $IS $SY $GL $QU $BA $HY $NS {eof}];
 332 $RI $CM* $RI $CM* $ZWJ ($ID | $Extended_Pict | $EmojiNRK);
 333
 334 # LB 30b Do not break between an Emoji Base and an Emoji Modifier
 335 $EB $CM* $EM;
 336
 337 #
 338 #  Reverse Rules.
 339 #
 340 ## -------------------------------------------------
 341
 342 !!reverse;
 343
 344 #  LB 9 Combining Marks.
 345 #  Stick together any combining sequences that don't match other rules.
 346
 347 ^$CM+ $CAN_CM?;
 348
 349 #
 350 #  Sequences of the form  (shown forwards)
 351 #      [CANT_CM]  <break>  [CM]  [whatever]
 352 #  The CM needs to behave as an AL
 353 #
 354 $AL_FOLLOW $CM+ / (
 355           [$BK $CR $LF $NL $ZW {eof}] |
 356           $SP+ $CM+ $SP |
 357           $SP+ $CM* ([^$OP $CM $SP] | [$AL {eof}]));   # if LB 14 will match, need to surpress this break.
 358                                                #  LB14 says    OP SP* x .
 359                                                #    becomes    OP SP* x AL
 360                                                #    becomes    OP SP* x CM+ AL_FOLLOW
 361                                                #
 362                                                # Further note:  the $AL in [$AL {eof}] is only to work around
 363                                                #                a rule compiler bug which complains about
 364                                                #                empty sets otherwise.
 365
 366
 367 # LB 4, 5, 6
 368
 369 $LB4Breaks [$LB4NonBreaks-$CM];
 370 $LB4Breaks $CM+ $CAN_CM;
 371 $LF $CR;
 372
 373
 374 # LB 7         x SP
 375 #              x ZW
 376 [$SP $ZW] [$LB4NonBreaks-$CM];
 377 [$SP $ZW] $CM+ $CAN_CM;
 378
 379 # LB 8 ZW SP* <break>
 380 #     TODO: to implement this, we need more than one look-ahead hard break in play at a time.
 381 #           Requires an engine enhancement.
 382 #   / $SP* $ZW
 383
 384 # LB 8a        ZWJ x (ID | Extended_Pict | EmojiNRK)
 385 #
 386 ($ID | $Extended_Pict | $EmojiNRK) $ZWJ $CM* $CAN_CM?;
 387
 388
 389 # LB 9,10  Combining marks.
 390 #    X   $CM needs to behave like X, where X is not $SP or controls.
 391 #    $CM not covered by the above needs to behave like $AL
 392 # Stick together any combining sequences that don't match other rules.
 393 ^$CM+ $CAN_CM;
 394
 395
 396 # LB 11
 397 #
 398 $WJ $CM* $CAN_CM;
 399 $WJ      [$LB8NonBreaks-$CM];
 400
 401      $CANT_CM $CM* $WJ;
 402 $CAN_CM  $CM* $WJ;
 403
 404 # LB 12a
 405 #      [^SP BA HY] x GL
 406 #
 407 $GL $CM* [$LB8NonBreaks-[$CM $SP $BA $HY]];
 408
 409 # LB 12
 410 #     GL  x
 411 #
 412 $CANT_CM $CM* $GL;
 413 $CAN_CM $CM* $GL;
 414
 415
 416 # LB 13
 417 $CL $CM+ $CAN_CM;
 418 $CP $CM+ $CAN_CM;
 419 $EX $CM+ $CAN_CM;
 420 $IS $CM+ $CAN_CM;
 421 $SY $CM+ $CAN_CM;
 422
 423 $CL [$LB8NonBreaks-$CM];
 424 $CP [$LB8NonBreaks-$CM];
 425 $EX [$LB8NonBreaks-$CM];
 426 $IS [$LB8NonBreaks-$CM];
 427 $SY [$LB8NonBreaks-$CM];
 428
 429
 430 # LB 14    OP SP* x
 431 #
 432 .   $SP* $CM* $OP;
 433 $AL_FOLLOW? $CM+ $SP+ $CM* $OP;     #  by LB 10, behaves like $AL_FOLLOW? $AL $SP+ $CM* $OP
 434
 435
 436 # LB 15
 437 $OP $SP* $CM* $QU;
 438
 439 # LB 16
 440 $NS $SP* $CM* ($CL | $CP);
 441
 442 # LB 17
 443 $B2 $SP* $CM* $B2;
 444
 445 # LB 18  break after spaces
 446 #        Nothing explicit needed here.
 447
 448
 449 #
 450 # LB 19
 451 #
 452 $QU $CM* $CAN_CM;                                #   . x QU
 453 $QU      $LB18NonBreaks;
 454
 455
 456 $CAN_CM  $CM* $QU;                               #   QU x .
 457      $CANT_CM $CM* $QU;
 458
 459 #
 460 #  LB 20  Break before and after CB.
 461 #         nothing needed here.
 462 #
 463
 464 # LB 21
 465 ($BA | $HY | $NS) $CM* [$LB20NonBreaks-$CM];     #  . x (BA | HY | NS)
 466
 467 [$LB20NonBreaks-$CM] $CM* $BB;                   #  BB x .
 468 [^$CB] $CM* $BB;                                      #
 469
 470 # LB21a
 471 [^$CB] $CM* ($HY | $BA) $CM* $HL;
 472
 473 # LB21b (reverse)
 474 $HL $CM* $SY;
 475
 476 # LB 22
 477 $IN $CM* ($ALPlus | $HL);
 478 $IN $CM* $EX;
 479 $IN $CM* ($ID | $EB | $EM);
 480 $IN $CM* $IN;
 481 $IN $CM* $NU;
 482
 483 # LB 23
 484 $NU $CM* ($ALPlus | $HL);
 485 ($ALPlus | $HL) $CM* $NU;
 486
 487 # LB23a
 488 ($ID | $EB | $EM) $CM* $PR;
 489 $PO $CM* ($ID | $EB | $EM);
 490
 491 # LB 24
 492 ($ALPlus | $HL) $CM* ($PR | $PO);
 493 ($PR | $PO) $CM* ($ALPlus | $HL);
 494
 495
 496 # LB 25
 497 ($CM* ($PR | $PO))? ($CM* ($CL | $CP))? ($CM* ($NU | $IS | $SY))* $CM* $NU ($CM* ($OP | $HY))? ($CM* ($PR | $PO))?;
 498
 499 # LB 26
 500 ($H3 | $H2 | $JV | $JL) $CM* $JL;
 501 ($JT | $JV) $CM* ($H2 | $JV);
 502 $JT $CM* ($H3 | $JT);
 503
 504 # LB 27
 505 $IN $CM* ($H3 | $H2 | $JT | $JV | $JL);
 506 $PO $CM* ($H3 | $H2 | $JT | $JV | $JL);
 507  ($H3 | $H2 | $JT | $JV | $JL) $CM* $PR;
 508
 509 # LB 28
 510 ($ALPlus | $HL) $CM* ($ALPlus | $HL);
 511
 512
 513 # LB 29
 514 ($ALPlus | $HL) $CM* $IS;
 515
 516 # LB 30
 517 $OP $CM* ($ALPlus | $HL | $NU);
 518 ($ALPlus | $HL | $NU) $CM* $CP;
 519
 520 # LB 30a
 521 #    Pairs of Regional Indicators.
 522 #    The following two rules are nearly identical. The first matches only sequences with an odd number of adjacent RIs,
 523 #    the second with an even number. Stripping away the cruft they look like
 524 #         [^RI] RI / (RI RI)+ ^RI;
 525 #         [^RI] RI RI / (RI RI)+ ^RI;
 526 #
 527 [{bof} $NS $HY $BA $QU $CL $CP $EX $IS $SY $WJ $GL $ZW $SP $BK $CR $LF $NL $ZWJ] $CM* $RI / ($CM* $RI $CM* $RI)+ $CM* [{eof}[^$RI $CM]];
 528 [{bof} $NS $HY $BA $QU $CL $CP $EX $IS $SY $WJ $GL $ZW $SP $BK $CR $LF $NL $ZWJ] $CM* $RI $CM* $RI / ($CM* $RI $CM* $RI)+ $CM* [{eof}[^$RI $CM]];
 529
 530 # In general, adjacent RIs stay together. The hard-break rules, above, overide this, forcing in the boundaries between pairs.
 531 $RI $CM* $RI;
 532
 533 #    WJ, GL, QU, etc. are classes with rules like "WJ x "   which includes "WJ x RI".
 534 $RI $CM* ([$WJ $GL $QU $BB] |  (($HY | $BA)$CM* $HL));
 535
 536
 537 # LB 30b Do not break between an Emoji Base and an Emoji Modifier
 538 $EM $CM* $EB;
 539
 540
 541 ## -------------------------------------------------
 542
 543 !!safe_reverse;
 544
 545 # LB 9
 546 ^$CM+ [^$CM $BK $CR $LF $NL $ZW $SP];
 547 ^$CM+ $SP / .;
 548
 549 # LB 14
 550 $SP+ $CM* $OP;
 551
 552 # LB 15
 553 $SP+ $CM* $QU;
 554
 555 # LB 16
 556 $SP+ $CM* ($CL | $CP);
 557
 558 # LB 17
 559 $SP+ $CM* $B2;
 560
 561 # LB 21
 562 $CM* ($HY | $BA) $CM* $HL;
 563
 564 # LB 25
 565 ($CM* ($IS | $SY))+ $CM* $NU;
 566 ($CL | $CP) $CM* ($NU | $IS | $SY);
 567
 568 #  LB 30
 569 ($CM* $RI)+;
 570
 571 # For dictionary-based break
 572 $dictionary $dictionary;
 573
 574 ## -------------------------------------------------
 575
 576 !!safe_forward;
 577
 578 # Skip forward over all character classes that are involved in
 579 #   rules containing patterns with possibly more than one char
 580 #   of context.
 581 #
 582 #  It might be slightly more efficient to have specific rules
 583 #  instead of one generic one, but only if we could
 584 #  turn off rule chaining.  We don't want to move more
 585 #  than necessary.
 586 #
 587 ^[$CM $OP $QU $CL $CP $B2 $PR $HY $BA $SP $RI $ZWJ $dictionary]+ [^$CM $OP $QU $CL $CP $B2 $PR $HY $BA $RI $ZWJ $dictionary];
 588 $dictionary $dictionary;
 589