icuSources/data/brkitr/line.txt

   1 # Copyright (c) 2002-2012  International Business Machines Corporation and
   2 # others. All Rights Reserved.
   3 #
   4 #  file:  line.txt
   5 #
   6 #         Line Breaking Rules
   7 #         Implement default line breaking as defined by
   8 #         Unicode Standard Annex #14 Revision 29 for Unicode 6.2
   9 #         http://www.unicode.org/reports/tr14/
  10 #
  11 #         TODO:  Rule LB 8 remains as it was in Unicode 5.2
  12 #         This is only because of a limitation of ICU break engine implementation,
  13 #         not because the older behavior is desirable.
  14
  15 #
  16 #  Character Classes defined by TR 14.
  17 #
  18
  19 !!chain;
  20 !!LBCMNoChain;
  21
  22
  23 !!lookAheadHardBreak;
  24 #
  25 #  !!lookAheadHardBreak    Described here because it is (as yet) undocumented elsewhere
  26 #                          and only used for the line break rules.
  27 #
  28 #           It is used in the implementation of rule LB 10
  29 #           which says to treat any combining mark that is not attached to a base
  30 #           character as if it were of class AL  (alphabetic).
  31 #
  32 #           The problem occurs in the reverse rules.
  33 #
  34 #           Consider a sequence like, with correct breaks as shown
  35 #               LF  ID  CM  AL  AL
  36 #                  ^       ^       ^
  37 #           Then consider the sequence without the initial ID (ideographic)
  38 #                 LF  CM  AL  AL
  39 #                    ^           ^
  40 #           Our CM, which in the first example was attached to the ideograph,
  41 #           is now unattached, becomes an alpha, and joins in with the other
  42 #           alphas.
  43 #
  44 #           When iterating forwards, these sequences do not present any problems
  45 #           When iterating backwards, we need to look ahead when encountering
  46 #           a CM to see whether it attaches to something further on or not.
  47 #           (Look-ahead in a reverse rule is looking towards the start)
  48 #
  49 #           If the CM is unattached, we need to force a break.
  50 #
  51 #           !!lookAheadHardBreak forces the run time state machine to
  52 #           stop immediately when a look ahead rule ( '/' operator) matches,
  53 #           and set the match position to that of the look-ahead operator,
  54 #           no matter what other rules may be in play at the time.
  55 #
  56 #           See rule LB 19 for an example.
  57 #
  58
  59 $AI = [:LineBreak =  Ambiguous:];
  60 $AL = [:LineBreak =  Alphabetic:];
  61 $BA = [:LineBreak =  Break_After:];
  62 $BB = [:LineBreak =  Break_Before:];
  63 $BK = [:LineBreak =  Mandatory_Break:];
  64 $B2 = [:LineBreak =  Break_Both:];
  65 $CB = [:LineBreak =  Contingent_Break:];
  66 $CJ = [:LineBreak =  Conditional_Japanese_Starter:];
  67 $CL = [:LineBreak =  Close_Punctuation:];
  68 $CM = [:LineBreak =  Combining_Mark:];
  69 $CP = [:LineBreak =  Close_Parenthesis:];
  70 $CR = [:LineBreak =  Carriage_Return:];
  71 $EX = [:LineBreak =  Exclamation:];
  72 $GL = [:LineBreak =  Glue:];
  73 $HL = [:LineBreak =  Hebrew_Letter:];
  74 $HY = [:LineBreak =  Hyphen:];
  75 $H2 = [:LineBreak =  H2:];
  76 $H3 = [:LineBreak =  H3:];
  77 $ID = [:LineBreak =  Ideographic:];
  78 $IN = [:LineBreak =  Inseperable:];
  79 $IS = [:LineBreak =  Infix_Numeric:];
  80 $JL = [:LineBreak =  JL:];
  81 $JV = [:LineBreak =  JV:];
  82 $JT = [:LineBreak =  JT:];
  83 $LF = [:LineBreak =  Line_Feed:];
  84 $NL = [:LineBreak =  Next_Line:];
  85 $NS = [[:LineBreak =  Nonstarter:] $CJ];
  86 $NU = [:LineBreak =  Numeric:];
  87 $OP = [:LineBreak =  Open_Punctuation:];
  88 $PO = [:LineBreak =  Postfix_Numeric:];
  89 $PR = [:LineBreak =  Prefix_Numeric:];
  90 $QU = [:LineBreak =  Quotation:];
  91 $RI = [:LineBreak =  Regional_Indicator:];
  92 $SA = [:LineBreak =  Complex_Context:];
  93 $SG = [:LineBreak =  Surrogate:];
  94 $SP = [:LineBreak =  Space:];
  95 $SY = [:LineBreak =  Break_Symbols:];
  96 $WJ = [:LineBreak =  Word_Joiner:];
  97 $XX = [:LineBreak =  Unknown:];
  98 $ZW = [:LineBreak =  ZWSpace:];
  99
 100 #   Dictionary character set, for triggering language-based break engines. Currently
 101 #   limited to LineBreak=Complex_Context. Note that this set only works in Unicode
 102 #   5.0 or later as the definition of Complex_Context was corrected to include all
 103 #   characters requiring dictionary break.
 104
 105 $dictionary = [:LineBreak = Complex_Context:];
 106
 107 #
 108 #  Rule LB1.  By default, treat AI  (characters with ambiguous east Asian width),
 109 #                               SA  (South East Asian: Thai, Lao, Khmer)
 110 #                               SG  (Unpaired Surrogates)
 111 #                               XX  (Unknown, unassigned)
 112 #                         as $AL  (Alphabetic)
 113 #
 114 $ALPlus = [$AL $AI $SA $SG $XX];
 115
 116 #
 117 #  Combining Marks.   X $CM*  behaves as if it were X.  Rule LB6.
 118 #
 119 $ALcm = $ALPlus $CM*;
 120 $BAcm = $BA $CM*;
 121 $BBcm = $BB $CM*;
 122 $B2cm = $B2 $CM*;
 123 $CLcm = $CL $CM*;
 124 $CPcm = $CP $CM*;
 125 $EXcm = $EX $CM*;
 126 $GLcm = $GL $CM*;
 127 $HLcm = $HL $CM*;
 128 $HYcm = $HY $CM*;
 129 $H2cm = $H2 $CM*;
 130 $H3cm = $H3 $CM*;
 131 $IDcm = $ID $CM*;
 132 $INcm = $IN $CM*;
 133 $IScm = $IS $CM*;
 134 $JLcm = $JL $CM*;
 135 $JVcm = $JV $CM*;
 136 $JTcm = $JT $CM*;
 137 $NScm = $NS $CM*;
 138 $NUcm = $NU $CM*;
 139 $OPcm = $OP $CM*;
 140 $POcm = $PO $CM*;
 141 $PRcm = $PR $CM*;
 142 $QUcm = $QU $CM*;
 143 $RIcm = $RI $CM*;
 144 $SYcm = $SY $CM*;
 145 $WJcm = $WJ $CM*;
 146
 147 ## -------------------------------------------------
 148
 149 !!forward;
 150
 151 #
 152 #  Each class of character can stand by itself as an unbroken token, with trailing combining stuff
 153 #
 154 $ALPlus $CM+;
 155 $BA $CM+;
 156 $BB $CM+;
 157 $B2 $CM+;
 158 $CL $CM+;
 159 $CP $CM+;
 160 $EX $CM+;
 161 $GL $CM+;
 162 $HL $CM+;
 163 $HY $CM+;
 164 $H2 $CM+;
 165 $H3 $CM+;
 166 $ID $CM+;
 167 $IN $CM+;
 168 $IS $CM+;
 169 $JL $CM+;
 170 $JV $CM+;
 171 $JT $CM+;
 172 $NS $CM+;
 173 $NU $CM+;
 174 $OP $CM+;
 175 $PO $CM+;
 176 $PR $CM+;
 177 $QU $CM+;
 178 $RI $CM+;
 179 $SY $CM+;
 180 $WJ $CM+;
 181
 182 #
 183 # CAN_CM  is the set of characters that may combine with CM combining chars.
 184 #         Note that Linebreak UAX 14's concept of a combining char and the rules
 185 #         for what they can combine with are _very_ different from the rest of Unicode.
 186 #
 187 #         Note that $CM itself is left out of this set.  If CM is needed as a base
 188 #         it must be listed separately in the rule.
 189 #
 190 $CAN_CM  = [^$SP $BK $CR $LF $NL $ZW $CM];       # Bases that can   take CMs
 191 $CANT_CM = [ $SP $BK $CR $LF $NL $ZW $CM];       # Bases that can't take CMs
 192
 193 #
 194 # AL_FOLLOW  set of chars that can unconditionally follow an AL
 195 #            Needed in rules where stand-alone $CM s are treated as AL.
 196 #            Chaining is disabled with CM because it causes other failures,
 197 #            so for this one case we need to manually list out longer sequences.
 198 #
 199 $AL_FOLLOW_NOCM = [$BK $CR $LF $NL $ZW $SP];
 200 $AL_FOLLOW_CM   = [$CL $CP $EX $HL $IS $SY $WJ $GL $OP $QU $BA $HY $NS $IN $NU $ALPlus];
 201 $AL_FOLLOW      = [$AL_FOLLOW_NOCM $AL_FOLLOW_CM];
 202
 203
 204 #
 205 #  Rule LB 4, 5    Mandatory (Hard) breaks.
 206 #
 207 $LB4Breaks    = [$BK $CR $LF $NL];
 208 $LB4NonBreaks = [^$BK $CR $LF $NL];
 209 $CR $LF {100};
 210
 211 #
 212 #  LB 6    Do not break before hard line breaks.
 213 #
 214 $LB4NonBreaks?  $LB4Breaks {100};    # LB 5  do not break before hard breaks.
 215 $CAN_CM $CM*    $LB4Breaks {100};
 216 $CM+            $LB4Breaks {100};
 217
 218 # LB 7         x SP
 219 #              x ZW
 220 $LB4NonBreaks [$SP $ZW];
 221 $CAN_CM $CM*  [$SP $ZW];
 222 $CM+          [$SP $ZW];
 223
 224 #
 225 # LB 8         Break after zero width space
 226 #              TODO:  ZW SP* <break>
 227 #              An engine change is required to write the reverse rule for this.
 228 #              For now, leave the Unicode 5.2 rule, ZW <break>
 229 #
 230 $LB8Breaks    = [$LB4Breaks $ZW];
 231 $LB8NonBreaks = [[$LB4NonBreaks] - [$ZW]];
 232
 233
 234 # LB 9     Combining marks.      X   $CM needs to behave like X, where X is not $SP, $BK $CR $LF $NL
 235 #                                $CM not covered by the above needs to behave like $AL
 236 #                                See definition of $CAN_CM.
 237
 238 $CAN_CM $CM+;                   #  Stick together any combining sequences that don't match other rules.
 239 $CM+;
 240
 241 #
 242 # LB 11  Do not break before or after WORD JOINER & related characters.
 243 #
 244 $CAN_CM $CM*  $WJcm;
 245 $LB8NonBreaks $WJcm;
 246 $CM+          $WJcm;
 247
 248 $WJcm $CANT_CM;
 249 $WJcm $CAN_CM $CM*;
 250
 251 #
 252 # LB 12  Do not break after NBSP and related characters.
 253 #         GL  x
 254 #
 255 $GLcm $CAN_CM $CM*;
 256 $GLcm $CANT_CM;
 257
 258 #
 259 # LB 12a  Do not break before NBSP and related characters ...
 260 #            [^SP BA HY] x GL
 261 #
 262 [[$LB8NonBreaks] - [$SP $BA $HY]] $CM* $GLcm;
 263 $CM+ GLcm;
 264
 265
 266
 267 #
 268 # LB 13   Don't break before ']' or '!' or ';' or '/', even after spaces.
 269 #
 270 $LB8NonBreaks $CL;
 271 $CAN_CM $CM*  $CL;
 272 $CM+          $CL;              # by rule 10, stand-alone CM behaves as AL
 273
 274 $LB8NonBreaks $CP;
 275 $CAN_CM $CM*  $CP;
 276 $CM+          $CP;              # by rule 10, stand-alone CM behaves as AL
 277
 278 $LB8NonBreaks $EX;
 279 $CAN_CM $CM*  $EX;
 280 $CM+          $EX;              # by rule 10, stand-alone CM behaves as AL
 281
 282 $LB8NonBreaks $IS;
 283 $CAN_CM $CM*  $IS;
 284 $CM+          $IS;              # by rule 10, stand-alone CM behaves as AL
 285
 286 $LB8NonBreaks $SY;
 287 $CAN_CM $CM*  $SY;
 288 $CM+          $SY;              # by rule 10, stand-alone CM behaves as AL
 289
 290
 291 #
 292 # LB 14  Do not break after OP, even after spaces
 293 #
 294 $OPcm $SP* $CAN_CM $CM*;
 295 $OPcm $SP* $CANT_CM;
 296
 297 $OPcm $SP+ $CM+ $AL_FOLLOW?;    # by rule 10, stand-alone CM behaves as AL
 298
 299 # LB 15
 300 $QUcm $SP* $OPcm;
 301
 302 # LB 16
 303 ($CLcm | $CPcm) $SP* $NScm;
 304
 305 # LB 17
 306 $B2cm $SP* $B2cm;
 307
 308 #
 309 # LB 18  Break after spaces.
 310 #
 311 $LB18NonBreaks = [$LB8NonBreaks - [$SP]];
 312 $LB18Breaks    = [$LB8Breaks $SP];
 313
 314
 315 # LB 19
 316 #         x QU
 317 $LB18NonBreaks $CM* $QUcm;
 318 $CM+                $QUcm;
 319
 320 #         QU  x
 321 $QUcm .?;
 322 $QUcm $LB18NonBreaks $CM*;    # Don't let a combining mark go onto $CR, $BK, etc.
 323                               #  TODO:  I don't think this rule is needed.
 324
 325
 326 # LB 20
 327 #        <break>  $CB
 328 #        $CB   <break>
 329
 330 $LB20NonBreaks = [$LB18NonBreaks - $CB];
 331
 332 # LB 21        x   (BA | HY | NS)
 333 #           BB x
 334 #
 335 $LB20NonBreaks $CM* ($BAcm | $HYcm | $NScm);
 336
 337 $BBcm [^$CB];                                  #  $BB  x
 338 $BBcm $LB20NonBreaks $CM*;
 339
 340 # LB 21a Don't break after Hebrew + Hyphen
 341 #   HL (HY | BA) x
 342 #
 343 $HLcm ($HYcm | $BAcm) [^$CB]?;
 344
 345 # LB 21b (forward) Don't break between SY and HL
 346 # (break between HL and SY already disallowed by LB 13 above)
 347 $SYcm $HLcm;
 348
 349 # LB 22
 350 ($ALcm | $HLcm) $INcm;
 351 $CM+     $INcm;     #  by rule 10, any otherwise unattached CM behaves as AL
 352 $IDcm    $INcm;
 353 $INcm    $INcm;
 354 $NUcm    $INcm;
 355
 356
 357 # $LB 23
 358 $IDcm  $POcm;
 359 $ALcm  $NUcm;       # includes $LB19
 360 $HLcm  $NUcm;
 361 $CM+   $NUcm;       # Rule 10, any otherwise unattached CM behaves as AL
 362 $NUcm  $ALcm;
 363 $NUcm  $HLcm;
 364
 365 #
 366 # LB 24
 367 #
 368 $PRcm $IDcm;
 369 $PRcm ($ALcm | $HLcm);
 370 $POcm ($ALcm | $HLcm);
 371
 372 #
 373 # LB 25   Numbers.
 374 #
 375 ($PRcm | $POcm)? ($OPcm | $HYcm)? $NUcm ($NUcm | $SYcm | $IScm)* ($CLcm | $CPcm)? ($PRcm | $POcm)?;
 376
 377 # LB 26  Do not break a Korean syllable
 378 #
 379 $JLcm ($JLcm | $JVcm | $H2cm | $H3cm);
 380 ($JVcm | $H2cm) ($JVcm | $JTcm);
 381 ($JTcm | $H3cm) $JTcm;
 382
 383 # LB 27  Treat korean Syllable Block the same as ID  (don't break it)
 384 ($JLcm | $JVcm | $JTcm | $H2cm | $H3cm) $INcm;
 385 ($JLcm | $JVcm | $JTcm | $H2cm | $H3cm) $POcm;
 386 $PRcm ($JLcm | $JVcm | $JTcm | $H2cm | $H3cm);
 387
 388
 389 # LB 28   Do not break between alphabetics
 390 #
 391 ($ALcm | $HLcm) ($ALcm | $HLcm);
 392 $CM+ ($ALcm | $HLcm);      # The $CM+ is from rule 10, an unattached CM is treated as AL
 393
 394 # LB 29
 395 $IScm ($ALcm | $HLcm);
 396
 397 # LB 30
 398 ($ALcm | $HLcm | $NUcm) $OPcm;
 399 $CM+ $OPcm;         # The $CM+ is from rule 10, an unattached CM is treated as AL.
 400 $CPcm ($ALcm | $HLcm | $NUcm);
 401
 402 # LB 30a  Do not break between regional indicators.
 403 $RIcm $RIcm;
 404
 405 #
 406 #  Reverse Rules.
 407 #
 408 ## -------------------------------------------------
 409
 410 !!reverse;
 411
 412 $CM+ $ALPlus;
 413 $CM+ $BA;
 414 $CM+ $BB;
 415 $CM+ $B2;
 416 $CM+ $CL;
 417 $CM+ $CP;
 418 $CM+ $EX;
 419 $CM+ $GL;
 420 $CM+ $HL;
 421 $CM+ $HY;
 422 $CM+ $H2;
 423 $CM+ $H3;
 424 $CM+ $ID;
 425 $CM+ $IN;
 426 $CM+ $IS;
 427 $CM+ $JL;
 428 $CM+ $JV;
 429 $CM+ $JT;
 430 $CM+ $NS;
 431 $CM+ $NU;
 432 $CM+ $OP;
 433 $CM+ $PO;
 434 $CM+ $PR;
 435 $CM+ $QU;
 436 $CM+ $RI;
 437 $CM+ $SY;
 438 $CM+ $WJ;
 439 $CM+;
 440
 441
 442 #
 443 #  Sequences of the form  (shown forwards)
 444 #      [CANT_CM]  <break>  [CM]  [whatever]
 445 #  The CM needs to behave as an AL
 446 #
 447 $AL_FOLLOW $CM+ / (
 448           [$BK $CR $LF $NL $ZW {eof}] |
 449           $SP+ $CM+ $SP |
 450           $SP+ $CM* ([^$OP $CM $SP] | [$AL {eof}]));   # if LB 14 will match, need to surpress this break.
 451                                                #  LB14 says    OP SP* x .
 452                                                #    becomes    OP SP* x AL
 453                                                #    becomes    OP SP* x CM+ AL_FOLLOW
 454                                                #
 455                                                # Further note:  the $AL in [$AL {eof}] is only to work around
 456                                                #                a rule compiler bug which complains about
 457                                                #                empty sets otherwise.
 458
 459 #
 460 #  Sequences of the form  (shown forwards)
 461 #      [CANT_CM]  <break> [CM]  <break>  [PR]
 462 #  The CM needs to behave as an AL
 463 #  This rule is concerned about getting the second of the two <breaks> in place.
 464 #
 465
 466 [$PR   ] / $CM+ [$BK $CR $LF $NL $ZW $SP {eof}];
 467
 468
 469
 470 # LB 4, 5, 5
 471
 472 $LB4Breaks [$LB4NonBreaks-$CM];
 473 $LB4Breaks $CM+ $CAN_CM;
 474 $LF $CR;
 475
 476
 477 # LB 7         x SP
 478 #              x ZW
 479 [$SP $ZW] [$LB4NonBreaks-$CM];
 480 [$SP $ZW] $CM+ $CAN_CM;
 481
 482 # LB 8 ZW SP* <break>
 483 #     TODO: to implement this, we need more than one look-ahead hard break in play at a time.
 484 #           Requires an engine enhancement.
 485 #   / $SP* $ZW
 486
 487 # LB 9,10  Combining marks.
 488 #    X   $CM needs to behave like X, where X is not $SP or controls.
 489 #    $CM not covered by the above needs to behave like $AL
 490 # Stick together any combining sequences that don't match other rules.
 491 $CM+ $CAN_CM;
 492
 493
 494 # LB 11
 495 $CM* $WJ $CM* $CAN_CM;
 496 $CM* $WJ      [$LB8NonBreaks-$CM];
 497
 498      $CANT_CM $CM* $WJ;
 499 $CM* $CAN_CM  $CM* $WJ;
 500
 501 # LB 12a
 502 #      [^SP BA HY] x GL
 503 #
 504 $CM* $GL $CM* [$LB8NonBreaks-[$CM $SP $BA $HY]];
 505
 506 # LB 12
 507 #     GL  x
 508 #
 509 $CANT_CM $CM* $GL;
 510 $CM* $CAN_CM $CM* $GL;
 511
 512
 513 # LB 13
 514 $CL $CM+ $CAN_CM;
 515 $CP $CM+ $CAN_CM;
 516 $EX $CM+ $CAN_CM;
 517 $IS $CM+ $CAN_CM;
 518 $SY $CM+ $CAN_CM;
 519
 520 $CL [$LB8NonBreaks-$CM];
 521 $CP [$LB8NonBreaks-$CM];
 522 $EX [$LB8NonBreaks-$CM];
 523 $IS [$LB8NonBreaks-$CM];
 524 $SY [$LB8NonBreaks-$CM];
 525
 526 # Rule 13 & 14 taken together for an edge case.
 527 #   Match this, shown forward
 528 #     OP SP+  ($CM+ behaving as $AL) (CL | CP | EX | IS | IY)
 529 #   This really wants to chain at the $CM+ (which is acting as an $AL)
 530 #   except for $CM chaining being disabled.
 531 [$CL $CP $EX $IS $SY] $CM+ $SP+ $CM* $OP;
 532
 533 # LB 14    OP SP* x
 534 #
 535 $CM* $CAN_CM    $SP* $CM* $OP;
 536      $CANT_CM   $SP* $CM* $OP;
 537 $AL_FOLLOW? $CM+  $SP $SP* $CM* $OP;     #  by LB 10, behaves like $AL_FOLLOW? $AL $SP* $CM* $OP
 538
 539      $AL_FOLLOW_NOCM $CM+ $SP+ $CM* $OP;
 540 $CM* $AL_FOLLOW_CM   $CM+ $SP+ $CM* $OP;
 541 $SY $CM $SP+ $OP;   # TODO:  Experiment.  Remove.
 542
 543
 544
 545 # LB 15
 546 $CM* $OP $SP* $CM* $QU;
 547
 548 # LB 16
 549 $CM* $NS $SP* $CM* ($CL | $CP);
 550
 551 # LB 17
 552 $CM* $B2 $SP* $CM* $B2;
 553
 554 # LB 18  break after spaces
 555 #        Nothing explicit needed here.
 556
 557
 558 #
 559 # LB 19
 560 #
 561 $CM* $QU $CM* $CAN_CM;                                #   . x QU
 562 $CM* $QU      $LB18NonBreaks;
 563
 564
 565 $CM* $CAN_CM  $CM* $QU;                               #   QU x .
 566      $CANT_CM $CM* $QU;
 567
 568 #
 569 #  LB 20  Break before and after CB.
 570 #         nothing needed here.
 571 #
 572
 573 # LB 21
 574 $CM* ($BA | $HY | $NS) $CM* [$LB20NonBreaks-$CM];     #  . x (BA | HY | NS)
 575
 576 $CM* [$LB20NonBreaks-$CM] $CM* $BB;                   #  BB x .
 577 [^$CB] $CM* $BB;                                      #
 578
 579 # LB21a
 580 [^$CB] $CM* ($HY | $BA) $CM* $HL;
 581
 582 # LB21b (reverse)
 583 $CM* $HL $CM* $SY;
 584
 585 # LB 22
 586 $CM* $IN $CM* ($ALPlus | $HL);
 587 $CM* $IN $CM* $ID;
 588 $CM* $IN $CM* $IN;
 589 $CM* $IN $CM* $NU;
 590
 591 # LB 23
 592 $CM* $PO $CM* $ID;
 593 $CM* $NU $CM* ($ALPlus | $HL);
 594 $CM* ($ALPlus | $HL) $CM* $NU;
 595
 596 # LB 24
 597 $CM* $ID $CM* $PR;
 598 $CM* ($ALPlus | $HL) $CM* $PR;
 599 $CM* ($ALPlus | $HL) $CM* $PO;
 600
 601
 602 # LB 25
 603 ($CM* ($PR | $PO))? ($CM* ($CL | $CP))? ($CM* ($NU | $IS | $SY))* $CM* $NU ($CM* ($OP | $HY))? ($CM* ($PR | $PO))?;
 604
 605 # LB 26
 606 $CM* ($H3 | $H2 | $JV | $JL) $CM* $JL;
 607 $CM* ($JT | $JV) $CM* ($H2 | $JV);
 608 $CM* $JT $CM* ($H3 | $JT);
 609
 610 # LB 27
 611 $CM* $IN $CM* ($H3 | $H2 | $JT | $JV | $JL);
 612 $CM* $PO $CM* ($H3 | $H2 | $JT | $JV | $JL);
 613 $CM* ($H3 | $H2 | $JT | $JV | $JL) $CM* $PR;
 614
 615 # LB 28
 616 $CM* ($ALPlus | $HL) $CM* ($ALPlus | $HL);
 617
 618
 619 # LB 29
 620 $CM* ($ALPlus | $HL) $CM* $IS;
 621
 622 # LB 30
 623 $CM* $OP $CM* ($ALPlus | $HL | $NU);
 624 $CM* ($ALPlus | $HL | $NU) $CM* $CP;
 625
 626 # LB 30a
 627 $CM* $RI $CM* $RI;
 628
 629 ## -------------------------------------------------
 630
 631 !!safe_reverse;
 632
 633 # LB 9
 634 $CM+ [^$CM $BK $CR $LF $NL $ZW $SP];
 635 $CM+ $SP / .;
 636
 637 # LB 14
 638 $SP+ $CM* $OP;
 639
 640 # LB 15
 641 $SP+ $CM* $QU;
 642
 643 # LB 16
 644 $SP+ $CM* ($CL | $CP);
 645
 646 # LB 17
 647 $SP+ $CM* $B2;
 648
 649 # LB 21
 650 $CM* ($HY | $BA) $CM* $HL;
 651
 652 # LB 25
 653 ($CM* ($IS | $SY))+ $CM* $NU;
 654 ($CL | $CP) $CM* ($NU | $IS | $SY);
 655
 656 # For dictionary-based break
 657 $dictionary $dictionary;
 658
 659 ## -------------------------------------------------
 660
 661 !!safe_forward;
 662
 663 # Skip forward over all character classes that are involved in
 664 #   rules containing patterns with possibly more than one char
 665 #   of context.
 666 #
 667 #  It might be slightly more efficient to have specific rules
 668 #  instead of one generic one, but only if we could
 669 #  turn off rule chaining.  We don't want to move more
 670 #  than necessary.
 671 #
 672 [$CM $OP $QU $CL $CP $B2 $PR $HY $BA $SP $dictionary]+ [^$CM $OP $QU $CL $CP $B2 $PR $HY $BA $dictionary];
 673 $dictionary $dictionary;
 674