src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include "system.h"
  24
  25 #include "complain.h"
  26 #include "conflicts.h"
  27 #include "files.h"
  28 #include "getargs.h"
  29 #include "gram.h"
  30 #include "muscle_tab.h"
  31 #include "output.h"
  32 #include "quotearg.h"
  33 #include "reader.h"
  34 #include "symlist.h"
  35
  36 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  37 static YYLTYPE lloc_default (YYLTYPE const *, int);
  38
  39 #define YY_LOCATION_PRINT(File, Loc) \
  40           location_print (File, Loc)
  41
  42 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  43    FIXME: depends on the undocumented availability of YYLLOC.  */
  44 #undef  yyerror
  45 #define yyerror(Msg) \
  46         gram_error (&yylloc, Msg)
  47 static void gram_error (location const *, char const *);
  48
  49 static void add_param (char const *, char *, location);
  50
  51 static symbol_class current_class = unknown_sym;
  52 static uniqstr current_type = 0;
  53 symbol *current_lhs;
  54 location current_lhs_location;
  55 assoc current_assoc;
  56 static int current_prec = 0;
  57 %}
  58
  59 %debug
  60 %verbose
  61 %defines
  62 %locations
  63 %pure-parser
  64 %error-verbose
  65 %defines
  66 %name-prefix="gram_"
  67
  68 %initial-action
  69 {
  70   /* Bison's grammar can initial empty locations, hence a default
  71      location is needed. */
  72   @$.start.file   = @$.end.file   = current_file;
  73   @$.start.line   = @$.end.line   = 1;
  74   @$.start.column = @$.end.column = 0;
  75 }
  76
  77 /* Only NUMBERS have a value.  */
  78 %union
  79 {
  80   symbol *symbol;
  81   symbol_list *list;
  82   int integer;
  83   char *chars;
  84   assoc assoc;
  85   uniqstr uniqstr;
  86 };
  87
  88 /* Define the tokens together with their human representation.  */
  89 %token GRAM_EOF 0 "end of file"
  90 %token STRING     "string"
  91 %token INT        "integer"
  92
  93 %token PERCENT_TOKEN       "%token"
  94 %token PERCENT_NTERM       "%nterm"
  95
  96 %token PERCENT_TYPE        "%type"
  97 %token PERCENT_DESTRUCTOR  "%destructor {...}"
  98 %token PERCENT_PRINTER     "%printer {...}"
  99
 100 %token PERCENT_UNION       "%union {...}"
 101
 102 %token PERCENT_LEFT        "%left"
 103 %token PERCENT_RIGHT       "%right"
 104 %token PERCENT_NONASSOC    "%nonassoc"
 105
 106 %token PERCENT_PREC          "%prec"
 107 %token PERCENT_DPREC         "%dprec"
 108 %token PERCENT_MERGE         "%merge"
 109
 110
 111 /*----------------------.
 112 | Global Declarations.  |
 113 `----------------------*/
 114
 115 %token
 116   PERCENT_DEBUG           "%debug"
 117   PERCENT_DEFAULT_PREC    "%default-prec"
 118   PERCENT_DEFINE          "%define"
 119   PERCENT_DEFINES         "%defines"
 120   PERCENT_ERROR_VERBOSE   "%error-verbose"
 121   PERCENT_EXPECT          "%expect"
 122   PERCENT_EXPECT_RR       "%expect-rr"
 123   PERCENT_FILE_PREFIX     "%file-prefix"
 124   PERCENT_GLR_PARSER      "%glr-parser"
 125   PERCENT_INITIAL_ACTION  "%initial-action {...}"
 126   PERCENT_LEX_PARAM       "%lex-param {...}"
 127   PERCENT_LOCATIONS       "%locations"
 128   PERCENT_NAME_PREFIX     "%name-prefix"
 129   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 130   PERCENT_NO_LINES        "%no-lines"
 131   PERCENT_NONDETERMINISTIC_PARSER
 132                           "%nondeterministic-parser"
 133   PERCENT_OUTPUT          "%output"
 134   PERCENT_PARSE_PARAM     "%parse-param {...}"
 135   PERCENT_PURE_PARSER     "%pure-parser"
 136   PERCENT_SKELETON        "%skeleton"
 137   PERCENT_START           "%start"
 138   PERCENT_TOKEN_TABLE     "%token-table"
 139   PERCENT_VERBOSE         "%verbose"
 140   PERCENT_YACC            "%yacc"
 141 ;
 142
 143 %token TYPE            "type"
 144 %token EQUAL           "="
 145 %token SEMICOLON       ";"
 146 %token PIPE            "|"
 147 %token ID              "identifier"
 148 %token ID_COLON        "identifier:"
 149 %token PERCENT_PERCENT "%%"
 150 %token PROLOGUE        "%{...%}"
 151 %token EPILOGUE        "epilogue"
 152 %token BRACED_CODE     "{...}"
 153
 154
 155 %type <chars> STRING string_content
 156               "%destructor {...}"
 157               "%initial-action {...}"
 158               "%lex-param {...}"
 159               "%parse-param {...}"
 160               "%printer {...}"
 161               "%union {...}"
 162               BRACED_CODE action
 163               PROLOGUE EPILOGUE
 164 %printer { fprintf (stderr, "\"%s\"", $$); }
 165               STRING string_content
 166 %printer { fprintf (stderr, "{\n%s\n}", $$); }
 167               "%destructor {...}"
 168               "%initial-action {...}"
 169               "%lex-param {...}"
 170               "%parse-param {...}"
 171               "%printer {...}"
 172               "%union {...}"
 173               BRACED_CODE action
 174               PROLOGUE EPILOGUE
 175 %type <uniqstr> TYPE
 176 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 177 %type <integer> INT
 178 %printer { fprintf (stderr, "%d", $$); } INT
 179 %type <symbol> ID symbol string_as_id
 180 %printer { fprintf (stderr, "%s", $$->tag); } ID symbol string_as_id
 181 %type <symbol> ID_COLON
 182 %printer { fprintf (stderr, "%s:", $$->tag); } ID_COLON
 183 %type <assoc> precedence_declarator
 184 %type <list>  symbols.1
 185 %%
 186
 187 input:
 188   declarations "%%" grammar epilogue.opt
 189 ;
 190
 191
 192         /*------------------------------------.
 193         | Declarations: before the first %%.  |
 194         `------------------------------------*/
 195
 196 declarations:
 197   /* Nothing */
 198 | declarations declaration
 199 ;
 200
 201 declaration:
 202   grammar_declaration
 203 | PROLOGUE                                 { prologue_augment ($1, @1); }
 204 | "%debug"                                 { debug_flag = true; }
 205 | "%define" string_content string_content  { muscle_insert ($2, $3); }
 206 | "%defines"                               { defines_flag = true; }
 207 | "%error-verbose"                         { error_verbose = true; }
 208 | "%expect" INT                            { expected_sr_conflicts = $2; }
 209 | "%expect-rr" INT                         { expected_rr_conflicts = $2; }
 210 | "%file-prefix" "=" string_content        { spec_file_prefix = $3; }
 211 | "%glr-parser"
 212   {
 213     nondeterministic_parser = true;
 214     glr_parser = true;
 215   }
 216 | "%initial-action {...}"
 217   {
 218     muscle_code_grow ("initial_action", $1, @1);
 219   }
 220 | "%lex-param {...}"                       { add_param ("lex_param", $1, @1); }
 221 | "%locations"                             { locations_flag = true; }
 222 | "%name-prefix" "=" string_content        { spec_name_prefix = $3; }
 223 | "%no-lines"                              { no_lines_flag = true; }
 224 | "%nondeterministic-parser"               { nondeterministic_parser = true; }
 225 | "%output" "=" string_content             { spec_outfile = $3; }
 226 | "%parse-param {...}"                     { add_param ("parse_param", $1, @1); }
 227 | "%pure-parser"                           { pure_parser = true; }
 228 | "%skeleton" string_content               { skeleton = $2; }
 229 | "%token-table"                           { token_table_flag = true; }
 230 | "%verbose"                               { report_flag = report_states; }
 231 | "%yacc"                                  { yacc_flag = true; }
 232 | /*FIXME: Err?  What is this horror doing here? */ ";"
 233 ;
 234
 235 grammar_declaration:
 236   precedence_declaration
 237 | symbol_declaration
 238 | "%start" symbol
 239     {
 240       grammar_start_symbol_set ($2, @2);
 241     }
 242 | "%union {...}"
 243     {
 244       typed = true;
 245       MUSCLE_INSERT_INT ("stype_line", @1.start.line);
 246       muscle_insert ("stype", $1);
 247     }
 248 | "%destructor {...}" symbols.1
 249     {
 250       symbol_list *list;
 251       for (list = $2; list; list = list->next)
 252         symbol_destructor_set (list->sym, $1, @1);
 253       symbol_list_free ($2);
 254     }
 255 | "%printer {...}" symbols.1
 256     {
 257       symbol_list *list;
 258       for (list = $2; list; list = list->next)
 259         symbol_printer_set (list->sym, $1, list->location);
 260       symbol_list_free ($2);
 261     }
 262 | "%default-prec"
 263     {
 264       default_prec = true;
 265     }
 266 | "%no-default-prec"
 267     {
 268       default_prec = false;
 269     }
 270 ;
 271
 272 symbol_declaration:
 273   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 274     {
 275       current_class = unknown_sym;
 276       current_type = NULL;
 277     }
 278 | "%token" { current_class = token_sym; } symbol_defs.1
 279     {
 280       current_class = unknown_sym;
 281       current_type = NULL;
 282     }
 283 | "%type" TYPE symbols.1
 284     {
 285       symbol_list *list;
 286       for (list = $3; list; list = list->next)
 287         symbol_type_set (list->sym, $2, @2);
 288       symbol_list_free ($3);
 289     }
 290 ;
 291
 292 precedence_declaration:
 293   precedence_declarator type.opt symbols.1
 294     {
 295       symbol_list *list;
 296       ++current_prec;
 297       for (list = $3; list; list = list->next)
 298         {
 299           symbol_type_set (list->sym, current_type, @2);
 300           symbol_precedence_set (list->sym, current_prec, $1, @1);
 301         }
 302       symbol_list_free ($3);
 303       current_type = NULL;
 304     }
 305 ;
 306
 307 precedence_declarator:
 308   "%left"     { $$ = left_assoc; }
 309 | "%right"    { $$ = right_assoc; }
 310 | "%nonassoc" { $$ = non_assoc; }
 311 ;
 312
 313 type.opt:
 314   /* Nothing. */ { current_type = NULL; }
 315 | TYPE           { current_type = $1; }
 316 ;
 317
 318 /* One or more nonterminals to be %typed. */
 319
 320 symbols.1:
 321   symbol            { $$ = symbol_list_new ($1, @1); }
 322 | symbols.1 symbol  { $$ = symbol_list_prepend ($1, $2, @2); }
 323 ;
 324
 325 /* One token definition.  */
 326 symbol_def:
 327   TYPE
 328      {
 329        current_type = $1;
 330      }
 331 | ID
 332      {
 333        symbol_class_set ($1, current_class, @1);
 334        symbol_type_set ($1, current_type, @1);
 335      }
 336 | ID INT
 337     {
 338       symbol_class_set ($1, current_class, @1);
 339       symbol_type_set ($1, current_type, @1);
 340       symbol_user_token_number_set ($1, $2, @2);
 341     }
 342 | ID string_as_id
 343     {
 344       symbol_class_set ($1, current_class, @1);
 345       symbol_type_set ($1, current_type, @1);
 346       symbol_make_alias ($1, $2, @$);
 347     }
 348 | ID INT string_as_id
 349     {
 350       symbol_class_set ($1, current_class, @1);
 351       symbol_type_set ($1, current_type, @1);
 352       symbol_user_token_number_set ($1, $2, @2);
 353       symbol_make_alias ($1, $3, @$);
 354     }
 355 ;
 356
 357 /* One or more symbol definitions. */
 358 symbol_defs.1:
 359   symbol_def
 360 | symbol_defs.1 symbol_def
 361 ;
 362
 363
 364         /*------------------------------------------.
 365         | The grammar section: between the two %%.  |
 366         `------------------------------------------*/
 367
 368 grammar:
 369   rules_or_grammar_declaration
 370 | grammar rules_or_grammar_declaration
 371 ;
 372
 373 /* As a Bison extension, one can use the grammar declarations in the
 374    body of the grammar.  */
 375 rules_or_grammar_declaration:
 376   rules
 377 | grammar_declaration ";"
 378     {
 379       if (yacc_flag)
 380         complain_at (@$, _("POSIX forbids declarations in the grammar"));
 381     }
 382 | error ";"
 383     {
 384       yyerrok;
 385     }
 386 ;
 387
 388 rules:
 389   ID_COLON { current_lhs = $1; current_lhs_location = @1; } rhses.1
 390 ;
 391
 392 rhses.1:
 393   rhs                { grammar_rule_end (@1); }
 394 | rhses.1 "|" rhs    { grammar_rule_end (@3); }
 395 | rhses.1 ";"
 396 ;
 397
 398 rhs:
 399   /* Nothing.  */
 400     { grammar_rule_begin (current_lhs, current_lhs_location); }
 401 | rhs symbol
 402     { grammar_current_rule_symbol_append ($2, @2); }
 403 | rhs action
 404     { grammar_current_rule_action_append ($2, @2); }
 405 | rhs "%prec" symbol
 406     { grammar_current_rule_prec_set ($3, @3); }
 407 | rhs "%dprec" INT
 408     { grammar_current_rule_dprec_set ($3, @3); }
 409 | rhs "%merge" TYPE
 410     { grammar_current_rule_merge_set ($3, @3); }
 411 ;
 412
 413 symbol:
 414   ID              { $$ = $1; }
 415 | string_as_id    { $$ = $1; }
 416 ;
 417
 418 action:
 419   BRACED_CODE
 420     { $$ = $1; }
 421 ;
 422
 423 /* A string used as an ID: quote it.  */
 424 string_as_id:
 425   STRING
 426     {
 427       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 428       symbol_class_set ($$, token_sym, @1);
 429     }
 430 ;
 431
 432 /* A string used for its contents.  Don't quote it.  */
 433 string_content:
 434   STRING
 435     { $$ = $1; }
 436 ;
 437
 438
 439 epilogue.opt:
 440   /* Nothing.  */
 441 | "%%" EPILOGUE
 442     {
 443       muscle_code_grow ("epilogue", $2, @2);
 444       scanner_last_string_free ();
 445     }
 446 ;
 447
 448 %%
 449
 450
 451 /* Return the location of the left-hand side of a rule whose
 452    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 453    the right-hand side, and return an empty location equal to the end
 454    boundary of RHS[0] if the right-hand side is empty.  */
 455
 456 static YYLTYPE
 457 lloc_default (YYLTYPE const *rhs, int n)
 458 {
 459   int i;
 460   YYLTYPE loc;
 461
 462   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 463      The bug is fixed in 7.4.2m, but play it safe for now.  */
 464   loc.start = rhs[n].end;
 465   loc.end = rhs[n].end;
 466
 467   /* Ignore empty nonterminals the start of the the right-hand side.
 468      Do not bother to ignore them at the end of the right-hand side,
 469      since empty nonterminals have the same end as their predecessors.  */
 470   for (i = 1; i <= n; i++)
 471     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 472       {
 473         loc.start = rhs[i].start;
 474         break;
 475       }
 476
 477   return loc;
 478 }
 479
 480
 481 /* Add a lex-param or a parse-param (depending on TYPE) with
 482    declaration DECL and location LOC.  */
 483
 484 static void
 485 add_param (char const *type, char *decl, location loc)
 486 {
 487   static char const alphanum[26 + 26 + 1 + 10] =
 488     "abcdefghijklmnopqrstuvwxyz"
 489     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 490     "_"
 491     "0123456789";
 492   char const *name_start = NULL;
 493   char *p;
 494
 495   /* Stop on last actual character.  */
 496   for (p = decl; p[1]; p++)
 497     if ((p == decl
 498          || ! memchr (alphanum, p[-1], sizeof alphanum))
 499         && memchr (alphanum, p[0], sizeof alphanum - 10))
 500       name_start = p;
 501
 502   /* Strip the surrounding '{' and '}', and any blanks just inside
 503      the braces.  */
 504   while (*--p == ' ' || *p == '\t')
 505     continue;
 506   p[1] = '\0';
 507   while (*++decl == ' ' || *decl == '\t')
 508     continue;
 509
 510   if (! name_start)
 511     complain_at (loc, _("missing identifier in parameter declaration"));
 512   else
 513     {
 514       char *name;
 515       size_t name_len;
 516
 517       for (name_len = 1;
 518            memchr (alphanum, name_start[name_len], sizeof alphanum);
 519            name_len++)
 520         continue;
 521
 522       name = xmalloc (name_len + 1);
 523       memcpy (name, name_start, name_len);
 524       name[name_len] = '\0';
 525       muscle_pair_list_grow (type, decl, name);
 526       free (name);
 527     }
 528
 529   scanner_last_string_free ();
 530 }
 531
 532 static void
 533 gram_error (location const *loc, char const *msg)
 534 {
 535   complain_at (*loc, "%s", msg);
 536 }
 537
 538 char const *
 539 token_name (int type)
 540 {
 541   return yytname[YYTRANSLATE (type)];
 542 }