tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We want a recent Autotest.
  21 m4_version_prereq([2.58])
  22
  23
  24 ## ------------- ##
  25 ## Basic tests.  ##
  26 ## ------------- ##
  27
  28 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  29 # ------------------------------------------
  30 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  31 # taken in "slurp" mode, i.e., one can match end-of-lines.
  32 m4_define([AT_MATCHES_CHECK],
  33 [AT_CHECK([perl -0777 -ne '
  34 my $count = 0;
  35 s{$2}{ ++$count; "" }gem;
  36 printf "$count\n";' $1], [0], [$3
  37 ])])
  38
  39
  40 ## ------------------------------- ##
  41 ## Macros decoding Bison options.  ##
  42 ## ------------------------------- ##
  43
  44 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  45 # ----------------------------------------------------------------
  46 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  47 m4_define([AT_LOC_PUSHDEF],
  48 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  49 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  50 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  51 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  52
  53 # AT_LOC_POPDEF
  54 # -------------
  55 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  56 m4_define([AT_LOC_POPDEF],
  57 [m4_popdef([AT_LOC_FIRST_LINE])
  58 m4_popdef([AT_LOC_FIRST_COLUMN])
  59 m4_popdef([AT_LOC_LAST_LINE])
  60 m4_popdef([AT_LOC_LAST_COLUMN])])
  61
  62
  63
  64 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  65 # -----------------------------------------
  66 m4_define([AT_BISON_OPTION_PUSHDEFS],
  67 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  68
  69
  70 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  71 # --------------------------------------------------
  72 # This macro works around the impossibility to define macros
  73 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  74 # This sucks hard, GNU M4 should really provide M5 like $$1.
  75 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  76 [m4_if([$1$2], $[1]$[2], [],
  77        [m4_fatal([$0: Invalid arguments: $@])])dnl
  78 m4_pushdef([AT_DEFINES_IF],
  79 [m4_bmatch([$3], [%defines], [$1], [$2])])
  80 m4_pushdef([AT_SKEL_CC_IF],
  81 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  82 m4_pushdef([AT_SKEL_JAVA_IF],
  83 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
  84 m4_pushdef([AT_GLR_IF],
  85 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  86 m4_pushdef([AT_LALR1_CC_IF],
  87 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  88 m4_pushdef([AT_GLR_CC_IF],
  89 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  90 # Using yacc.c?
  91 m4_pushdef([AT_YACC_IF],
  92 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  93 m4_pushdef([AT_LEXPARAM_IF],
  94 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  95 m4_pushdef([AT_LOCATION_IF],
  96 [m4_bmatch([$3], [%locations], [$1], [$2])])
  97 m4_pushdef([AT_LOCATION_TYPE_IF],
  98 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
  99 m4_pushdef([AT_PARAM_IF],
 100 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 101 m4_pushdef([AT_PURE_IF],
 102 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 103            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 104            [$2])])
 105 m4_pushdef([AT_PURE_AND_LOC_IF],
 106 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 107 m4_pushdef([AT_GLR_OR_PARAM_IF],
 108 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 109 m4_pushdef([AT_NAME_PREFIX],
 110 [m4_bmatch([$3], [%name-prefix ".*"],
 111            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
 112            [yy])])
 113 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 114 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 115 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 116                     [$2])])
 117 # yyerror always sees the locations (when activated), except if
 118 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 119 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 120 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 121                                         [$1])],
 122                             [$1])],
 123                 [$2])])
 124
 125 # The interface is pure: either because %define api.pure, or because we
 126 # are using the C++ parsers.
 127 m4_pushdef([AT_PURE_LEX_IF],
 128 [AT_PURE_IF([$1],
 129             [AT_SKEL_CC_IF([$1], [$2])])])
 130
 131 AT_PURE_LEX_IF(
 132 [m4_pushdef([AT_LOC], [(*llocp)])
 133  m4_pushdef([AT_VAL], [(*lvalp)])
 134  m4_pushdef([AT_LEX_FORMALS],
 135             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 136  m4_pushdef([AT_LEX_ARGS],
 137             [lvalp[]AT_LOCATION_IF([, llocp])])
 138  m4_pushdef([AT_USE_LEX_ARGS],
 139             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 140  m4_pushdef([AT_LEX_PRE_FORMALS],
 141             [AT_LEX_FORMALS, ])
 142  m4_pushdef([AT_LEX_PRE_ARGS],
 143             [AT_LEX_ARGS, ])
 144 ],
 145 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 146  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 147  m4_pushdef([AT_LEX_FORMALS],     [void])
 148  m4_pushdef([AT_LEX_ARGS],        [])
 149  m4_pushdef([AT_USE_LEX_ARGS],    [])
 150  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 151  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 152 ])
 153
 154 # Handle the different types of location components.
 155
 156 AT_SKEL_CC_IF(
 157   [AT_LOCATION_TYPE_IF(
 158     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 159     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 160   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 161
 162 ])# _AT_BISON_OPTION_PUSHDEFS
 163
 164
 165 # AT_BISON_OPTION_POPDEFS
 166 # -----------------------
 167 m4_define([AT_BISON_OPTION_POPDEFS],
 168 [m4_popdef([AT_LEX_PRE_ARGS])
 169 m4_popdef([AT_LEX_PRE_FORMALS])
 170 m4_popdef([AT_USE_LEX_ARGS])
 171 m4_popdef([AT_LEX_ARGS])
 172 m4_popdef([AT_LEX_FORMALS])
 173 m4_popdef([AT_VAL])
 174 m4_popdef([AT_LOC])
 175 m4_popdef([AT_PURE_LEX_IF])
 176 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 177 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 178 m4_popdef([AT_NAME_PREFIX])
 179 m4_popdef([AT_GLR_OR_PARAM_IF])
 180 m4_popdef([AT_PURE_AND_LOC_IF])
 181 m4_popdef([AT_LOCATION_TYPE_IF])
 182 m4_popdef([AT_LOCATION_IF])
 183 m4_popdef([AT_PARAM_IF])
 184 m4_popdef([AT_LEXPARAM_IF])
 185 m4_popdef([AT_YACC_IF])
 186 m4_popdef([AT_GLR_IF])
 187 m4_popdef([AT_SKEL_CC_IF])
 188 m4_popdef([AT_SKEL_JAVA_IF])
 189 m4_popdef([AT_GLR_CC_IF])
 190 m4_popdef([AT_LALR1_CC_IF])
 191 m4_popdef([AT_DEFINES_IF])
 192 AT_LOC_POPDEF
 193 ])# AT_BISON_OPTION_POPDEFS
 194
 195
 196
 197 ## -------------------------- ##
 198 ## Generating Grammar Files.  ##
 199 ## -------------------------- ##
 200
 201 # AT_DATA_SOURCE_PROLOGUE
 202 # ------------------------
 203 # The prologue that should be included in any source code that is
 204 # meant to be compiled.
 205 m4_define([AT_DATA_SOURCE_PROLOGUE],
 206 [[#include <config.h>
 207 /* We don't need perfect functions for these tests. */
 208 #undef malloc
 209 #undef memcmp
 210 #undef realloc
 211 ]])
 212
 213 # AT_DATA_GRAMMAR_PROLOGUE
 214 # ------------------------
 215 # The prologue that should be included in any grammar which parser is
 216 # meant to be compiled.
 217 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 218 [[%code top {
 219 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 220 [}
 221 ]])
 222
 223 # AT_DATA_SOURCE(NAME, CONTENT)
 224 # -----------------------------
 225 # Generate the file NAME, which CONTENT is preceded by
 226 # AT_DATA_SOURCE_PROLOGUE.
 227 m4_define([AT_DATA_SOURCE],
 228 [AT_DATA([$1],
 229 [AT_DATA_SOURCE_PROLOGUE
 230 $2])
 231 ])
 232
 233 # AT_DATA_GRAMMAR(NAME, CONTENT)
 234 # ------------------------------
 235 # Generate the file NAME, which CONTENT is preceded by
 236 # AT_DATA_GRAMMAR_PROLOGUE.
 237 m4_define([AT_DATA_GRAMMAR],
 238 [AT_DATA([$1],
 239 [AT_DATA_GRAMMAR_PROLOGUE
 240 $2])
 241 ])
 242
 243 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 244 # -------------------------------------------------
 245 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 246 # shell constructs (such as redirection or pipes) that would prevent
 247 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 248 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 249 #
 250 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 251 # Bison in the test suite.  For now it ensures that:
 252 #
 253 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 254 #      a non-zero exit status since Bison doesn't always try to free all memory
 255 #      in that case.
 256 #
 257 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 258 #      --graph and --report=all output for every working grammar.
 259 #
 260 #   3. If stderr contains a warning, -Werror and --warnings=error
 261 #      convert the warning to an error.
 262 #
 263 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 264 m4_define([AT_BISON_CHECK],
 265 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 266        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 267 AT_BISON_CHECK_NO_XML($@)])
 268
 269 m4_define([AT_BISON_WERROR_MSG],
 270           [[bison: warnings being treated as errors]])
 271
 272 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 273 # --------------------------------------------------------
 274 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 275 # when a tortured grammar's XML is known to be too large for xsltproc to
 276 # handle.
 277 m4_define([AT_BISON_CHECK_NO_XML],
 278 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 279                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 280 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 281       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 282         # Defining POSIXLY_CORRECT causes bison to complain if options
 283         # are added after the grammar file name, so skip these checks
 284         # in that case.
 285         if test -z "${POSIXLY_CORRECT+set}"; then
 286           # Don't interfere with caller's files.
 287           if test -f stderr; then mv stderr at-bison-check-stderr.bak; fi
 288           if test -f experr; then mv experr at-bison-check-experr.bak; fi
 289           if test -f expout; then mv expout at-bison-check-expout.bak; fi
 290
 291           # To avoid expanding it repeatedly, store specified stdout.
 292           ]AT_DATA([expout], [$3])[
 293
 294           # Run with -Werror.
 295           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 296                     [[1]], [expout], [stderr])[
 297
 298           # Build expected stderr up to and including the "warnings being
 299           # treated as errors" message.
 300           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 301           at_bison_check_first="` \
 302             sed -n '/: warning: /=' at-bison-check-warnings \
 303             | sed -n 1p \
 304           `"
 305           at_bison_check_first_tmp="` \
 306             sed -n '/conflicts: [0-9].*reduce$/=' at-bison-check-warnings \
 307             | sed -n 1p \
 308           `"
 309           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 310             at_bison_check_first=$at_bison_check_first_tmp
 311           fi
 312           if test $at_bison_check_first -gt 1; then
 313             sed -n "1,`expr $at_bison_check_first - 1`"p \
 314               at-bison-check-warnings > experr
 315           fi
 316           echo ']AT_BISON_WERROR_MSG[' >> experr
 317
 318           # Finish building expected stderr and check.  Unlike warnings,
 319           # complaints cause bison to exit early.  Thus, with -Werror, bison
 320           # does not necessarily report all warnings that it does without
 321           # -Werror, but it at least reports one.
 322           at_bison_check_last="`sed -n '$=' stderr`"
 323           if test x"$at_bison_check_last" = x; then
 324             at_bison_check_last=1
 325           fi
 326           at_bison_check_last="`expr $at_bison_check_last - 1`"
 327           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 328             at-bison-check-warnings >> experr
 329           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 330                       stderr 1>&2]], [[0]], [[]], [experr])[
 331
 332           # Now check --warnings=error.
 333           cp stderr experr
 334           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 335                     [[1]], [expout], [experr])[
 336
 337           # Now check -Wnone and --warnings=none by making sure that
 338           # -Werror doesn't change the exit status when -Wnone or
 339           # --warnings=none is specified.
 340           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 341                     [[0]], [expout])[
 342           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 343                     -Werror]], [[0]], [expout])[
 344
 345           # Restore caller's files.
 346           if test -f at-bison-check-expout.bak; then
 347             mv at-bison-check-expout.bak expout
 348           fi
 349           if test -f at-bison-check-experr.bak; then
 350             mv at-bison-check-experr.bak experr
 351           fi
 352           if test -f at-bison-check-stderr.bak; then
 353             mv at-bison-check-stderr.bak stderr
 354           fi
 355         fi
 356       ]])
 357 ])
 358
 359 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 360 # -----------------------------------------------------
 361 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 362 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 363 # have a non-zero exit status.
 364 m4_define([AT_BISON_CHECK_XML],
 365 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 366   mkdir xml-tests]
 367   m4_pushdef([AT_BISON_ARGS],
 368              [m4_bpatsubsts([[$1]],
 369                             [--report(-file)?=[^][ ]*], [],
 370                             [--graph=[^][ ]*], [],
 371                             [--xml=[^][ ]*], [])])dnl
 372   # Don't combine these Bison invocations since we want to be sure that
 373   # --report=all isn't required to get the full XML file.
 374   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 375              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 376            [[0]], [ignore], [ignore])
 377   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 378            [[0]], [ignore], [ignore])
 379   m4_popdef([AT_BISON_ARGS])dnl
 380   [cp xml-tests/test.output expout]
 381   AT_CHECK([[$XSLTPROC \
 382              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 383              xml-tests/test.xml]], [[0]], [expout])
 384   [cp xml-tests/test.dot expout]
 385   AT_CHECK([[$XSLTPROC \
 386              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 387              xml-tests/test.xml]], [[0]], [expout])
 388   [rm -rf xml-tests expout
 389 fi]])
 390
 391 # AT_QUELL_VALGRIND
 392 # -----------------
 393 # Put this before a Bison invocation to keep Valgrind from complaining about
 394 # reachable memory.
 395 #
 396 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 397 # The triple quoting below will cause test cases to fail if you do.  If you do
 398 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 399 # will then fail to shell-escape its contents when attempting to print them.
 400 # The testsuite verbose output, at least, will be incorrect, but nothing may
 401 # fail to make sure you notice.
 402 m4_define([AT_QUELL_VALGRIND],
 403 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 404
 405 ## ------------------------ ##
 406 ## Compiling C, C++ Files.  ##
 407 ## ------------------------ ##
 408
 409
 410 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 411 # ----------------------------------------
 412 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 413 # assume that we are linking too; this is a hack.
 414 m4_define([AT_COMPILE],
 415 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 416            0, [ignore], [ignore])])
 417
 418 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 419 # --------------------------------------------
 420 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 421 # assume that we are linking too; this is a hack.
 422 # If the C++ compiler does not work, ignore the test.
 423 m4_define([AT_COMPILE_CXX],
 424 [AT_KEYWORDS(c++)
 425 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 426 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 427          0, [ignore], [ignore])])
 428
 429 # AT_JAVA_COMPILE(SOURCES)
 430 # ------------------------
 431 # Compile SOURCES into Java class files.  Skip the test if java or javac
 432 # is not installed.
 433 m4_define([AT_JAVA_COMPILE],
 434 [AT_KEYWORDS(java)
 435 AT_CHECK([[test -n "$CONF_JAVA" || exit 77
 436            test -n "$CONF_JAVAC" || exit 77]])
 437 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 438          [[0]], [ignore], [ignore])])
 439
 440 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 441 # --------------------------------
 442 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 443 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 444 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 445 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 446 # AT_SKEL_JAVA_IF.
 447 m4_define([AT_FULL_COMPILE], [
 448   AT_SKEL_JAVA_IF([
 449     AT_BISON_CHECK([[-o ]$1[.java ]$1[.y]])
 450     AT_JAVA_COMPILE([$1[.java]]m4_ifval($2,
 451                                         [[$1[.java ]$1[-]$2[.java]]]))
 452   ], [
 453     AT_SKEL_CC_IF([
 454       AT_BISON_CHECK([[-o ]$1[.cc ]$1[.y]])
 455       AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1[.cc ]$1[-]$2[.cc]]]))
 456     ], [
 457       AT_BISON_CHECK([[-o ]$1[.c ]$1[.y]])
 458       AT_COMPILE([$1]m4_ifval($2, [, [$1[.c ]$1[-]$2[.c]]]))
 459     ])
 460   ])
 461 ])
 462
 463
 464 ## ---------------------------- ##
 465 ## Running a generated parser.  ##
 466 ## ---------------------------- ##
 467
 468 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 469 # ------------------------------------------------------------
 470 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 471 m4_define([AT_PARSER_CHECK],
 472 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 473
 474 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 475 # -----------------------------------------------------------------
 476 m4_define([AT_JAVA_PARSER_CHECK],
 477 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 478
 479 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 480 #                          DECLS, GRAMMAR, INPUT,
 481 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 482 #                          [OTHER-CHECKS],
 483 #                          [PARSER-EXIT-VALUE],
 484 #                          [PARSER-STDOUT], [PARSER-STDERR])
 485 # -------------------------------------------------------------
 486 # Using TITLE as the test group title, check the generated parser tables
 487 # and parser for a specified grammar file under a condition labeled by
 488 # COND-VALUE.
 489 #
 490 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 491 # recognized attribute is described below where it is relevant.
 492 #
 493 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 494 # the grammar file.  Insert basic yyerror, yylex, and main function
 495 # definitions as well.  Hardcode yylex to return the (possibly empty)
 496 # comma-delimited series of tokens in INPUT followed by token 0.
 497 #
 498 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 499 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 500 # On the bison command-line, specify `--report=all --defines'.  Check
 501 # that Bison exits with value 0, has no stdout, and has stderr
 502 # BISON-STDERR.
 503 #
 504 # If TEST-SPEC contains the attribute `last-state', check that the value
 505 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 506 # the grammar; in other words, check the number of states (minus one).
 507 # Otherwise, check that everything in the `.output' file starting with
 508 # the definition of state 0 is the same as the entire value of
 509 # TABLES-OR-LAST-STATE.
 510 #
 511 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 512 # `.output' file, which is named `input.output', and/or grammar file,
 513 # which is named `input.y'.
 514 #
 515 # Finally, compile the generated parser and then run it using
 516 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 517 # PARSER-STDERR as the 2nd-4th arguments.
 518 #
 519 # As a precondition, you must properly double-quote all arguments that
 520 # are to be interpreted as strings.
 521 #
 522 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 523 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 524 # first argument.  This is useful, for example, when wrapping multiple
 525 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 526 # condition, in another macro.
 527 #
 528 # For example:
 529 #
 530 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 531 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 532 #   # ---------------------------------------------------------------------
 533 #   m4_define([AT_TEST_SYNTAX_ERROR],
 534 #   [
 535 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 536 #                              [[last-state]],
 537 #                              [[%error-verbose ]$2], [$3], [$4],
 538 #                              [[]], [$5], [], [$6], [$7], [$8])
 539 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 540 #                              [[last-state]],
 541 #                              [$2], [$3], [$4],
 542 #                              [[]], [$5], [], [$6], [$7], [$8])
 543 #   ])
 544 #
 545 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 546 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 547 #                        [[3]],
 548 #                        [[1]], [[]],
 549 #                        [AT_COND_CASE([[no verbose]],
 550 #                                      [[syntax error
 551 #   ]],
 552 #                                      [[syntax error, unexpected 'b', expecting $end
 553 #   ]])])
 554 m4_define([AT_TEST_TABLES_AND_PARSE],
 555 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 556
 557 AT_SETUP([$1])
 558
 559 AT_DATA_GRAMMAR([[input.y]],
 560 [[%code {
 561   #include <stdio.h>
 562   static void yyerror (char const *msg);
 563   static int yylex (void);
 564 }
 565
 566 ]$4[
 567
 568 %%
 569
 570 ]$5[
 571
 572 %%
 573
 574 static void
 575 yyerror (char const *msg)
 576 {
 577   fprintf (stderr, "%s\n", msg);
 578 }
 579
 580 static int
 581 yylex (void)
 582 {
 583   static int const input[] = {
 584     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 585   };
 586   static int const *inputp = input;
 587   return *inputp++;
 588 }
 589
 590 int
 591 main (void)
 592 {
 593   return yyparse ();
 594 }
 595 ]])
 596
 597 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 598 # expanding macros, so it corrupts some special characters in the
 599 # macros.  To avoid this, expand now and pass it the result with proper
 600 # string quotation.  Assume args 7 thru 12 expand to properly quoted
 601 # strings.
 602
 603 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 604       [AT_BISON_CHECK],
 605       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 606                                [0], [], m4_dquote($7))
 607
 608 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 609       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 610                 m4_dquote($8))],
 611       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 612                 m4_dquote($8)[[
 613 ]])])
 614
 615 $9
 616
 617 AT_COMPILE([[input]])
 618
 619 AT_PARSER_CHECK([[./input]],
 620                 m4_ifval([$10], [m4_dquote($10)]),
 621                 m4_ifval([$11], [m4_dquote($11)]),
 622                 m4_ifval([$12], [m4_dquote($12)]))
 623
 624 AT_CLEANUP
 625
 626 m4_popdef([AT_COND_CASE])])
 627
 628
 629
 630 ## ----------------------- ##
 631 ## Launch the test suite.  ##
 632 ## ----------------------- ##
 633
 634 AT_INIT
 635
 636 AT_TESTED([bison])