src/scan-skel.l

   1 /* Scan Bison Skeletons.                                       -*- C -*-
   2
   3    Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    Bison is free software; you can redistribute it and/or modify it
   9    under the terms of the GNU General Public License as published by
  10    the Free Software Foundation; either version 2, or (at your option)
  11    any later version.
  12
  13    Bison is distributed in the hope that it will be useful, but
  14    WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16    General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with Bison; see the file COPYING.  If not, write to the Free
  20    Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21    02110-1301, USA.  */
  22
  23 %option nodefault noyywrap nounput never-interactive debug
  24 %option prefix="skel_" outfile="lex.yy.c"
  25
  26 %{
  27 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  28    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  29 #undef skel_wrap
  30 #define skel_wrap() 1
  31
  32 #include "system.h"
  33
  34 #include <dirname.h>
  35 #include <error.h>
  36 #include <quotearg.h>
  37
  38 #include "complain.h"
  39 #include "getargs.h"
  40 #include "files.h"
  41 #include "scan-skel.h"
  42
  43 /* Pacify "gcc -Wmissing-prototypes" when flex 2.5.31 is used.  */
  44 int skel_lex (void);
  45 int skel_get_lineno (void);
  46 FILE *skel_get_in (void);
  47 FILE *skel_get_out (void);
  48 int skel_get_leng (void);
  49 char *skel_get_text (void);
  50 void skel_set_lineno (int);
  51 void skel_set_in (FILE *);
  52 void skel_set_out (FILE *);
  53 int skel_get_debug (void);
  54 void skel_set_debug (int);
  55 int skel_lex_destroy (void);
  56
  57 #define QPUTS(String) \
  58    fputs (quotearg_style (c_quoting_style, String), yyout)
  59
  60 #define BASE_QPUTS(File) \
  61    QPUTS (last_component (File))
  62
  63 %}
  64 %%
  65
  66 %{
  67   int lineno IF_LINT (= 0);
  68   char *outname = NULL;
  69 %}
  70
  71 "@output ".*\n {
  72   char const *file_name = yytext + sizeof "@output " - 1;
  73   yytext[yyleng - 1] = '\0';
  74
  75   /* Decode special file names.  They include the directory part,
  76      contrary to their "free" occurrences, used for issuing #includes,
  77      which must not include the directory part.  */
  78
  79   if (*file_name == '@')
  80     {
  81       if (strcmp (file_name, "@output_header_name@") == 0)
  82         file_name = spec_defines_file;
  83       else if (strcmp (file_name, "@output_parser_name@") == 0)
  84         file_name = parser_file_name;
  85       else
  86         fatal ("invalid token in skeleton: %s", yytext);
  87     }
  88   if (outname)
  89     {
  90       free (outname);
  91       xfclose (yyout);
  92     }
  93   outname = xstrdup (file_name);
  94   yyout = xfopen (outname, "w");
  95   lineno = 1;
  96 }
  97
  98 "@@"       fputc ('@', yyout);
  99 "@{"       fputc ('[', yyout);
 100 "@}"       fputc (']', yyout);
 101
 102 "@oline@"  fprintf (yyout, "%d", lineno + 1);
 103 "@ofile@"  QPUTS (outname);
 104 "@dir_prefix@" QPUTS (dir_prefix);
 105 "@output_parser_name@"  BASE_QPUTS (parser_file_name);
 106 "@output_header_name@"  BASE_QPUTS (spec_defines_file);
 107
 108   /* This pattern must not match more than the previous @ patterns. */
 109 @[^{}@\n]* fatal ("invalid @ in skeleton: %s", yytext);
 110 \n         lineno++; ECHO;
 111 [^@\n]+    ECHO;
 112
 113 <<EOF>> {
 114   if (outname)
 115     {
 116       free (outname);
 117       xfclose (yyout);
 118     }
 119   return EOF;
 120 }
 121 %%
 122
 123 /*------------------------.
 124 | Scan a Bison skeleton.  |
 125 `------------------------*/
 126
 127 void
 128 scan_skel (FILE *in)
 129 {
 130   skel_in = in;
 131   skel__flex_debug = trace_flag & trace_skeleton;
 132   skel_lex ();
 133   /* Reclaim Flex's buffers.  */
 134   yy_delete_buffer (YY_CURRENT_BUFFER);
 135 }