src/scan-skel.l

   1 /* Scan Bison Skeletons.                                       -*- C -*-
   2
   3    Copyright (C) 2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    Bison is free software; you can redistribute it and/or modify it
   8    under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2, or (at your option)
  10    any later version.
  11
  12    Bison is distributed in the hope that it will be useful, but
  13    WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with Bison; see the file COPYING.  If not, write to the Free
  19    Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301, USA.  */
  21
  22 %option nodefault noyywrap nounput never-interactive debug
  23 %option prefix="skel_" outfile="lex.yy.c"
  24
  25 %{
  26 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  27    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  28 #undef skel_wrap
  29 #define skel_wrap() 1
  30
  31 #include "system.h"
  32
  33 #include <error.h>
  34 #include <quotearg.h>
  35
  36 #include "complain.h"
  37 #include "getargs.h"
  38 #include "files.h"
  39 #include "scan-skel.h"
  40
  41 #define QPUTS(String) \
  42    fputs (quotearg_style (c_quoting_style, (String)), yyout)
  43
  44 %}
  45 %%
  46
  47 %{
  48   int lineno IF_LINT (= 0);
  49   char *outname = NULL;
  50 %}
  51
  52 "@output ".*\n {
  53   char const *file_name = yytext + sizeof "@output " - 1;
  54   yytext[yyleng - 1] = '\0';
  55
  56   /* Decode special file names.  They include the directory part,
  57      contrary to their "free" occurrences, used for issuing #includes,
  58      which must not include the directory part.  */
  59
  60   if (*file_name == '@')
  61     {
  62       if (strcmp (file_name, "@output_header_name@") == 0)
  63         file_name = spec_defines_file;
  64       else if (strcmp (file_name, "@output_parser_name@") == 0)
  65         file_name = parser_file_name;
  66       else
  67         fatal ("invalid token in skeleton: %s", yytext);
  68     }
  69
  70   if (outname)
  71     {
  72       free (outname);
  73       xfclose (yyout);
  74     }
  75   outname = xstrdup (file_name);
  76   yyout = xfopen (outname, "w");
  77   lineno = 1;
  78 }
  79
  80 "@@"       fputc ('@', yyout);
  81 "@{"       fputc ('[', yyout);
  82 "@}"       fputc (']', yyout);
  83
  84 "@oline@"  fprintf (yyout, "%d", lineno + 1);
  85 "@ofile@"  QPUTS (outname);
  86 "@dir_prefix@" QPUTS (dir_prefix);
  87 "@output_parser_name@"  QPUTS (base_name (parser_file_name));
  88 "@output_header_name@"  QPUTS (base_name (spec_defines_file));
  89
  90   /* This pattern must not match more than the previous @ patterns. */
  91 @[^{}@\n]* fatal ("invalid @ in skeleton: %s", yytext);
  92 \n         lineno++; ECHO;
  93 [^@\n]+    ECHO;
  94
  95 <<EOF>> {
  96   if (outname)
  97     {
  98       free (outname);
  99       xfclose (yyout);
 100     }
 101   return EOF;
 102 }
 103 %%
 104
 105 /*------------------------.
 106 | Scan a Bison skeleton.  |
 107 `------------------------*/
 108
 109 void
 110 scan_skel (FILE *in)
 111 {
 112   skel_in = in;
 113   skel__flex_debug = trace_flag & trace_skeleton;
 114   skel_lex ();
 115   /* Reclaim Flex's buffers.  */
 116   yy_delete_buffer (YY_CURRENT_BUFFER);
 117 }