data/c.m4

   1                                                             -*- Autoconf -*-
   2
   3 # C M4 Macros for Bison.
   4 # Copyright (C) 2002, 2004, 2005, 2006, 2007, 2008, 2009
   5 # Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ## ---------------- ##
  21 ## Identification.  ##
  22 ## ---------------- ##
  23
  24 # b4_comment_(TEXT, OPEN, CONTINUE, END)
  25 # -------------------------------------
  26 # Put TEXT in comment.  Avoid trailing spaces: don't indent empty lines.
  27 # Avoid adding indentation to the first line, as the indentation comes
  28 # from OPEN.  That's why we don't patsubst([$1], [^\(.\)], [   \1]).
  29 #
  30 # Prefix all the output lines with PREFIX.
  31 m4_define([b4_comment_], [$2[]m4_bpatsubst([$1], [
  32 \(.\)], [
  33 $3\1])$4])
  34
  35
  36 # b4_c_comment(TEXT, [PREFIX])
  37 # ----------------------------
  38 # Put TEXT in comment.  Avoid trailing spaces: don't indent empty lines.
  39 # Avoid adding indentation to the first line, as the indentation comes
  40 # from "/*".  That's why we don't patsubst([$1], [^\(.\)], [   \1]).
  41 #
  42 # Prefix all the output lines with PREFIX.
  43 m4_define([b4_c_comment],
  44 [b4_comment_([$1], [$2/* ], [$2   ], [$2  */])])
  45
  46
  47 # b4_comment(TEXT, [PREFIX])
  48 # --------------------------
  49 # By default, C comments.
  50 m4_define([b4_comment], [b4_c_comment($@)])
  51
  52
  53 # b4_identification
  54 # -----------------
  55 # Depends on individual skeletons to define b4_pure_flag, b4_push_flag, or
  56 # b4_pull_flag if they use the values of the %define variables api.pure or
  57 # api.push_pull.
  58 m4_define([b4_identification],
  59 [[/* Identify Bison output.  */
  60 #define YYBISON 1
  61
  62 /* Bison version.  */
  63 #define YYBISON_VERSION "]b4_version["
  64
  65 /* Skeleton name.  */
  66 #define YYSKELETON_NAME ]b4_skeleton[]m4_ifdef([b4_pure_flag], [[
  67
  68 /* Pure parsers.  */
  69 #define YYPURE ]b4_pure_flag])[]m4_ifdef([b4_push_flag], [[
  70
  71 /* Push parsers.  */
  72 #define YYPUSH ]b4_push_flag])[]m4_ifdef([b4_pull_flag], [[
  73
  74 /* Pull parsers.  */
  75 #define YYPULL ]b4_pull_flag])[
  76
  77 /* Using locations.  */
  78 #define YYLSP_NEEDED ]b4_locations_flag[
  79 ]])
  80
  81
  82 ## ---------------- ##
  83 ## Default values.  ##
  84 ## ---------------- ##
  85
  86 # If the %union is not named, its name is YYSTYPE.
  87 m4_define_default([b4_union_name], [YYSTYPE])
  88
  89 # If the %name-prefix is not given, it is yy.
  90 m4_define_default([b4_prefix], [yy])
  91
  92 ## ------------------------ ##
  93 ## Pure/impure interfaces.  ##
  94 ## ------------------------ ##
  95
  96 # b4_user_args
  97 # ------------
  98 m4_define([b4_user_args],
  99 [m4_ifset([b4_parse_param], [, b4_c_args(b4_parse_param)])])
 100
 101
 102 # b4_parse_param
 103 # --------------
 104 # If defined, b4_parse_param arrives double quoted, but below we prefer
 105 # it to be single quoted.
 106 m4_define([b4_parse_param],
 107 b4_parse_param)
 108
 109
 110 # b4_parse_param_for(DECL, FORMAL, BODY)
 111 # ---------------------------------------
 112 # Iterate over the user parameters, binding the declaration to DECL,
 113 # the formal name to FORMAL, and evaluating the BODY.
 114 m4_define([b4_parse_param_for],
 115 [m4_foreach([$1_$2], m4_defn([b4_parse_param]),
 116 [m4_pushdef([$1], m4_unquote(m4_car($1_$2)))dnl
 117 m4_pushdef([$2], m4_shift($1_$2))dnl
 118 $3[]dnl
 119 m4_popdef([$2])dnl
 120 m4_popdef([$1])dnl
 121 ])])
 122
 123 # b4_parse_param_use
 124 # ------------------
 125 # `YYUSE' all the parse-params.
 126 m4_define([b4_parse_param_use],
 127 [b4_parse_param_for([Decl], [Formal], [  YYUSE (Formal);
 128 ])dnl
 129 ])
 130
 131
 132 ## ------------ ##
 133 ## Data Types.  ##
 134 ## ------------ ##
 135
 136 # b4_int_type(MIN, MAX)
 137 # ---------------------
 138 # Return the smallest int type able to handle numbers ranging from
 139 # MIN to MAX (included).
 140 m4_define([b4_int_type],
 141 [m4_if(b4_ints_in($@,      [0],   [255]), [1], [unsigned char],
 142        b4_ints_in($@,   [-128],   [127]), [1], [signed char],
 143
 144        b4_ints_in($@,      [0], [65535]), [1], [unsigned short int],
 145        b4_ints_in($@, [-32768], [32767]), [1], [short int],
 146
 147        m4_eval([0 <= $1]),                [1], [unsigned int],
 148
 149                                                [int])])
 150
 151
 152 # b4_int_type_for(NAME)
 153 # ---------------------
 154 # Return the smallest int type able to handle numbers ranging from
 155 # `NAME_min' to `NAME_max' (included).
 156 m4_define([b4_int_type_for],
 157 [b4_int_type($1_min, $1_max)])
 158
 159
 160
 161 ## ---------##
 162 ## Values.  ##
 163 ## ---------##
 164
 165 # b4_null
 166 ---------
 167 # Return a null pointer constant.  NULL infringes on the user name
 168 # space in C, so use 0 rather than NULL.
 169 m4_define([b4_null], [0])
 170
 171
 172 # b4_integral_parser_table_define(TABLE-NAME, CONTENT, COMMENT)
 173 # -------------------------------------------------------------
 174 # Define "yy<TABLE-NAME>" which contents is CONTENT.
 175 m4_define([b4_integral_parser_table_define],
 176 [m4_ifval([$3], [b4_c_comment([$3], [  ])
 177 ])dnl
 178 static const b4_int_type_for([$2]) yy$1[[]] =
 179 {
 180   $2
 181 };dnl
 182 ])
 183
 184
 185 ## ------------------------- ##
 186 ## Assigning token numbers.  ##
 187 ## ------------------------- ##
 188
 189 # b4_token_define(TOKEN-NAME, TOKEN-NUMBER)
 190 # -----------------------------------------
 191 # Output the definition of this token as #define.
 192 m4_define([b4_token_define],
 193 [#define b4_percent_define_get([token.prefix])$1 $2
 194 ])
 195
 196
 197 # b4_token_defines(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 198 # -------------------------------------------------------
 199 # Output the definition of the tokens (if there are) as #defines.
 200 m4_define([b4_token_defines],
 201 [m4_if([$#$1], [1], [],
 202 [/* Tokens.  */
 203 m4_map([b4_token_define], [$@])])
 204 ])
 205
 206
 207 # b4_token_enum(TOKEN-NAME, TOKEN-NUMBER)
 208 # ---------------------------------------
 209 # Output the definition of this token as an enum.
 210 m4_define([b4_token_enum],
 211 [b4_percent_define_get([token.prefix])$1 = $2])
 212
 213
 214 # b4_token_enums(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 215 # -----------------------------------------------------
 216 # Output the definition of the tokens (if there are) as enums.
 217 m4_define([b4_token_enums],
 218 [m4_if([$#$1], [1], [],
 219 [/* Tokens.  */
 220 #ifndef YYTOKENTYPE
 221 # define YYTOKENTYPE
 222    /* Put the tokens into the symbol table, so that GDB and other debuggers
 223       know about them.  */
 224    enum yytokentype {
 225 m4_map_sep([     b4_token_enum], [,
 226 ],
 227            [$@])
 228    };
 229 #endif
 230 ])])
 231
 232
 233 # b4_token_enums_defines(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
 234 # -------------------------------------------------------------
 235 # Output the definition of the tokens (if there are any) as enums and, if POSIX
 236 # Yacc is enabled, as #defines.
 237 m4_define([b4_token_enums_defines],
 238 [b4_token_enums($@)b4_yacc_if([b4_token_defines($@)], [])
 239 ])
 240
 241
 242 ## ----------------- ##
 243 ## Semantic Values.  ##
 244 ## ----------------- ##
 245
 246
 247 # b4_symbol_value(VAL, [TYPE])
 248 # ----------------------------
 249 # Given a semantic value VAL ($$, $1 etc.), extract its value of type
 250 # TYPE if TYPE is given, otherwise just return VAL.  The result can be
 251 # used safetly, it is put in parens to avoid nasty precedence issues.
 252 # TYPE is *not* put in braces, provide some if needed.
 253 m4_define([b4_symbol_value],
 254 [($1[]m4_ifval([$2], [.$2]))])
 255
 256
 257
 258 ## --------------------------------------------- ##
 259 ## Defining C functions in both K&R and ANSI-C.  ##
 260 ## --------------------------------------------- ##
 261
 262
 263 # b4_modern_c
 264 # -----------
 265 # A predicate useful in #if to determine whether C is ancient or modern.
 266 #
 267 # If __STDC__ is defined, the compiler is modern.  IBM xlc 7.0 when run
 268 # as 'cc' doesn't define __STDC__ (or __STDC_VERSION__) for pedantic
 269 # reasons, but it defines __C99__FUNC__ so check that as well.
 270 # Microsoft C normally doesn't define these macros, but it defines _MSC_VER.
 271 # Consider a C++ compiler to be modern if it defines __cplusplus.
 272 #
 273 m4_define([b4_c_modern],
 274   [[(defined __STDC__ || defined __C99__FUNC__ \
 275      || defined __cplusplus || defined _MSC_VER)]])
 276
 277 # b4_c_function_def(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 278 # ----------------------------------------------------------
 279 # Declare the function NAME.
 280 m4_define([b4_c_function_def],
 281 [#if b4_c_modern
 282 b4_c_ansi_function_def($@)
 283 #else
 284 $2
 285 $1 (b4_c_knr_formal_names(m4_shift2($@)))
 286 b4_c_knr_formal_decls(m4_shift2($@))
 287 #endif[]dnl
 288 ])
 289
 290
 291 # b4_c_ansi_function_def(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 292 # ---------------------------------------------------------------
 293 # Declare the function NAME in ANSI.
 294 m4_define([b4_c_ansi_function_def],
 295 [$2
 296 $1 (b4_c_ansi_formals(m4_shift2($@)))[]dnl
 297 ])
 298
 299
 300 # b4_c_ansi_formals([DECL1, NAME1], ...)
 301 # --------------------------------------
 302 # Output the arguments ANSI-C definition.
 303 m4_define([b4_c_ansi_formals],
 304 [m4_if([$#], [0], [void],
 305        [$#$1], [1], [void],
 306                [m4_map_sep([b4_c_ansi_formal], [, ], [$@])])])
 307
 308 m4_define([b4_c_ansi_formal],
 309 [$1])
 310
 311
 312 # b4_c_knr_formal_names([DECL1, NAME1], ...)
 313 # ------------------------------------------
 314 # Output the argument names.
 315 m4_define([b4_c_knr_formal_names],
 316 [m4_map_sep([b4_c_knr_formal_name], [, ], [$@])])
 317
 318 m4_define([b4_c_knr_formal_name],
 319 [$2])
 320
 321
 322 # b4_c_knr_formal_decls([DECL1, NAME1], ...)
 323 # ------------------------------------------
 324 # Output the K&R argument declarations.
 325 m4_define([b4_c_knr_formal_decls],
 326 [m4_map_sep([b4_c_knr_formal_decl],
 327             [
 328 ],
 329             [$@])])
 330
 331 m4_define([b4_c_knr_formal_decl],
 332 [    $1;])
 333
 334
 335
 336 ## ------------------------------------------------------------ ##
 337 ## Declaring (prototyping) C functions in both K&R and ANSI-C.  ##
 338 ## ------------------------------------------------------------ ##
 339
 340
 341 # b4_c_function_decl(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 342 # -----------------------------------------------------------
 343 # Declare the function NAME.
 344 m4_define([b4_c_function_decl],
 345 [#if b4_c_modern
 346 b4_c_ansi_function_decl($@)
 347 #else
 348 $2 $1 ();
 349 #endif[]dnl
 350 ])
 351
 352
 353 # b4_c_ansi_function_decl(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 354 # ----------------------------------------------------------------
 355 # Declare the function NAME.
 356 m4_define([b4_c_ansi_function_decl],
 357 [$2 $1 (b4_c_ansi_formals(m4_shift2($@)));[]dnl
 358 ])
 359
 360
 361
 362
 363 ## --------------------- ##
 364 ## Calling C functions.  ##
 365 ## --------------------- ##
 366
 367
 368 # b4_c_function_call(NAME, RETURN-VALUE, [DECL1, NAME1], ...)
 369 # -----------------------------------------------------------
 370 # Call the function NAME with arguments NAME1, NAME2 etc.
 371 m4_define([b4_c_function_call],
 372 [$1 (b4_c_args(m4_shift2($@)))[]dnl
 373 ])
 374
 375
 376 # b4_c_args([DECL1, NAME1], ...)
 377 # ------------------------------
 378 # Output the arguments NAME1, NAME2...
 379 m4_define([b4_c_args],
 380 [m4_map_sep([b4_c_arg], [, ], [$@])])
 381
 382 m4_define([b4_c_arg],
 383 [$2])
 384
 385
 386 ## ----------- ##
 387 ## Synclines.  ##
 388 ## ----------- ##
 389
 390 # b4_sync_start(LINE, FILE)
 391 # -----------------------
 392 m4_define([b4_sync_start], [[#]line $1 $2])
 393
 394
 395 ## -------------- ##
 396 ## User actions.  ##
 397 ## -------------- ##
 398
 399 # b4_case(LABEL, STATEMENTS)
 400 # --------------------------
 401 m4_define([b4_case],
 402 [  case $1:
 403 $2
 404 b4_syncline([@oline@], [@ofile@])
 405     break;])
 406
 407
 408 # b4_yydestruct_generate(FUNCTION-DECLARATOR)
 409 # -------------------------------------------
 410 # Generate the "yydestruct" function, which declaration is issued using
 411 # FUNCTION-DECLARATOR, which may be "b4_c_ansi_function_def" for ISO C
 412 # or "b4_c_function_def" for K&R.
 413 m4_define_default([b4_yydestruct_generate],
 414 [[/*-----------------------------------------------.
 415 | Release the memory associated to this symbol.  |
 416 `-----------------------------------------------*/
 417
 418 /*ARGSUSED*/
 419 ]$1([yydestruct],
 420     [static void],
 421     [[const char *yymsg],    [yymsg]],
 422     [[int yytype],           [yytype]],
 423     [[YYSTYPE *yyvaluep],    [yyvaluep]][]dnl
 424 b4_locations_if(            [, [[YYLTYPE *yylocationp], [yylocationp]]])[]dnl
 425 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 426 {
 427   YYUSE (yyvaluep);
 428 ]b4_locations_if([  YYUSE (yylocationp);
 429 ])dnl
 430 b4_parse_param_use[]dnl
 431 [
 432   if (!yymsg)
 433     yymsg = "Deleting";
 434   YY_SYMBOL_PRINT (yymsg, yytype, yyvaluep, yylocationp);
 435
 436   switch (yytype)
 437     {
 438 ]b4_symbol_foreach([b4_symbol_destructor])dnl
 439 [      default:
 440         break;
 441     }
 442 }]dnl
 443 ])
 444
 445
 446 # b4_yy_symbol_print_generate(FUNCTION-DECLARATOR)
 447 # ------------------------------------------------
 448 # Generate the "yy_symbol_print" function, which declaration is issued using
 449 # FUNCTION-DECLARATOR, which may be "b4_c_ansi_function_def" for ISO C
 450 # or "b4_c_function_def" for K&R.
 451 m4_define_default([b4_yy_symbol_print_generate],
 452 [[
 453 /*--------------------------------.
 454 | Print this symbol on YYOUTPUT.  |
 455 `--------------------------------*/
 456
 457 /*ARGSUSED*/
 458 ]$1([yy_symbol_value_print],
 459     [static void],
 460                [[FILE *yyoutput],                       [yyoutput]],
 461                [[int yytype],                           [yytype]],
 462                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 463 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 464 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 465 {
 466   if (!yyvaluep)
 467     return;
 468 ]b4_locations_if([  YYUSE (yylocationp);
 469 ])dnl
 470 b4_parse_param_use[]dnl
 471 [# ifdef YYPRINT
 472   if (yytype < YYNTOKENS)
 473     YYPRINT (yyoutput, yytoknum[yytype], *yyvaluep);
 474 # else
 475   YYUSE (yyoutput);
 476 # endif
 477   switch (yytype)
 478     {
 479 ]b4_symbol_foreach([b4_symbol_printer])dnl
 480 [      default:
 481         break;
 482     }
 483 }
 484
 485
 486 /*--------------------------------.
 487 | Print this symbol on YYOUTPUT.  |
 488 `--------------------------------*/
 489
 490 ]$1([yy_symbol_print],
 491     [static void],
 492                [[FILE *yyoutput],                       [yyoutput]],
 493                [[int yytype],                           [yytype]],
 494                [[YYSTYPE const * const yyvaluep],       [yyvaluep]][]dnl
 495 b4_locations_if([, [[YYLTYPE const * const yylocationp], [yylocationp]]])[]dnl
 496 m4_ifset([b4_parse_param], [, b4_parse_param]))[
 497 {
 498   if (yytype < YYNTOKENS)
 499     YYFPRINTF (yyoutput, "token %s (", yytname[yytype]);
 500   else
 501     YYFPRINTF (yyoutput, "nterm %s (", yytname[yytype]);
 502
 503 ]b4_locations_if([  YY_LOCATION_PRINT (yyoutput, *yylocationp);
 504   YYFPRINTF (yyoutput, ": ");
 505 ])dnl
 506 [  yy_symbol_value_print (yyoutput, yytype, yyvaluep]dnl
 507 b4_locations_if([, yylocationp])[]b4_user_args[);
 508   YYFPRINTF (yyoutput, ")");
 509 }]dnl
 510 ])