tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 ## ------------- ##
  33 ## Basic tests.  ##
  34 ## ------------- ##
  35
  36 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  37 # ------------------------------------------
  38 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  39 # taken in "slurp" mode, i.e., one can match end-of-lines.
  40 m4_define([AT_MATCHES_CHECK],
  41 [AT_CHECK([perl -0777 -ne '
  42 my $count = 0;
  43 s{$2}{ ++$count; "" }gem;
  44 printf "$count\n";' $1], [0], [$3
  45 ])])
  46
  47
  48 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  49 # ------------------------------------------------
  50 # Don't interfere with caller's files.
  51 m4_divert_text([PREPARE_TESTS],
  52 [at_save_special_files ()
  53 {
  54   for at_save_file in stderr experr expout
  55   do
  56     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  57   done
  58 }
  59
  60 at_restore_special_files ()
  61 {
  62   for at_save_file in stderr experr expout
  63   do
  64     test ! -f at-bison-check-$at_save_file.bak ||
  65       mv at-bison-check-$at_save_file.bak $at_save_file
  66   done
  67 }
  68 ])
  69
  70 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  71 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  72
  73
  74
  75 ## ------------------------------- ##
  76 ## Macros decoding Bison options.  ##
  77 ## ------------------------------- ##
  78
  79 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  80 # ----------------------------------------------------------------
  81 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  82 m4_define([AT_LOC_PUSHDEF],
  83 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  84 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  85 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  86 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  87
  88 # AT_LOC_POPDEF
  89 # -------------
  90 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  91 m4_define([AT_LOC_POPDEF],
  92 [m4_popdef([AT_LOC_FIRST_LINE])
  93 m4_popdef([AT_LOC_FIRST_COLUMN])
  94 m4_popdef([AT_LOC_LAST_LINE])
  95 m4_popdef([AT_LOC_LAST_COLUMN])])
  96
  97
  98
  99 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 100 # -----------------------------------------
 101 m4_define([AT_BISON_OPTION_PUSHDEFS],
 102 [m4_divert_text([KILL],
 103                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 104
 105
 106 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 107 # --------------------------------------------------
 108 # This macro works around the impossibility to define macros
 109 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 110 # This sucks hard, GNU M4 should really provide M5 like $$1.
 111 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 112 [m4_if([$1$2], $[1]$[2], [],
 113        [m4_fatal([$0: Invalid arguments: $@])])dnl
 114 m4_pushdef([AT_DEFINES_IF],
 115 [m4_bmatch([$3], [%defines], [$1], [$2])])
 116 m4_pushdef([AT_SKEL_CC_IF],
 117 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 118 m4_pushdef([AT_SKEL_JAVA_IF],
 119 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 120 m4_pushdef([AT_LANG],
 121 [AT_SKEL_JAVA_IF([java],
 122                  [AT_SKEL_CC_IF([c++],
 123                                 [c])])])
 124 m4_pushdef([AT_GLR_IF],
 125 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 126 m4_pushdef([AT_LALR1_CC_IF],
 127 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 128 m4_pushdef([AT_GLR_CC_IF],
 129 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 130 # Using yacc.c?
 131 m4_pushdef([AT_YACC_IF],
 132 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 133 m4_pushdef([AT_LEXPARAM_IF],
 134 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 135 m4_pushdef([AT_LOCATION_IF],
 136 [m4_bmatch([$3], [%locations], [$1], [$2])])
 137 m4_pushdef([AT_LOCATION_TYPE_IF],
 138 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 139 m4_pushdef([AT_PARAM_IF],
 140 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 141 m4_pushdef([AT_PURE_IF],
 142 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 143            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 144            [$2])])
 145 m4_pushdef([AT_PURE_AND_LOC_IF],
 146 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 147 m4_pushdef([AT_GLR_OR_PARAM_IF],
 148 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 149 m4_pushdef([AT_NAME_PREFIX],
 150 [m4_bmatch([$3], [\(%define api\.prefix\|%name-prefix\) ".*"],
 151            [m4_bregexp([$3], [\(%define api\.prefix\|%name-prefix\) "\([^""]*\)"], [\2])],
 152            [yy])])
 153 m4_pushdef([AT_API_prefix],
 154 [m4_bmatch([$3], [%define api\.prefix ".*"],
 155            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 156            [yy])])
 157 m4_pushdef([AT_API_PREFIX],
 158 [m4_toupper(AT_API_prefix)])
 159 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 160 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 161 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 162                     [$2])])
 163 # yyerror always sees the locations (when activated), except if
 164 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 165 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 166 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 167                                         [$1])],
 168                             [$1])],
 169                 [$2])])
 170
 171 # The interface is pure: either because %define api.pure, or because we
 172 # are using the C++ parsers.
 173 m4_pushdef([AT_PURE_LEX_IF],
 174 [AT_PURE_IF([$1],
 175             [AT_SKEL_CC_IF([$1], [$2])])])
 176
 177 m4_pushdef([AT_YYSTYPE],
 178 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 179                [AT_API_PREFIX[STYPE]])])
 180 m4_pushdef([AT_YYLTYPE],
 181 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 182                [AT_API_PREFIX[LTYPE]])])
 183
 184
 185 AT_PURE_LEX_IF(
 186 [m4_pushdef([AT_LOC], [(*llocp)])
 187  m4_pushdef([AT_VAL], [(*lvalp)])
 188  m4_pushdef([AT_YYLEX_FORMALS],
 189             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 190  m4_pushdef([AT_YYLEX_ARGS],
 191             [lvalp[]AT_LOCATION_IF([, llocp])])
 192  m4_pushdef([AT_USE_LEX_ARGS],
 193             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 194  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 195             [AT_YYLEX_FORMALS, ])
 196  m4_pushdef([AT_YYLEX_PRE_ARGS],
 197             [AT_YYLEX_ARGS, ])
 198 ],
 199 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 200  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 201  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 202  m4_pushdef([AT_YYLEX_ARGS],        [])
 203  m4_pushdef([AT_USE_LEX_ARGS],    [])
 204  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 205  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 206 ])
 207
 208 # Handle the different types of location components.
 209
 210 AT_SKEL_CC_IF(
 211   [AT_LOCATION_TYPE_IF(
 212     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 213     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 214   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 215
 216 ])# _AT_BISON_OPTION_PUSHDEFS
 217
 218
 219 # AT_BISON_OPTION_POPDEFS
 220 # -----------------------
 221 m4_define([AT_BISON_OPTION_POPDEFS],
 222 [m4_divert_text([KILL],
 223 [m4_popdef([AT_YYLEX_PRE_ARGS])
 224 m4_popdef([AT_YYLEX_PRE_FORMALS])
 225 m4_popdef([AT_USE_LEX_ARGS])
 226 m4_popdef([AT_YYLEX_ARGS])
 227 m4_popdef([AT_YYLEX_FORMALS])
 228 m4_popdef([AT_YYLTYPE])
 229 m4_popdef([AT_YYSTYPE])
 230 m4_popdef([AT_VAL])
 231 m4_popdef([AT_LOC])
 232 m4_popdef([AT_PURE_LEX_IF])
 233 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 234 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 235 m4_popdef([AT_API_PREFIX])
 236 m4_popdef([AT_API_prefix])
 237 m4_popdef([AT_NAME_PREFIX])
 238 m4_popdef([AT_GLR_OR_PARAM_IF])
 239 m4_popdef([AT_PURE_AND_LOC_IF])
 240 m4_popdef([AT_LOCATION_TYPE_IF])
 241 m4_popdef([AT_LOCATION_IF])
 242 m4_popdef([AT_PARAM_IF])
 243 m4_popdef([AT_LEXPARAM_IF])
 244 m4_popdef([AT_YACC_IF])
 245 m4_popdef([AT_GLR_IF])
 246 m4_popdef([AT_SKEL_CC_IF])
 247 m4_popdef([AT_LANG])
 248 m4_popdef([AT_SKEL_JAVA_IF])
 249 m4_popdef([AT_GLR_CC_IF])
 250 m4_popdef([AT_LALR1_CC_IF])
 251 m4_popdef([AT_DEFINES_IF])
 252 AT_LOC_POPDEF])dnl
 253 ])# AT_BISON_OPTION_POPDEFS
 254
 255
 256
 257 ## -------------------------- ##
 258 ## Generating Grammar Files.  ##
 259 ## -------------------------- ##
 260
 261 # AT_DATA_SOURCE_PROLOGUE
 262 # ------------------------
 263 # The prologue that should be included in any source code that is
 264 # meant to be compiled.
 265 m4_define([AT_DATA_SOURCE_PROLOGUE],
 266 [[#include <config.h>
 267 /* We don't need perfect functions for these tests. */
 268 #undef malloc
 269 #undef memcmp
 270 #undef realloc
 271 ]])
 272
 273 # AT_DATA_GRAMMAR_PROLOGUE
 274 # ------------------------
 275 # The prologue that should be included in any grammar which parser is
 276 # meant to be compiled.
 277 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 278 [[%code top {
 279 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 280 [}
 281 ]])
 282
 283 # AT_DATA_SOURCE(NAME, CONTENT)
 284 # -----------------------------
 285 # Generate the file NAME, which CONTENT is preceded by
 286 # AT_DATA_SOURCE_PROLOGUE.
 287 m4_define([AT_DATA_SOURCE],
 288 [AT_DATA([$1],
 289 [AT_DATA_SOURCE_PROLOGUE
 290 $2])
 291 ])
 292
 293 # AT_DATA_GRAMMAR(NAME, CONTENT)
 294 # ------------------------------
 295 # Generate the file NAME, which CONTENT is preceded by
 296 # AT_DATA_GRAMMAR_PROLOGUE.
 297 m4_define([AT_DATA_GRAMMAR],
 298 [AT_DATA([$1],
 299 [AT_DATA_GRAMMAR_PROLOGUE
 300 $2])
 301 ])
 302
 303 # AT_YYLEX_PROTOTYPE
 304 # AT_YYLEX_DECLARE_EXTERN
 305 # AT_YYLEX_DECLARE
 306 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 307 # ----------------------------------
 308 # INPUT can be empty, or in double quotes, or a list (in braces).
 309 # ACTION may compute yylval for instance, using "res" as token type,
 310 # and "toknum" as the number of calls to yylex (starting at 0).
 311 m4_define([AT_YYLEX_PROTOTYPE],
 312 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 313 ])
 314
 315 m4_define([AT_YYLEX_DECLARE_EXTERN],
 316 [AT_YYLEX_PROTOTYPE;dnl
 317 ])
 318
 319 m4_define([AT_YYLEX_DECLARE],
 320 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 321 ])
 322
 323 m4_define([AT_YYLEX_DEFINE],
 324 [[#include <assert.h>
 325 static
 326 ]AT_YYLEX_PROTOTYPE[
 327 {
 328   ]m4_bmatch([$1], [^\(".*"\)?$],
 329              [[static char const input[] = ]m4_default([$1], [""])],
 330              [[static int const input[] = ]$1])[;
 331   static size_t toknum = 0;
 332   int res;
 333   ]AT_USE_LEX_ARGS[;
 334   assert (toknum < sizeof input);
 335   res = input[toknum++];
 336   ]$2[;]AT_LOCATION_IF([[
 337   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 338   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 339   return res;
 340 }]dnl
 341 ])
 342
 343 # AT_YYERROR_PROTOTYPE
 344 # AT_YYERROR_DECLARE_EXTERN
 345 # AT_YYERROR_DECLARE
 346 # AT_YYERROR_DEFINE
 347 # -------------------------
 348 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 349 m4_define([AT_YYERROR_FORMALS],
 350 [m4_case(AT_LANG,
 351 [c], [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE *llocp, ])[const char *msg]])[]dnl
 352 ])
 353
 354 m4_define([AT_YYERROR_PROTOTYPE],
 355 [m4_case(AT_LANG,
 356 [c], [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])[]dnl
 357 ])
 358
 359 m4_define([AT_YYERROR_DECLARE_EXTERN],
 360 [m4_case(AT_LANG,
 361 [c], [AT_YYERROR_PROTOTYPE;])[]dnl
 362 ])
 363
 364 m4_define([AT_YYERROR_DECLARE],
 365 [m4_case(AT_LANG,
 366 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 367 ])
 368
 369 m4_define([AT_YYERROR_DEFINE],
 370 [m4_case(AT_LANG,
 371 [c], [[#include <stdio.h>
 372 /* A C error reporting function.  */
 373 static
 374 ]AT_YYERROR_PROTOTYPE[
 375 {
 376 ]AT_YYERROR_SEES_LOC_IF([[
 377   fprintf (stderr, "%d.%d",
 378            ]AT_LOC_FIRST_LINE[, ]AT_LOC_FIRST_COLUMN[);
 379   if (]AT_LOC_FIRST_LINE[ != ]AT_LOC_LAST_LINE[)
 380     fprintf (stderr, "-%d.%d",
 381              ]AT_LOC_LAST_LINE[,  ]AT_LOC_LAST_COLUMN[ - 1);
 382   else if (]AT_LOC_FIRST_COLUMN[ != ]AT_LOC_LAST_COLUMN[ - 1)
 383     fprintf (stderr, "-%d",
 384              ]AT_LOC_LAST_COLUMN[ - 1);
 385   fprintf (stderr, ": ");]])[
 386   fprintf (stderr, "%s\n", msg);
 387 }]],
 388 [c++], [[/* A C++ error reporting function.  */
 389 void
 390 ]AT_NAME_PREFIX[::parser::error (const location_type& l, const std::string& m)
 391 {
 392   (void) l;
 393   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 394 }]],
 395 [java], [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 396   {
 397     if (l == null)
 398       System.err.println (s);
 399     else
 400       System.err.println (l + ": " + s);
 401   }
 402 ]], [[
 403   public void yyerror (String s)
 404   {
 405     System.err.println (s);
 406   }]])])dnl
 407 ])
 408
 409
 410 ## --------------- ##
 411 ## Running Bison.  ##
 412 ## --------------- ##
 413
 414 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 415 # -------------------------------------------------
 416 # High-level routine that may call bison several times, under different
 417 # conditions.
 418 #
 419 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 420 # shell constructs (such as redirection or pipes) that would prevent
 421 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 422 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 423 #
 424 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 425 # Bison in the test suite.  For now it ensures that:
 426 #
 427 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 428 #      a non-zero exit status since Bison doesn't always try to free all memory
 429 #      in that case.
 430 #
 431 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 432 #      --graph and --report=all output for every working grammar.
 433 #
 434 #   3. If stderr contains a warning, -Werror and --warnings=error
 435 #      convert the warning to an error.
 436 #
 437 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 438 m4_define([AT_BISON_CHECK],
 439 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 440 AT_BISON_CHECK_NO_XML($@)])
 441
 442 m4_define([AT_BISON_WERROR_MSG],
 443           [[bison: warnings being treated as errors]])
 444
 445
 446 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 447 # --------------------------------------------------
 448 # Low-level macro to run bison once.
 449 m4_define([AT_BISON_CHECK_],
 450 [AT_CHECK(AT_QUELL_VALGRIND[[ bison ]]$@)])
 451
 452
 453 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 454 # ----------------------------------------------------------
 455 # Check that warnings (if some are expected) are correctly
 456 # turned into errors with -Werror, etc.
 457 m4_define([AT_BISON_CHECK_WARNINGS],
 458 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 459       [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 460
 461 m4_define([AT_BISON_CHECK_WARNINGS_],
 462 [[# Defining POSIXLY_CORRECT causes bison to complain if options
 463 # are added after the grammar file name, so skip these checks
 464 # in that case.
 465 if test -z "${POSIXLY_CORRECT+set}"; then
 466   ]AT_SAVE_SPECIAL_FILES[
 467
 468   # To avoid expanding it repeatedly, store specified stdout.
 469   ]AT_DATA([expout], [$3])[
 470
 471   # Run with -Werror.
 472   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 473
 474   # Build expected stderr up to and including the "warnings being
 475   # treated as errors" message.
 476   ]AT_DATA([[at-bison-check-warnings]], [$4])[
 477   at_bison_check_first=`sed -n \
 478     '/: warning: /{=;q;}' at-bison-check-warnings`
 479   : ${at_bison_check_first:=1}
 480   at_bison_check_first_tmp=`sed -n \
 481     '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 482   : ${at_bison_check_first_tmp:=1}
 483   if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 484     at_bison_check_first=$at_bison_check_first_tmp
 485   fi
 486   if test $at_bison_check_first -gt 1; then
 487     sed -n "1,`expr $at_bison_check_first - 1`"p \
 488       at-bison-check-warnings > experr
 489   fi
 490   echo ']AT_BISON_WERROR_MSG[' >> experr
 491
 492   # Finish building expected stderr and check.  Unlike warnings,
 493   # complaints cause bison to exit early.  Thus, with -Werror, bison
 494   # does not necessarily report all warnings that it does without
 495   # -Werror, but it at least reports one.
 496   at_bison_check_last=`sed -n '$=' stderr`
 497   : ${at_bison_check_last:=1}
 498   at_bison_check_last=`expr $at_bison_check_last - 1`
 499   sed -n "$at_bison_check_first,$at_bison_check_last"p \
 500     at-bison-check-warnings >> experr
 501   ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 502               stderr 1>&2]], [[0]], [[]], [experr])[
 503
 504   # Now check --warnings=error.
 505   cp stderr experr
 506   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 507
 508   # Now check -Wnone and --warnings=none by making sure that
 509   # -Werror doesn't change the exit status when -Wnone or
 510   # --warnings=none is specified.
 511   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 512   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 513
 514   ]AT_RESTORE_SPECIAL_FILES[
 515 fi]dnl
 516 ])
 517
 518 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 519 # --------------------------------------------------------
 520 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 521 # when a tortured grammar's XML is known to be too large for xsltproc to
 522 # handle.
 523 m4_define([AT_BISON_CHECK_NO_XML],
 524 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison ]]$@)
 525 AT_BISON_CHECK_WARNINGS($@)])
 526
 527 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 528 # -----------------------------------------------------
 529 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 530 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 531 # have a non-zero exit status.
 532 m4_define([AT_BISON_CHECK_XML],
 533 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 534   AT_SAVE_SPECIAL_FILES
 535   [mkdir xml-tests]
 536   m4_pushdef([AT_BISON_ARGS],
 537              [m4_bpatsubsts([[$1]],
 538                             [--report(-file)?=[^][ ]*], [],
 539                             [--graph=[^][ ]*], [],
 540                             [--xml=[^][ ]*], [])])dnl
 541   # Don't combine these Bison invocations since we want to be sure that
 542   # --report=all isn't required to get the full XML file.
 543   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 544                   --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 545                   [[0]], [ignore], [ignore])
 546   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 547                  [[0]], [ignore], [ignore])
 548   m4_popdef([AT_BISON_ARGS])dnl
 549   [cp xml-tests/test.output expout]
 550   AT_CHECK([[$XSLTPROC \
 551              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 552              xml-tests/test.xml]], [[0]], [expout])
 553   [cp xml-tests/test.dot expout]
 554   AT_CHECK([[$XSLTPROC \
 555              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 556              xml-tests/test.xml]], [[0]], [expout])
 557   [rm -rf xml-tests expout]
 558   AT_RESTORE_SPECIAL_FILES
 559 [fi]])
 560
 561 # AT_QUELL_VALGRIND
 562 # -----------------
 563 # Put this before a Bison invocation to keep Valgrind from complaining about
 564 # reachable memory.
 565 #
 566 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 567 # The triple quoting below will cause test cases to fail if you do.  If you do
 568 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 569 # will then fail to shell-escape its contents when attempting to print them.
 570 # The testsuite verbose output, at least, will be incorrect, but nothing may
 571 # fail to make sure you notice.
 572 m4_define([AT_QUELL_VALGRIND],
 573 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 574
 575
 576
 577 ## ------------------------ ##
 578 ## Compiling C, C++ Files.  ##
 579 ## ------------------------ ##
 580
 581
 582 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 583 # ----------------------------------------
 584 # Compile SOURCES into OUTPUT.
 585 #
 586 # If OUTPUT does not contain '.', assume that we are linking too,
 587 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 588 # with trailing .o removed, and ".c" appended.
 589 m4_define([AT_COMPILE],
 590 [AT_CHECK(m4_join([ ],
 591                   [$CC $CFLAGS $CPPFLAGS],
 592                   [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 593                   [-o $1],
 594                   [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 595                   [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 596            0, [ignore], [ignore])])
 597
 598 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 599 # ---------------------------------------------
 600 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 601 # ignore the test.
 602 #
 603 # If OUTPUT does not contain '.', assume that we are linking too,
 604 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 605 # with trailing .o removed, and ".cc" appended.
 606 m4_define([AT_COMPILE_CXX],
 607 [AT_KEYWORDS(c++)
 608 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 609 AT_CHECK(m4_join([ ],
 610                  [$CXX $CXXFLAGS $CPPFLAGS],
 611                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 612                  [-o $1],
 613                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 614                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 615          0, [ignore], [ignore])])
 616
 617 # AT_JAVA_COMPILE(SOURCES)
 618 # ------------------------
 619 # Compile SOURCES into Java class files.  Skip the test if java or javac
 620 # is not installed.
 621 m4_define([AT_JAVA_COMPILE],
 622 [AT_KEYWORDS(java)
 623 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 624 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 625 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 626          [[0]], [ignore], [ignore])])
 627
 628 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 629 # --------------------------------------------
 630 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 631 #
 632 # If OUTPUT does not contain '.', assume that we are linking too,
 633 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 634 # with trailing .o removed, and ".c"/".cc" appended.
 635 m4_define([AT_LANG_COMPILE],
 636 [m4_case(AT_LANG,
 637 [c],    [AT_COMPILE([$1], [$2])],
 638 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 639 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 640         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 641 ])
 642
 643 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 644 # -------------------------------------------
 645 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 646 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 647 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 648 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 649 # AT_SKEL_JAVA_IF.
 650 m4_define([AT_FULL_COMPILE],
 651 [m4_case(AT_LANG,
 652 [java],
 653   [AT_BISON_CHECK([-o $1.java $1.y])
 654    AT_LANG_COMPILE([$1],
 655                    m4_join([ ],
 656                            [$1.java],
 657                            m4_ifval($2, [[$1-$2.java]]),
 658                            m4_ifval($3, [[$1-$3.java]])))],
 659 [c++],
 660   [AT_BISON_CHECK([-o $1.cc $1.y])
 661    AT_LANG_COMPILE([$1],
 662                    m4_join([ ],
 663                            [$1.cc],
 664                            m4_ifval($2, [[$1-$2.cc]]),
 665                            m4_ifval($3, [[$1-$3.cc]])))],
 666 [c],
 667   [AT_BISON_CHECK([-o $1.c $1.y])
 668    AT_LANG_COMPILE([$1],
 669                    m4_join([ ],
 670                            [$1.c],
 671                            m4_ifval($2, [[$1-$2.c]]),
 672                            m4_ifval($3, [[$1-$3.c]])))])
 673 ])
 674
 675
 676 ## ---------------------------- ##
 677 ## Running a generated parser.  ##
 678 ## ---------------------------- ##
 679
 680
 681 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 682 # ------------------------------------------------------------
 683 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 684 #
 685 # Get rid of spurious messages when compiled with --coverage:
 686 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 687 m4_define([AT_PARSER_CHECK],
 688 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 689 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 690          [0], [], [$4])
 691 ])
 692
 693
 694 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 695 # -----------------------------------------------------------------
 696 m4_define([AT_JAVA_PARSER_CHECK],
 697 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 698
 699
 700 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 701 #                          DECLS, GRAMMAR, INPUT,
 702 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 703 #                          [OTHER-CHECKS],
 704 #                          [PARSER-EXIT-VALUE],
 705 #                          [PARSER-STDOUT], [PARSER-STDERR])
 706 # -------------------------------------------------------------
 707 # Using TITLE as the test group title, check the generated parser tables
 708 # and parser for a specified grammar file under a condition labeled by
 709 # COND-VALUE.
 710 #
 711 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 712 # recognized attribute is described below where it is relevant.
 713 #
 714 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 715 # the grammar file.  Insert basic yyerror, yylex, and main function
 716 # definitions as well.  Hardcode yylex to return the (possibly empty)
 717 # comma-delimited series of tokens in INPUT followed by token 0.
 718 #
 719 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 720 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 721 # On the bison command-line, specify `--report=all --defines'.  Check
 722 # that Bison exits with value 0, has no stdout, and has stderr
 723 # BISON-STDERR.
 724 #
 725 # If TEST-SPEC contains the attribute `last-state', check that the value
 726 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 727 # the grammar; in other words, check the number of states (minus one).
 728 # Otherwise, check that everything in the `.output' file starting with
 729 # the definition of state 0 is the same as the entire value of
 730 # TABLES-OR-LAST-STATE.
 731 #
 732 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 733 # `.output' file, which is named `input.output', and/or grammar file,
 734 # which is named `input.y'.
 735 #
 736 # Finally, compile the generated parser and then run it using
 737 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 738 # PARSER-STDERR as the 2nd-4th arguments.
 739 #
 740 # As a precondition, you must properly double-quote all arguments that
 741 # are to be interpreted as strings.
 742 #
 743 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 744 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 745 # first argument.  This is useful, for example, when wrapping multiple
 746 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 747 # condition, in another macro.
 748 #
 749 # For example:
 750 #
 751 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 752 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 753 #   # ---------------------------------------------------------------------
 754 #   m4_define([AT_TEST_SYNTAX_ERROR],
 755 #   [
 756 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 757 #                              [[last-state]],
 758 #                              [[%error-verbose ]$2], [$3], [$4],
 759 #                              [[]], [$5], [], [$6], [$7], [$8])
 760 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 761 #                              [[last-state]],
 762 #                              [$2], [$3], [$4],
 763 #                              [[]], [$5], [], [$6], [$7], [$8])
 764 #   ])
 765 #
 766 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 767 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 768 #                        [[3]],
 769 #                        [[1]], [[]],
 770 #                        [AT_COND_CASE([[no verbose]],
 771 #                                      [[syntax error
 772 #   ]],
 773 #                                      [[syntax error, unexpected 'b', expecting $end
 774 #   ]])])
 775 m4_define([AT_TEST_TABLES_AND_PARSE],
 776 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 777
 778 AT_SETUP([$1])
 779 AT_BISON_OPTION_PUSHDEFS([$4])
 780 AT_DATA_GRAMMAR([[input.y]],
 781 [[%code {
 782   #include <stdio.h>
 783   ]AT_YYERROR_DECLARE[
 784   ]AT_YYLEX_DECLARE[
 785 }
 786
 787 ]$4[
 788
 789 %%
 790
 791 ]$5[
 792
 793 %%
 794 ]AT_YYERROR_DEFINE[
 795 static int
 796 yylex (void)
 797 {
 798   static int const input[] = {
 799     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 800   };
 801   static int const *inputp = input;
 802   return *inputp++;
 803 }
 804
 805 int
 806 main (void)
 807 {
 808   return yyparse ();
 809 }
 810 ]])
 811
 812 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 813 # expanding macros, so it corrupts some special characters in the
 814 # macros.  To avoid this, expand now and pass it the result with proper
 815 # string quotation.  Assume args 7 through 12 expand to properly quoted
 816 # strings.
 817
 818 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 819       [AT_BISON_CHECK],
 820       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 821                                [0], [], m4_dquote($7))
 822
 823 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 824       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 825                 m4_dquote($8))],
 826       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 827                 m4_dquote($8)[[
 828 ]])])
 829
 830 $9
 831
 832 # Canonical LR generates very large tables, resulting in very long
 833 # files with #line directives that may overflow what the standards
 834 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 835 # will issue an error.
 836 #
 837 # There is no "" around `wc` since some indent the result.
 838 m4_bmatch([$4], [%define lr.type canonical-lr],
 839 [if test 32767 -lt `wc -l < input.c`; then
 840   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 841   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 842 fi])
 843 AT_COMPILE([[input]])
 844
 845 AT_PARSER_CHECK([[./input]],
 846                 m4_ifval([$10], [m4_dquote($10)]),
 847                 m4_ifval([$11], [m4_dquote($11)]),
 848                 m4_ifval([$12], [m4_dquote($12)]))
 849
 850 AT_BISON_OPTION_POPDEFS
 851 AT_CLEANUP
 852
 853 m4_popdef([AT_COND_CASE])])
 854
 855
 856
 857 ## ----------------------- ##
 858 ## Launch the test suite.  ##
 859 ## ----------------------- ##
 860
 861 AT_INIT
 862
 863 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 864 # options are processed, so we don't know the value of CXX and
 865 # CXXFLAGS yet.
 866 #
 867 # Note that it also means that command line values for CXX and
 868 # CXXFLAGS will not be propagated to CC and CFLAGS.
 869 AT_ARG_OPTION([compile-c-with-cxx],
 870               [compile C parsers with the C++ compiler])
 871
 872 AT_COLOR_TESTS
 873
 874 AT_TESTED([bison])