src/scan-skel.l

   1 /* Scan Bison Skeletons.                                       -*- C -*-
   2    Copyright (C) 2001, 2002  Free Software Foundation, Inc.
   3
   4    This file is part of Bison, the GNU Compiler Compiler.
   5
   6    Bison is free software; you can redistribute it and/or modify it
   7    under the terms of the GNU General Public License as published by
   8    the Free Software Foundation; either version 2, or (at your option)
   9    any later version.
  10
  11    Bison is distributed in the hope that it will be useful, but
  12    WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    General Public License for more details.
  15
  16    You should have received a copy of the GNU General Public License
  17    along with Bison; see the file COPYING.  If not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19    02111-1307, USA.  */
  20
  21 %option nodefault noyywrap nounput never-interactive debug
  22 %option prefix="skel_" outfile="lex.yy.c"
  23
  24 %{
  25 #include "system.h"
  26 #include "quotearg.h"
  27 #include "error.h"
  28 #include "getargs.h"
  29 #include "files.h"
  30
  31 int skel_lex (void);
  32
  33 #define QPUTS(String) \
  34    fputs (quotearg_style (c_quoting_style, (String)), yyout);
  35
  36 %}
  37 %%
  38
  39 %{
  40   int lineno IF_LINT (= 0);
  41   char *outname = NULL;
  42 %}
  43
  44 "@output ".*\n {
  45   char const *filename = yytext + sizeof "@output " - 1;
  46   yytext[yyleng - 1] = '\0';
  47
  48   if (*filename == '@')
  49     {
  50       if (strcmp (filename, "@output_header_name@") == 0)
  51         filename = spec_defines_file;
  52       else if (strcmp (filename, "@output_parser_name@") == 0)
  53         filename = parser_file_name;
  54       else
  55         abort ();
  56     }
  57
  58   XFREE (outname);
  59   outname = xstrdup (filename);
  60   yyout = xfopen (outname, "w");
  61   lineno = 1;
  62 }
  63
  64 "@@"       fputc ('@', yyout);
  65 "@{"       fputc ('[', yyout);
  66 "@}"       fputc (']', yyout);
  67
  68 "@oline@"  fprintf (yyout, "%d", lineno);
  69 "@ofile@"  QPUTS (outname);
  70 "@output_parser_name@"  QPUTS (parser_file_name);
  71 "@output_header_name@"  QPUTS (spec_defines_file);
  72
  73 "@"        abort ();
  74 \n         lineno++; ECHO;
  75 [^@\n]+    ECHO;
  76
  77 <<EOF>>    xfclose (yyout); free (outname); return EOF;
  78 %%
  79
  80 /*------------------------.
  81 | Scan a Bison skeleton.  |
  82 `------------------------*/
  83
  84 void scan_skel (FILE *);
  85
  86 void
  87 scan_skel (FILE *in)
  88 {
  89   skel_in = in;
  90   skel__flex_debug = trace_flag & trace_skeleton;
  91   skel_lex ();
  92   /* Reclaim Flex's buffers.  */
  93   yy_delete_buffer (YY_CURRENT_BUFFER);
  94 }