src/scan-gram.l

   1 /* Bison Grammar Scanner                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009
   4    Free Software Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    This program is free software: you can redistribute it and/or modify
   9    it under the terms of the GNU General Public License as published by
  10    the Free Software Foundation, either version 3 of the License, or
  11    (at your option) any later version.
  12
  13    This program is distributed in the hope that it will be useful,
  14    but WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16    GNU General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with this program.  If not, see <http://www.gnu.org/licenses/>.  */
  20
  21 %option debug nodefault nounput noyywrap never-interactive
  22 %option prefix="gram_" outfile="lex.yy.c"
  23
  24 %{
  25 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  26    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  27 #undef gram_wrap
  28 #define gram_wrap() 1
  29
  30 #define FLEX_PREFIX(Id) gram_ ## Id
  31 #include <src/flex-scanner.h>
  32
  33 #include <src/complain.h>
  34 #include <src/files.h>
  35 #include <src/gram.h>
  36 #include <quotearg.h>
  37 #include <src/reader.h>
  38 #include <src/uniqstr.h>
  39
  40 #include <mbswidth.h>
  41 #include <quote.h>
  42
  43 #include <src/scan-gram.h>
  44
  45 #define YY_DECL GRAM_LEX_DECL
  46
  47 #define YY_USER_INIT                                    \
  48    code_start = scanner_cursor = loc->start;            \
  49
  50 /* Location of scanner cursor.  */
  51 static boundary scanner_cursor;
  52
  53 #define YY_USER_ACTION  location_compute (loc, &scanner_cursor, yytext, yyleng);
  54
  55 static size_t no_cr_read (FILE *, char *, size_t);
  56 #define YY_INPUT(buf, result, size) ((result) = no_cr_read (yyin, buf, size))
  57
  58 #define RETURN_PERCENT_FLAG(Value)              \
  59   do {                                          \
  60     val->uniqstr = uniqstr_new (Value);         \
  61     return PERCENT_FLAG;                        \
  62   } while (0)
  63
  64 #define ROLLBACK_CURRENT_TOKEN                                  \
  65   do {                                                          \
  66     scanner_cursor.column -= mbsnwidth (yytext, yyleng, 0);     \
  67     yyless (0);                                                 \
  68   } while (0)
  69
  70 /* A string representing the most recently saved token.  */
  71 static char *last_string;
  72
  73 /* Bracketed identifier */
  74 static uniqstr bracketed_id_str = 0;
  75 static location bracketed_id_loc;
  76 static boundary bracketed_id_start;
  77 static int bracketed_id_context_state = 0;
  78
  79 void
  80 gram_scanner_last_string_free (void)
  81 {
  82   STRING_FREE;
  83 }
  84
  85 static void handle_syncline (char *, location);
  86 static unsigned long int scan_integer (char const *p, int base, location loc);
  87 static int convert_ucn_to_byte (char const *hex_text);
  88 static void unexpected_eof (boundary, char const *);
  89 static void unexpected_newline (boundary, char const *);
  90
  91 %}
  92  /* A C-like comment in directives/rules. */
  93 %x SC_YACC_COMMENT
  94  /* Strings and characters in directives/rules. */
  95 %x SC_ESCAPED_STRING SC_ESCAPED_CHARACTER
  96  /* A identifier was just read in directives/rules.  Special state
  97     to capture the sequence `identifier :'. */
  98 %x SC_AFTER_IDENTIFIER
  99  /* A complex tag, with nested angles brackets. */
 100 %x SC_TAG
 101
 102  /* Three types of user code:
 103     - prologue (code between `%{' `%}' in the first section, before %%);
 104     - actions, printers, union, etc, (between braced in the middle section);
 105     - epilogue (everything after the second %%). */
 106 %x SC_PROLOGUE SC_BRACED_CODE SC_EPILOGUE
 107  /* C and C++ comments in code. */
 108 %x SC_COMMENT SC_LINE_COMMENT
 109  /* Strings and characters in code. */
 110 %x SC_STRING SC_CHARACTER
 111  /* Bracketed identifiers support */
 112 %x SC_BRACKETED_ID SC_RETURN_BRACKETED_ID
 113
 114 letter    [-.abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_]
 115 id        {letter}({letter}|[0-9])*
 116 directive %{id}
 117 int       [0-9]+
 118
 119 /* POSIX says that a tag must be both an id and a C union member, but
 120    historically almost any character is allowed in a tag.  We disallow
 121    NUL, as this simplifies our implementation.  We disallow angle
 122    bracket to match them in nested pairs: several languages use them
 123    for generics/template types.  */
 124 tag      [^\0<>]+
 125
 126 /* Zero or more instances of backslash-newline.  Following GCC, allow
 127    white space between the backslash and the newline.  */
 128 splice   (\\[ \f\t\v]*\n)*
 129
 130 %%
 131 %{
 132   /* Nesting level.  Either for nested braces, or nested angle brackets
 133      (but not mixed).  */
 134   int nesting IF_LINT (= 0);
 135
 136   /* Parent context state, when applicable.  */
 137   int context_state IF_LINT (= 0);
 138
 139   /* Location of most recent identifier, when applicable.  */
 140   location id_loc IF_LINT (= empty_location);
 141
 142   /* Where containing code started, when applicable.  Its initial
 143      value is relevant only when yylex is invoked in the SC_EPILOGUE
 144      start condition.  */
 145   boundary code_start = scanner_cursor;
 146
 147   /* Where containing comment or string or character literal started,
 148      when applicable.  */
 149   boundary token_start IF_LINT (= scanner_cursor);
 150 %}
 151
 152
 153   /*-----------------------.
 154   | Scanning white space.  |
 155   `-----------------------*/
 156
 157 <INITIAL,SC_AFTER_IDENTIFIER,SC_BRACKETED_ID,SC_RETURN_BRACKETED_ID>
 158 {
 159   /* Comments and white space.  */
 160   ","          warn_at (*loc, _("stray `,' treated as white space"));
 161   [ \f\n\t\v]  |
 162   "//".*       ;
 163   "/*" {
 164     token_start = loc->start;
 165     context_state = YY_START;
 166     BEGIN SC_YACC_COMMENT;
 167   }
 168
 169   /* #line directives are not documented, and may be withdrawn or
 170      modified in future versions of Bison.  */
 171   ^"#line "{int}" \"".*"\"\n" {
 172     handle_syncline (yytext + sizeof "#line " - 1, *loc);
 173   }
 174 }
 175
 176
 177   /*----------------------------.
 178   | Scanning Bison directives.  |
 179   `----------------------------*/
 180
 181   /* For directives that are also command line options, the regex must be
 182         "%..."
 183      after "[-_]"s are removed, and the directive must match the --long
 184      option name, with a single string argument.  Otherwise, add exceptions
 185      to ../build-aux/cross-options.pl.  */
 186
 187 <INITIAL>
 188 {
 189   "%binary"                         return PERCENT_NONASSOC;
 190   "%code"                           return PERCENT_CODE;
 191   "%debug"                          RETURN_PERCENT_FLAG("parse.trace");
 192   "%default"[-_]"prec"              return PERCENT_DEFAULT_PREC;
 193   "%define"                         return PERCENT_DEFINE;
 194   "%defines"                        return PERCENT_DEFINES;
 195   "%destructor"                     return PERCENT_DESTRUCTOR;
 196   "%dprec"                          return PERCENT_DPREC;
 197   "%error"[-_]"verbose"             RETURN_PERCENT_FLAG("error-verbose");
 198   "%expect"                         return PERCENT_EXPECT;
 199   "%expect"[-_]"rr"                 return PERCENT_EXPECT_RR;
 200   "%file-prefix"                    return PERCENT_FILE_PREFIX;
 201   "%fixed"[-_]"output"[-_]"files"   return PERCENT_YACC;
 202   "%initial-action"                 return PERCENT_INITIAL_ACTION;
 203   "%glr-parser"                     return PERCENT_GLR_PARSER;
 204   "%language"                       return PERCENT_LANGUAGE;
 205   "%left"                           return PERCENT_LEFT;
 206   "%lex-param"                      return PERCENT_LEX_PARAM;
 207   "%locations"                      RETURN_PERCENT_FLAG("locations");
 208   "%merge"                          return PERCENT_MERGE;
 209   "%name"[-_]"prefix"               return PERCENT_NAME_PREFIX;
 210   "%no"[-_]"default"[-_]"prec"      return PERCENT_NO_DEFAULT_PREC;
 211   "%no"[-_]"lines"                  return PERCENT_NO_LINES;
 212   "%nonassoc"                       return PERCENT_NONASSOC;
 213   "%nondeterministic-parser"        return PERCENT_NONDETERMINISTIC_PARSER;
 214   "%nterm"                          return PERCENT_NTERM;
 215   "%output"                         return PERCENT_OUTPUT;
 216   "%parse-param"                    return PERCENT_PARSE_PARAM;
 217   "%prec"                           return PERCENT_PREC;
 218   "%precedence"                     return PERCENT_PRECEDENCE;
 219   "%printer"                        return PERCENT_PRINTER;
 220   "%pure"[-_]"parser"               RETURN_PERCENT_FLAG("api.pure");
 221   "%require"                        return PERCENT_REQUIRE;
 222   "%right"                          return PERCENT_RIGHT;
 223   "%skeleton"                       return PERCENT_SKELETON;
 224   "%start"                          return PERCENT_START;
 225   "%term"                           return PERCENT_TOKEN;
 226   "%token"                          return PERCENT_TOKEN;
 227   "%token"[-_]"table"               return PERCENT_TOKEN_TABLE;
 228   "%type"                           return PERCENT_TYPE;
 229   "%union"                          return PERCENT_UNION;
 230   "%verbose"                        return PERCENT_VERBOSE;
 231   "%yacc"                           return PERCENT_YACC;
 232
 233   {directive} {
 234     complain_at (*loc, _("invalid directive: %s"), quote (yytext));
 235   }
 236
 237   "="                     return EQUAL;
 238   "|"                     return PIPE;
 239   ";"                     return SEMICOLON;
 240
 241   {id} {
 242     val->uniqstr = uniqstr_new (yytext);
 243     id_loc = *loc;
 244     bracketed_id_str = NULL;
 245     BEGIN SC_AFTER_IDENTIFIER;
 246   }
 247
 248   {int} {
 249     val->integer = scan_integer (yytext, 10, *loc);
 250     return INT;
 251   }
 252   0[xX][0-9abcdefABCDEF]+ {
 253     val->integer = scan_integer (yytext, 16, *loc);
 254     return INT;
 255   }
 256
 257   /* Identifiers may not start with a digit.  Yet, don't silently
 258      accept "1FOO" as "1 FOO".  */
 259   {int}{id} {
 260     complain_at (*loc, _("invalid identifier: %s"), quote (yytext));
 261   }
 262
 263   /* Characters.  We don't check there is only one.  */
 264   "'"         STRING_GROW; token_start = loc->start; BEGIN SC_ESCAPED_CHARACTER;
 265
 266   /* Strings. */
 267   "\""        token_start = loc->start; BEGIN SC_ESCAPED_STRING;
 268
 269   /* Prologue. */
 270   "%{"        code_start = loc->start; BEGIN SC_PROLOGUE;
 271
 272   /* Code in between braces.  */
 273   "{" {
 274     STRING_GROW;
 275     nesting = 0;
 276     code_start = loc->start;
 277     BEGIN SC_BRACED_CODE;
 278   }
 279
 280   /* A type. */
 281   "<*>"       return TAG_ANY;
 282   "<>"        return TAG_NONE;
 283   "<"{tag}">" {
 284     obstack_grow (&obstack_for_string, yytext + 1, yyleng - 2);
 285     STRING_FINISH;
 286     val->uniqstr = uniqstr_new (last_string);
 287     STRING_FREE;
 288     return TAG;
 289   }
 290   "<"         {
 291     nesting = 0;
 292     token_start = loc->start;
 293     BEGIN SC_TAG;
 294   }
 295
 296   "%%" {
 297     static int percent_percent_count;
 298     if (++percent_percent_count == 2)
 299       BEGIN SC_EPILOGUE;
 300     return PERCENT_PERCENT;
 301   }
 302
 303   "[" {
 304     bracketed_id_str = NULL;
 305     bracketed_id_start = loc->start;
 306     bracketed_id_context_state = YY_START;
 307     BEGIN SC_BRACKETED_ID;
 308   }
 309
 310   . {
 311     complain_at (*loc, _("invalid character: %s"), quote (yytext));
 312   }
 313
 314   <<EOF>> {
 315     loc->start = loc->end = scanner_cursor;
 316     yyterminate ();
 317   }
 318 }
 319
 320
 321   /*--------------------------------------------------------------.
 322   | Supporting \0 complexifies our implementation for no expected |
 323   | added value.                                                  |
 324   `--------------------------------------------------------------*/
 325
 326 <SC_ESCAPED_CHARACTER,SC_ESCAPED_STRING,SC_TAG>
 327 {
 328   \0        complain_at (*loc, _("invalid null character"));
 329 }
 330
 331
 332   /*-----------------------------------------------------------------.
 333   | Scanning after an identifier, checking whether a colon is next.  |
 334   `-----------------------------------------------------------------*/
 335
 336 <SC_AFTER_IDENTIFIER>
 337 {
 338   "[" {
 339     if (!bracketed_id_str)
 340       {
 341         bracketed_id_start = loc->start;
 342         bracketed_id_context_state = YY_START;
 343         BEGIN SC_BRACKETED_ID;
 344       }
 345     else
 346       {
 347         ROLLBACK_CURRENT_TOKEN;
 348         BEGIN SC_RETURN_BRACKETED_ID;
 349         *loc = id_loc;
 350         return ID;
 351       }
 352   }
 353   ":" {
 354     BEGIN (bracketed_id_str ? SC_RETURN_BRACKETED_ID : INITIAL);
 355     *loc = id_loc;
 356     return ID_COLON;
 357   }
 358   . {
 359     ROLLBACK_CURRENT_TOKEN;
 360     BEGIN (bracketed_id_str ? SC_RETURN_BRACKETED_ID : INITIAL);
 361     *loc = id_loc;
 362     return ID;
 363   }
 364   <<EOF>> {
 365     BEGIN (bracketed_id_str ? SC_RETURN_BRACKETED_ID : INITIAL);
 366     *loc = id_loc;
 367     return ID;
 368   }
 369 }
 370
 371   /*--------------------------------.
 372   | Scanning bracketed identifiers. |
 373   `--------------------------------*/
 374
 375 <SC_BRACKETED_ID>
 376 {
 377   {id} {
 378     if (!bracketed_id_str)
 379       {
 380         bracketed_id_str = uniqstr_new (yytext);
 381         bracketed_id_loc = *loc;
 382       }
 383     else
 384       {
 385         complain_at (*loc, _("redundant identifier in bracketed name: %s"),
 386                      quote (yytext));
 387       }
 388   }
 389   "]" {
 390     BEGIN bracketed_id_context_state;
 391     if (bracketed_id_str)
 392       {
 393         if (INITIAL == bracketed_id_context_state)
 394           {
 395             val->uniqstr = bracketed_id_str;
 396             bracketed_id_str = 0;
 397             *loc = bracketed_id_loc;
 398             return BRACKETED_ID;
 399           }
 400       }
 401     else
 402       complain_at (*loc, _("a non empty identifier expected"));
 403   }
 404   . {
 405     complain_at (*loc, _("invalid character in bracketed name: %s"),
 406                  quote (yytext));
 407   }
 408   <<EOF>> {
 409     BEGIN bracketed_id_context_state;
 410     unexpected_eof (bracketed_id_start, "]");
 411   }
 412 }
 413
 414 <SC_RETURN_BRACKETED_ID>
 415 {
 416   . {
 417     ROLLBACK_CURRENT_TOKEN;
 418     val->uniqstr = bracketed_id_str;
 419     bracketed_id_str = 0;
 420     *loc = bracketed_id_loc;
 421     BEGIN INITIAL;
 422     return BRACKETED_ID;
 423   }
 424 }
 425
 426
 427   /*---------------------------------------------------------------.
 428   | Scanning a Yacc comment.  The initial `/ *' is already eaten.  |
 429   `---------------------------------------------------------------*/
 430
 431 <SC_YACC_COMMENT>
 432 {
 433   "*/"     BEGIN context_state;
 434   .|\n     ;
 435   <<EOF>>  unexpected_eof (token_start, "*/"); BEGIN context_state;
 436 }
 437
 438
 439   /*------------------------------------------------------------.
 440   | Scanning a C comment.  The initial `/ *' is already eaten.  |
 441   `------------------------------------------------------------*/
 442
 443 <SC_COMMENT>
 444 {
 445   "*"{splice}"/"  STRING_GROW; BEGIN context_state;
 446   <<EOF>>         unexpected_eof (token_start, "*/"); BEGIN context_state;
 447 }
 448
 449
 450   /*--------------------------------------------------------------.
 451   | Scanning a line comment.  The initial `//' is already eaten.  |
 452   `--------------------------------------------------------------*/
 453
 454 <SC_LINE_COMMENT>
 455 {
 456   "\n"           STRING_GROW; BEGIN context_state;
 457   {splice}       STRING_GROW;
 458   <<EOF>>        BEGIN context_state;
 459 }
 460
 461
 462   /*------------------------------------------------.
 463   | Scanning a Bison string, including its escapes. |
 464   | The initial quote is already eaten.             |
 465   `------------------------------------------------*/
 466
 467 <SC_ESCAPED_STRING>
 468 {
 469   "\""|"\n" {
 470     if (yytext[0] == '\n')
 471       unexpected_newline (token_start, "\"");
 472     STRING_FINISH;
 473     loc->start = token_start;
 474     val->chars = last_string;
 475     BEGIN INITIAL;
 476     return STRING;
 477   }
 478   <<EOF>> {
 479     unexpected_eof (token_start, "\"");
 480     STRING_FINISH;
 481     loc->start = token_start;
 482     val->chars = last_string;
 483     BEGIN INITIAL;
 484     return STRING;
 485   }
 486 }
 487
 488   /*----------------------------------------------------------.
 489   | Scanning a Bison character literal, decoding its escapes. |
 490   | The initial quote is already eaten.                       |
 491   `----------------------------------------------------------*/
 492
 493 <SC_ESCAPED_CHARACTER>
 494 {
 495   "'"|"\n" {
 496     if (yytext[0] == '\n')
 497       unexpected_newline (token_start, "'");
 498     STRING_GROW;
 499     STRING_FINISH;
 500     loc->start = token_start;
 501     val->character = last_string[1];
 502     STRING_FREE;
 503     BEGIN INITIAL;
 504     return CHAR;
 505   }
 506   <<EOF>> {
 507     unexpected_eof (token_start, "'");
 508     STRING_FINISH;
 509     loc->start = token_start;
 510     if (strlen (last_string) > 1)
 511       val->character = last_string[1];
 512     else
 513       val->character = last_string[0];
 514     STRING_FREE;
 515     BEGIN INITIAL;
 516     return CHAR;
 517   }
 518 }
 519
 520   /*-----------------------------------------------------------.
 521   | Scanning a Bison nested tag.  The initial angle bracket is |
 522   | already eaten.                                             |
 523   `-----------------------------------------------------------*/
 524
 525 <SC_TAG>
 526 {
 527   ">" {
 528     --nesting;
 529     if (nesting < 0)
 530       {
 531         STRING_FINISH;
 532         loc->start = token_start;
 533         val->uniqstr = uniqstr_new (last_string);
 534         STRING_FREE;
 535         BEGIN INITIAL;
 536         return TAG;
 537       }
 538     STRING_GROW;
 539   }
 540
 541   [^<>]+ STRING_GROW;
 542   "<"+   STRING_GROW; nesting += yyleng;
 543
 544   <<EOF>> {
 545     unexpected_eof (token_start, ">");
 546     STRING_FINISH;
 547     loc->start = token_start;
 548     val->uniqstr = uniqstr_new (last_string);
 549     STRING_FREE;
 550     BEGIN INITIAL;
 551     return TAG;
 552   }
 553 }
 554
 555   /*----------------------------.
 556   | Decode escaped characters.  |
 557   `----------------------------*/
 558
 559 <SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>
 560 {
 561   \\[0-7]{1,3} {
 562     unsigned long int c = strtoul (yytext + 1, NULL, 8);
 563     if (UCHAR_MAX < c)
 564       complain_at (*loc, _("invalid escape sequence: %s"), quote (yytext));
 565     else if (! c)
 566       complain_at (*loc, _("invalid null character: %s"), quote (yytext));
 567     else
 568       obstack_1grow (&obstack_for_string, c);
 569   }
 570
 571   \\x[0-9abcdefABCDEF]+ {
 572     verify (UCHAR_MAX < ULONG_MAX);
 573     unsigned long int c = strtoul (yytext + 2, NULL, 16);
 574     if (UCHAR_MAX < c)
 575       complain_at (*loc, _("invalid escape sequence: %s"), quote (yytext));
 576     else if (! c)
 577       complain_at (*loc, _("invalid null character: %s"), quote (yytext));
 578     else
 579       obstack_1grow (&obstack_for_string, c);
 580   }
 581
 582   \\a   obstack_1grow (&obstack_for_string, '\a');
 583   \\b   obstack_1grow (&obstack_for_string, '\b');
 584   \\f   obstack_1grow (&obstack_for_string, '\f');
 585   \\n   obstack_1grow (&obstack_for_string, '\n');
 586   \\r   obstack_1grow (&obstack_for_string, '\r');
 587   \\t   obstack_1grow (&obstack_for_string, '\t');
 588   \\v   obstack_1grow (&obstack_for_string, '\v');
 589
 590   /* \\[\"\'?\\] would be shorter, but it confuses xgettext.  */
 591   \\("\""|"'"|"?"|"\\")  obstack_1grow (&obstack_for_string, yytext[1]);
 592
 593   \\(u|U[0-9abcdefABCDEF]{4})[0-9abcdefABCDEF]{4} {
 594     int c = convert_ucn_to_byte (yytext);
 595     if (c < 0)
 596       complain_at (*loc, _("invalid escape sequence: %s"), quote (yytext));
 597     else if (! c)
 598       complain_at (*loc, _("invalid null character: %s"), quote (yytext));
 599     else
 600       obstack_1grow (&obstack_for_string, c);
 601   }
 602   \\(.|\n)      {
 603     complain_at (*loc, _("unrecognized escape sequence: %s"), quote (yytext));
 604     STRING_GROW;
 605   }
 606 }
 607
 608   /*--------------------------------------------.
 609   | Scanning user-code characters and strings.  |
 610   `--------------------------------------------*/
 611
 612 <SC_CHARACTER,SC_STRING>
 613 {
 614   {splice}|\\{splice}[^\n\[\]]  STRING_GROW;
 615 }
 616
 617 <SC_CHARACTER>
 618 {
 619   "'"           STRING_GROW; BEGIN context_state;
 620   \n            unexpected_newline (token_start, "'"); BEGIN context_state;
 621   <<EOF>>       unexpected_eof (token_start, "'"); BEGIN context_state;
 622 }
 623
 624 <SC_STRING>
 625 {
 626   "\""          STRING_GROW; BEGIN context_state;
 627   \n            unexpected_newline (token_start, "\""); BEGIN context_state;
 628   <<EOF>>       unexpected_eof (token_start, "\""); BEGIN context_state;
 629 }
 630
 631
 632   /*---------------------------------------------------.
 633   | Strings, comments etc. can be found in user code.  |
 634   `---------------------------------------------------*/
 635
 636 <SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>
 637 {
 638   "'" {
 639     STRING_GROW;
 640     context_state = YY_START;
 641     token_start = loc->start;
 642     BEGIN SC_CHARACTER;
 643   }
 644   "\"" {
 645     STRING_GROW;
 646     context_state = YY_START;
 647     token_start = loc->start;
 648     BEGIN SC_STRING;
 649   }
 650   "/"{splice}"*" {
 651     STRING_GROW;
 652     context_state = YY_START;
 653     token_start = loc->start;
 654     BEGIN SC_COMMENT;
 655   }
 656   "/"{splice}"/" {
 657     STRING_GROW;
 658     context_state = YY_START;
 659     BEGIN SC_LINE_COMMENT;
 660   }
 661 }
 662
 663
 664
 665   /*-----------------------------------------------------------.
 666   | Scanning some code in braces (actions). The initial "{" is |
 667   | already eaten.                                             |
 668   `-----------------------------------------------------------*/
 669
 670 <SC_BRACED_CODE>
 671 {
 672   "{"|"<"{splice}"%"  STRING_GROW; nesting++;
 673   "%"{splice}">"      STRING_GROW; nesting--;
 674   "}" {
 675     obstack_1grow (&obstack_for_string, '}');
 676
 677     --nesting;
 678     if (nesting < 0)
 679       {
 680         STRING_FINISH;
 681         loc->start = code_start;
 682         val->code = last_string;
 683         BEGIN INITIAL;
 684         return BRACED_CODE;
 685       }
 686   }
 687
 688   /* Tokenize `<<%' correctly (as `<<' `%') rather than incorrrectly
 689      (as `<' `<%').  */
 690   "<"{splice}"<"  STRING_GROW;
 691
 692   <<EOF>> {
 693     unexpected_eof (code_start, "}");
 694     STRING_FINISH;
 695     loc->start = code_start;
 696     val->code = last_string;
 697     BEGIN INITIAL;
 698     return BRACED_CODE;
 699   }
 700 }
 701
 702
 703   /*--------------------------------------------------------------.
 704   | Scanning some prologue: from "%{" (already scanned) to "%}".  |
 705   `--------------------------------------------------------------*/
 706
 707 <SC_PROLOGUE>
 708 {
 709   "%}" {
 710     STRING_FINISH;
 711     loc->start = code_start;
 712     val->chars = last_string;
 713     BEGIN INITIAL;
 714     return PROLOGUE;
 715   }
 716
 717   <<EOF>> {
 718     unexpected_eof (code_start, "%}");
 719     STRING_FINISH;
 720     loc->start = code_start;
 721     val->chars = last_string;
 722     BEGIN INITIAL;
 723     return PROLOGUE;
 724   }
 725 }
 726
 727
 728   /*---------------------------------------------------------------.
 729   | Scanning the epilogue (everything after the second "%%", which |
 730   | has already been eaten).                                       |
 731   `---------------------------------------------------------------*/
 732
 733 <SC_EPILOGUE>
 734 {
 735   <<EOF>> {
 736     STRING_FINISH;
 737     loc->start = code_start;
 738     val->chars = last_string;
 739     BEGIN INITIAL;
 740     return EPILOGUE;
 741   }
 742 }
 743
 744
 745   /*-----------------------------------------------------.
 746   | By default, grow the string obstack with the input.  |
 747   `-----------------------------------------------------*/
 748
 749 <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE,SC_STRING,SC_CHARACTER,SC_ESCAPED_STRING,SC_ESCAPED_CHARACTER>.      |
 750 <SC_COMMENT,SC_LINE_COMMENT,SC_BRACED_CODE,SC_PROLOGUE,SC_EPILOGUE>\n   STRING_GROW;
 751
 752 %%
 753
 754 /* Read bytes from FP into buffer BUF of size SIZE.  Return the
 755    number of bytes read.  Remove '\r' from input, treating \r\n
 756    and isolated \r as \n.  */
 757
 758 static size_t
 759 no_cr_read (FILE *fp, char *buf, size_t size)
 760 {
 761   size_t bytes_read = fread (buf, 1, size, fp);
 762   if (bytes_read)
 763     {
 764       char *w = memchr (buf, '\r', bytes_read);
 765       if (w)
 766         {
 767           char const *r = ++w;
 768           char const *lim = buf + bytes_read;
 769
 770           for (;;)
 771             {
 772               /* Found an '\r'.  Treat it like '\n', but ignore any
 773                  '\n' that immediately follows.  */
 774               w[-1] = '\n';
 775               if (r == lim)
 776                 {
 777                   int ch = getc (fp);
 778                   if (ch != '\n' && ungetc (ch, fp) != ch)
 779                     break;
 780                 }
 781               else if (*r == '\n')
 782                 r++;
 783
 784               /* Copy until the next '\r'.  */
 785               do
 786                 {
 787                   if (r == lim)
 788                     return w - buf;
 789                 }
 790               while ((*w++ = *r++) != '\r');
 791             }
 792
 793           return w - buf;
 794         }
 795     }
 796
 797   return bytes_read;
 798 }
 799
 800
 801
 802 /*------------------------------------------------------.
 803 | Scan NUMBER for a base-BASE integer at location LOC.  |
 804 `------------------------------------------------------*/
 805
 806 static unsigned long int
 807 scan_integer (char const *number, int base, location loc)
 808 {
 809   verify (INT_MAX < ULONG_MAX);
 810   unsigned long int num = strtoul (number, NULL, base);
 811
 812   if (INT_MAX < num)
 813     {
 814       complain_at (loc, _("integer out of range: %s"), quote (number));
 815       num = INT_MAX;
 816     }
 817
 818   return num;
 819 }
 820
 821
 822 /*------------------------------------------------------------------.
 823 | Convert universal character name UCN to a single-byte character,  |
 824 | and return that character.  Return -1 if UCN does not correspond  |
 825 | to a single-byte character.                                       |
 826 `------------------------------------------------------------------*/
 827
 828 static int
 829 convert_ucn_to_byte (char const *ucn)
 830 {
 831   verify (UCHAR_MAX <= INT_MAX);
 832   unsigned long int code = strtoul (ucn + 2, NULL, 16);
 833
 834   /* FIXME: Currently we assume Unicode-compatible unibyte characters
 835      on ASCII hosts (i.e., Latin-1 on hosts with 8-bit bytes).  On
 836      non-ASCII hosts we support only the portable C character set.
 837      These limitations should be removed once we add support for
 838      multibyte characters.  */
 839
 840   if (UCHAR_MAX < code)
 841     return -1;
 842
 843 #if ! ('$' == 0x24 && '@' == 0x40 && '`' == 0x60 && '~' == 0x7e)
 844   {
 845     /* A non-ASCII host.  Use CODE to index into a table of the C
 846        basic execution character set, which is guaranteed to exist on
 847        all Standard C platforms.  This table also includes '$', '@',
 848        and '`', which are not in the basic execution character set but
 849        which are unibyte characters on all the platforms that we know
 850        about.  */
 851     static signed char const table[] =
 852       {
 853         '\0',   -1,   -1,   -1,   -1,   -1,   -1, '\a',
 854         '\b', '\t', '\n', '\v', '\f', '\r',   -1,   -1,
 855           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 856           -1,   -1,   -1,   -1,   -1,   -1,   -1,   -1,
 857          ' ',  '!',  '"',  '#',  '$',  '%',  '&', '\'',
 858          '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
 859          '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
 860          '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
 861          '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
 862          'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
 863          'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
 864          'X',  'Y',  'Z',  '[', '\\',  ']',  '^',  '_',
 865          '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
 866          'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
 867          'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
 868          'x',  'y',  'z',  '{',  '|',  '}',  '~'
 869       };
 870
 871     code = code < sizeof table ? table[code] : -1;
 872   }
 873 #endif
 874
 875   return code;
 876 }
 877
 878
 879 /*----------------------------------------------------------------.
 880 | Handle `#line INT "FILE"'.  ARGS has already skipped `#line '.  |
 881 `----------------------------------------------------------------*/
 882
 883 static void
 884 handle_syncline (char *args, location loc)
 885 {
 886   char *after_num;
 887   unsigned long int lineno = strtoul (args, &after_num, 10);
 888   char *file = strchr (after_num, '"') + 1;
 889   *strchr (file, '"') = '\0';
 890   if (INT_MAX <= lineno)
 891     {
 892       warn_at (loc, _("line number overflow"));
 893       lineno = INT_MAX;
 894     }
 895   current_file = uniqstr_new (file);
 896   boundary_set (&scanner_cursor, current_file, lineno, 1);
 897 }
 898
 899
 900 /*----------------------------------------------------------------.
 901 | For a token or comment starting at START, report message MSGID, |
 902 | which should say that an end marker was found before            |
 903 | the expected TOKEN_END.                                         |
 904 `----------------------------------------------------------------*/
 905
 906 static void
 907 unexpected_end (boundary start, char const *msgid, char const *token_end)
 908 {
 909   location loc;
 910   loc.start = start;
 911   loc.end = scanner_cursor;
 912   complain_at (loc, _(msgid), token_end);
 913 }
 914
 915
 916 /*------------------------------------------------------------------------.
 917 | Report an unexpected EOF in a token or comment starting at START.       |
 918 | An end of file was encountered and the expected TOKEN_END was missing.  |
 919 `------------------------------------------------------------------------*/
 920
 921 static void
 922 unexpected_eof (boundary start, char const *token_end)
 923 {
 924   unexpected_end (start, N_("missing `%s' at end of file"), token_end);
 925 }
 926
 927
 928 /*----------------------------------------.
 929 | Likewise, but for unexpected newlines.  |
 930 `----------------------------------------*/
 931
 932 static void
 933 unexpected_newline (boundary start, char const *token_end)
 934 {
 935   unexpected_end (start, N_("missing `%s' at end of line"), token_end);
 936 }
 937
 938
 939 /*-------------------------.
 940 | Initialize the scanner.  |
 941 `-------------------------*/
 942
 943 void
 944 gram_scanner_initialize (void)
 945 {
 946   obstack_init (&obstack_for_string);
 947 }
 948
 949
 950 /*-----------------------------------------------.
 951 | Free all the memory allocated to the scanner.  |
 952 `-----------------------------------------------*/
 953
 954 void
 955 gram_scanner_free (void)
 956 {
 957   obstack_free (&obstack_for_string, 0);
 958   /* Reclaim Flex's buffers.  */
 959   yylex_destroy ();
 960 }