data/bison.m4

   1                                                             -*- Autoconf -*-
   2
   3 # Language-independent M4 Macros for Bison.
   4 # Copyright (C) 2002, 2004, 2005, 2006, 2007, 2008 Free Software Foundation,
   5 # Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 ## ---------------- ##
  22 ## Identification.  ##
  23 ## ---------------- ##
  24
  25 # b4_copyright(TITLE, [YEARS])
  26 # ----------------------------
  27 # If YEARS are not defined, use b4_copyright_years.
  28 m4_define([b4_copyright],
  29 [b4_comment([A Bison parser, made by GNU Bison b4_version.])
  30
  31 b4_comment([$1
  32
  33 ]m4_dquote(m4_text_wrap([Copyright (C)
  34 ]m4_ifval([$2], [[$2]], [m4_defn([b4_copyright_years])])[
  35 Free Software Foundation, Inc.]))[
  36
  37 This program is free software: you can redistribute it and/or modify
  38 it under the terms of the GNU General Public License as published by
  39 the Free Software Foundation, either version 3 of the License, or
  40 (at your option) any later version.
  41
  42 This program is distributed in the hope that it will be useful,
  43 but WITHOUT ANY WARRANTY; without even the implied warranty of
  44 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  45 GNU General Public License for more details.
  46
  47 You should have received a copy of the GNU General Public License
  48 along with this program.  If not, see <http://www.gnu.org/licenses/>.])
  49
  50 b4_comment([As a special exception, you may create a larger work that contains
  51 part or all of the Bison parser skeleton and distribute that work
  52 under terms of your choice, so long as that work isn't itself a
  53 parser generator using the skeleton or a modified version thereof
  54 as a parser skeleton.  Alternatively, if you modify or redistribute
  55 the parser skeleton itself, you may (at your option) remove this
  56 special exception, which will cause the skeleton and the resulting
  57 Bison output files to be licensed under the GNU General Public
  58 License without this special exception.
  59
  60 This special exception was added by the Free Software Foundation in
  61 version 2.2 of Bison.])])
  62
  63
  64 ## ---------------- ##
  65 ## Error handling.  ##
  66 ## ---------------- ##
  67
  68 # The following error handling macros print error directives that should not
  69 # become arguments of other macro invocations since they would likely then be
  70 # mangled.  Thus, they print to stdout directly.
  71
  72 # b4_cat(TEXT)
  73 # ------------
  74 # Write TEXT to stdout.  Precede the final newline with an @ so that it's
  75 # escaped.  For example:
  76 #
  77 #   b4_cat([[@complain(invalid input@)]])
  78 m4_define([b4_cat],
  79 [m4_syscmd([cat <<'_m4eof'
  80 ]m4_bpatsubst(m4_dquote($1), [_m4eof], [_m4@`eof])[@
  81 _m4eof
  82 ])dnl
  83 m4_if(m4_sysval, [0], [], [m4_fatal([$0: cannot write to stdout])])])
  84
  85 # b4_error(KIND, FORMAT, [ARG1], [ARG2], ...)
  86 # -------------------------------------------
  87 # Write @KIND(FORMAT@,ARG1@,ARG2@,...@) to stdout.
  88 #
  89 # For example:
  90 #
  91 #   b4_error([[warn]], [[invalid value for `%s': %s]], [[foo]], [[3]])
  92 m4_define([b4_error],
  93 [b4_cat([[@]$1[(]$2[]]dnl
  94 [m4_if([$#], [2], [],
  95        [m4_foreach([b4_arg],
  96                    m4_dquote(m4_shift(m4_shift($@))),
  97                    [[@,]b4_arg])])[@)]])])
  98
  99 # b4_error_at(KIND, START, END, FORMAT, [ARG1], [ARG2], ...)
 100 # ----------------------------------------------------------
 101 # Write @KIND_at(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 102 #
 103 # For example:
 104 #
 105 #   b4_error_at([[complain]], [[input.y:2.3]], [[input.y:5.4]],
 106 #               [[invalid %s]], [[foo]])
 107 m4_define([b4_error_at],
 108 [b4_cat([[@]$1[_at(]$2[@,]$3[@,]$4[]]dnl
 109 [m4_if([$#], [4], [],
 110        [m4_foreach([b4_arg],
 111                    m4_dquote(m4_shift(m4_shift(m4_shift(m4_shift($@))))),
 112                    [[@,]b4_arg])])[@)]])])
 113
 114 # b4_warn(FORMAT, [ARG1], [ARG2], ...)
 115 # ------------------------------------
 116 # Write @warn(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 117 #
 118 # For example:
 119 #
 120 #   b4_warn([[invalid value for `%s': %s]], [[foo]], [[3]])
 121 #
 122 # As a simple test suite, this:
 123 #
 124 #   m4_divert(-1)
 125 #   m4_define([asdf], [ASDF])
 126 #   m4_define([fsa], [FSA])
 127 #   m4_define([fdsa], [FDSA])
 128 #   b4_warn([[[asdf), asdf]]], [[[fsa), fsa]]], [[[fdsa), fdsa]]])
 129 #   b4_warn([[asdf), asdf]], [[fsa), fsa]], [[fdsa), fdsa]])
 130 #   b4_warn()
 131 #   b4_warn(1)
 132 #   b4_warn(1, 2)
 133 #
 134 # Should produce this without newlines:
 135 #
 136 #   @warn([asdf), asdf]@,[fsa), fsa]@,[fdsa), fdsa]@)
 137 #   @warn(asdf), asdf@,fsa), fsa@,fdsa), fdsa@)
 138 #   @warn(@)
 139 #   @warn(1@)
 140 #   @warn(1@,2@)
 141 m4_define([b4_warn],
 142 [b4_error([[warn]], $@)])
 143
 144 # b4_warn_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 145 # ---------------------------------------------------
 146 # Write @warn(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 147 #
 148 # For example:
 149 #
 150 #   b4_warn_at([[input.y:2.3]], [[input.y:5.4]], [[invalid %s]], [[foo]])
 151 m4_define([b4_warn_at],
 152 [b4_error_at([[warn]], $@)])
 153
 154 # b4_complain(FORMAT, [ARG1], [ARG2], ...)
 155 # ----------------------------------------
 156 # Write @complain(FORMAT@,ARG1@,ARG2@,...@) to stdout.
 157 #
 158 # See b4_warn example.
 159 m4_define([b4_complain],
 160 [b4_error([[complain]], $@)])
 161
 162 # b4_complain_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 163 # -------------------------------------------------------
 164 # Write @complain(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout.
 165 #
 166 # See b4_warn_at example.
 167 m4_define([b4_complain_at],
 168 [b4_error_at([[complain]], $@)])
 169
 170 # b4_fatal(FORMAT, [ARG1], [ARG2], ...)
 171 # -------------------------------------
 172 # Write @fatal(FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 173 #
 174 # See b4_warn example.
 175 m4_define([b4_fatal],
 176 [b4_error([[fatal]], $@)dnl
 177 m4_exit(1)])
 178
 179 # b4_fatal_at(START, END, FORMAT, [ARG1], [ARG2], ...)
 180 # ----------------------------------------------------
 181 # Write @fatal(START@,END@,FORMAT@,ARG1@,ARG2@,...@) to stdout and exit.
 182 #
 183 # See b4_warn_at example.
 184 m4_define([b4_fatal_at],
 185 [b4_error_at([[fatal]], $@)dnl
 186 m4_exit(1)])
 187
 188
 189 ## ---------------- ##
 190 ## Default values.  ##
 191 ## ---------------- ##
 192
 193 # m4_define_default([b4_lex_param], [])   dnl breaks other skeletons
 194 m4_define_default([b4_pre_prologue], [])
 195 m4_define_default([b4_post_prologue], [])
 196 m4_define_default([b4_epilogue], [])
 197 m4_define_default([b4_parse_param], [])
 198
 199 # The initial column and line.
 200 m4_define_default([b4_location_initial_column], [1])
 201 m4_define_default([b4_location_initial_line],   [1])
 202
 203
 204 ## ------------ ##
 205 ## Data Types.  ##
 206 ## ------------ ##
 207
 208 # b4_ints_in(INT1, INT2, LOW, HIGH)
 209 # ---------------------------------
 210 # Return 1 iff both INT1 and INT2 are in [LOW, HIGH], 0 otherwise.
 211 m4_define([b4_ints_in],
 212 [m4_eval([$3 <= $1 && $1 <= $4 && $3 <= $2 && $2 <= $4])])
 213
 214
 215 # b4_subtract(LHS, RHS)
 216 # ---------------------
 217 # Evaluate LHS - RHS if they are integer literals, otherwise expand
 218 # to (LHS) - (RHS).
 219 m4_define([b4_subtract],
 220 [m4_bmatch([$1$2], [^[0123456789]*$],
 221            [m4_eval([$1 - $2])],
 222            [($1) - ($2)])])
 223
 224
 225 ## ------------------ ##
 226 ## Decoding options.  ##
 227 ## ------------------ ##
 228
 229 # b4_flag_if(FLAG, IF-TRUE, IF-FALSE)
 230 # -----------------------------------
 231 # Run IF-TRUE if b4_FLAG_flag is 1, IF-FALSE if FLAG is 0, otherwise fail.
 232 m4_define([b4_flag_if],
 233 [m4_case(b4_$1_flag,
 234          [0], [$3],
 235          [1], [$2],
 236          [m4_fatal([invalid $1 value: ]$1)])])
 237
 238
 239 # b4_define_flag_if(FLAG)
 240 # -----------------------
 241 # Define "b4_FLAG_if(IF-TRUE, IF-FALSE)" that depends on the
 242 # value of the Boolean FLAG.
 243 m4_define([b4_define_flag_if],
 244 [_b4_define_flag_if($[1], $[2], [$1])])
 245
 246 # _b4_define_flag_if($1, $2, FLAG)
 247 # --------------------------------
 248 # This macro works around the impossibility to define macros
 249 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 250 # This sucks hard, GNU M4 should really provide M5 like $$1.
 251 m4_define([_b4_define_flag_if],
 252 [m4_if([$1$2], $[1]$[2], [],
 253        [m4_fatal([$0: Invalid arguments: $@])])dnl
 254 m4_define([b4_$3_if],
 255           [b4_flag_if([$3], [$1], [$2])])])
 256
 257
 258 # b4_FLAG_if(IF-TRUE, IF-FALSE)
 259 # -----------------------------
 260 # Expand IF-TRUE, if FLAG is true, IF-FALSE otherwise.
 261 b4_define_flag_if([defines])            # Whether headers are requested.
 262 b4_define_flag_if([error_verbose])      # Whether error are verbose.
 263 b4_define_flag_if([glr])                # Whether a GLR parser is requested.
 264 b4_define_flag_if([locations])          # Whether locations are tracked.
 265 b4_define_flag_if([nondeterministic])   # Whether conflicts should be handled.
 266 b4_define_flag_if([yacc])               # Whether POSIX Yacc is emulated.
 267
 268
 269 ## ----------- ##
 270 ## Synclines.  ##
 271 ## ----------- ##
 272
 273 # b4_basename(NAME)
 274 # -----------------
 275 # Similar to POSIX basename; the differences don't matter here.
 276 # Beware that NAME is not evaluated.
 277 m4_define([b4_basename],
 278 [m4_bpatsubst([$1], [^.*/\([^/]+\)/*$], [\1])])
 279
 280
 281 # b4_syncline(LINE, FILE)
 282 # -----------------------
 283 m4_define([b4_syncline],
 284 [b4_flag_if([synclines], [
 285 b4_sync_end([__line__], [b4_basename(m4_quote(__file__))])
 286 b4_sync_start([$1], [$2])])])
 287
 288 m4_define([b4_sync_end], [b4_comment([Line $1 of $2])])
 289 m4_define([b4_sync_start], [b4_comment([Line $1 of $2])])
 290
 291 # b4_user_code(USER-CODE)
 292 # -----------------------
 293 # Emit code from the user, ending it with synclines.
 294 m4_define([b4_user_code],
 295 [$1
 296 b4_syncline([@oline@], [@ofile@])])
 297
 298
 299 # b4_define_user_code(MACRO)
 300 # --------------------------
 301 # From b4_MACRO, build b4_user_MACRO that includes the synclines.
 302 m4_define([b4_define_user_code],
 303 [m4_define([b4_user_$1],
 304 [b4_user_code([b4_$1])])])
 305
 306
 307 # b4_user_actions
 308 # b4_user_initial_action
 309 # b4_user_post_prologue
 310 # b4_user_pre_prologue
 311 # b4_user_stype
 312 # ----------------------
 313 # Macros that issue user code, ending with synclines.
 314 b4_define_user_code([actions])
 315 b4_define_user_code([initial_action])
 316 b4_define_user_code([post_prologue])
 317 b4_define_user_code([pre_prologue])
 318 b4_define_user_code([stype])
 319
 320
 321 # b4_check_user_names(WHAT, USER-LIST, BISON-NAMESPACE)
 322 # --------------------------------------------------------
 323 # Warn if any name of type WHAT is used by the user (as recorded in USER-LIST)
 324 # but is not used by Bison (as recorded by macros in the namespace
 325 # BISON-NAMESPACE).
 326 #
 327 # USER-LIST must expand to a list specifying all grammar occurrences of all
 328 # names of type WHAT.   Each item in the list must be a triplet specifying one
 329 # occurrence: name, start boundary, and end boundary.  Empty string names are
 330 # fine.  An empty list is fine.
 331 #
 332 # For example, to define b4_foo_user_names to be used for USER-LIST with three
 333 # name occurrences and with correct quoting:
 334 #
 335 #   m4_define([b4_foo_user_names],
 336 #             [[[[[[bar]], [[parser.y:1.7]], [[parser.y:1.16]]]],
 337 #               [[[[bar]], [[parser.y:5.7]], [[parser.y:5.16]]]],
 338 #               [[[[baz]], [[parser.y:8.7]], [[parser.y:8.16]]]]]])
 339 #
 340 # The macro BISON-NAMESPACE(bar) must be defined iff the name bar of type WHAT
 341 # is used by Bison (in the front-end or in the skeleton).  Empty string names
 342 # are fine, but it would be ugly for Bison to actually use one.
 343 #
 344 # For example, to use b4_foo_bison_names for BISON-NAMESPACE and define that
 345 # the names bar and baz are used by Bison:
 346 #
 347 #   m4_define([b4_foo_bison_names(bar)])
 348 #   m4_define([b4_foo_bison_names(baz)])
 349 #
 350 # To invoke b4_check_user_names with TYPE foo, with USER-LIST
 351 # b4_foo_user_names, with BISON-NAMESPACE b4_foo_bison_names, and with correct
 352 # quoting:
 353 #
 354 #   b4_check_user_names([[foo]], [b4_foo_user_names],
 355 #                       [[b4_foo_bison_names]])
 356 m4_define([b4_check_user_names],
 357 [m4_foreach([b4_occurrence], $2,
 358 [m4_pushdef([b4_occurrence], b4_occurrence)dnl
 359 m4_pushdef([b4_user_name], m4_car(b4_occurrence))dnl
 360 m4_pushdef([b4_start], m4_car(m4_shift(b4_occurrence)))dnl
 361 m4_pushdef([b4_end], m4_shift(m4_shift(b4_occurrence)))dnl
 362 m4_ifndef($3[(]m4_quote(b4_user_name)[)],
 363           [b4_warn_at([b4_start], [b4_end],
 364                       [[%s `%s' is not used]],
 365                       [$1], [b4_user_name])])[]dnl
 366 m4_popdef([b4_occurrence])dnl
 367 m4_popdef([b4_user_name])dnl
 368 m4_popdef([b4_start])dnl
 369 m4_popdef([b4_end])dnl
 370 ])])
 371
 372 # b4_percent_define_get(VARIABLE)
 373 # -------------------------------
 374 # Mimic muscle_percent_define_get in ../src/muscle_tab.h exactly.  That is, if
 375 # the %define variable VARIABLE is defined, emit its value.  Also, record
 376 # Bison's usage of VARIABLE by defining
 377 # b4_percent_define_bison_variables(VARIABLE).
 378 #
 379 # For example:
 380 #
 381 #   b4_percent_define_get([[foo]])
 382 m4_define([b4_percent_define_get],
 383 [m4_define([b4_percent_define_bison_variables(]$1[)])dnl
 384 m4_ifdef([b4_percent_define(]$1[)], [m4_indir([b4_percent_define(]$1[)])])])
 385
 386 # b4_percent_define_get_loc(VARIABLE)
 387 # -----------------------------------
 388 # Mimic muscle_percent_define_get_loc in ../src/muscle_tab.h exactly.  That is,
 389 # if the %define variable VARIABLE is undefined, complain fatally since that's
 390 # a Bison or skeleton error.  Otherwise, return its definition location in a
 391 # form approriate for the first two arguments of b4_warn_at, b4_complain_at, or
 392 # b4_fatal_at.  Don't record this as a Bison usage of VARIABLE as there's no
 393 # reason to suspect that the user-supplied value has yet influenced the output.
 394 #
 395 # For example:
 396 #
 397 #   b4_complain_at(b4_percent_define_get_loc([[foo]]), [[invalid foo]])
 398 m4_define([b4_percent_define_get_loc],
 399 [m4_ifdef([b4_percent_define_loc(]$1[)],
 400           [m4_pushdef([b4_loc], m4_indir([b4_percent_define_loc(]$1[)]))dnl
 401 b4_loc[]dnl
 402 m4_popdef([b4_loc])],
 403           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_loc]], [$1])])])
 404
 405 # b4_percent_define_get_syncline(VARIABLE)
 406 # ----------------------------------------
 407 # Mimic muscle_percent_define_get_syncline in ../src/muscle_tab.h exactly.
 408 # That is, if the %define variable VARIABLE is undefined, complain fatally
 409 # since that's a Bison or skeleton error.  Otherwise, return its definition
 410 # location as a b4_syncline invocation.  Don't record this as a Bison usage of
 411 # VARIABLE as there's no reason to suspect that the user-supplied value has yet
 412 # influenced the output.
 413 #
 414 # For example:
 415 #
 416 #   b4_percent_define_get_syncline([[foo]])
 417 m4_define([b4_percent_define_get_syncline],
 418 [m4_ifdef([b4_percent_define_syncline(]$1[)],
 419           [m4_indir([b4_percent_define_syncline(]$1[)])],
 420           [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_get_syncline]], [$1])])])
 421
 422 # b4_percent_define_ifdef(VARIABLE, IF-TRUE, [IF-FALSE])
 423 # ------------------------------------------------------
 424 # Mimic muscle_percent_define_ifdef in ../src/muscle_tab.h exactly.  That is,
 425 # if the %define variable VARIABLE is defined, expand IF-TRUE, else expand
 426 # IF-FALSE.  Also, record Bison's usage of VARIABLE by defining
 427 # b4_percent_define_bison_variables(VARIABLE).
 428 #
 429 # For example:
 430 #
 431 #   b4_percent_define_ifdef([[foo]], [[it's defined]], [[it's undefined]])
 432 m4_define([b4_percent_define_ifdef],
 433 [m4_ifdef([b4_percent_define(]$1[)],
 434           [m4_define([b4_percent_define_bison_variables(]$1[)])$2],
 435           [$3])])
 436
 437 # b4_percent_define_flag_if(VARIABLE, IF-TRUE, [IF-FALSE])
 438 # --------------------------------------------------------
 439 # Mimic muscle_percent_define_flag_if in ../src/muscle_tab.h exactly.  That is,
 440 # if the %define variable VARIABLE is defined to "" or "true", expand IF-TRUE.
 441 # If it is defined to "false", expand IF-FALSE.  Complain if it is undefined
 442 # (a Bison or skeleton error since the default value should have been set
 443 # already) or defined to any other value (possibly a user error).  Also, record
 444 # Bison's usage of VARIABLE by defining
 445 # b4_percent_define_bison_variables(VARIABLE).
 446 #
 447 # For example:
 448 #
 449 #   b4_percent_define_flag_if([[foo]], [[it's true]], [[it's false]])
 450 m4_define([b4_percent_define_flag_if],
 451 [b4_percent_define_ifdef([$1],
 452   [m4_case(b4_percent_define_get([$1]),
 453            [], [$2], [true], [$2], [false], [$3],
 454            [m4_expand_once([b4_complain_at(b4_percent_define_get_loc([$1]),
 455                                            [[invalid value for %%define Boolean variable `%s']],
 456                                            [$1])],
 457                            [[b4_percent_define_flag_if($1)]])])],
 458   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_flag_if]], [$1])])])
 459
 460 # b4_percent_define_default(VARIABLE, DEFAULT)
 461 # --------------------------------------------
 462 # Mimic muscle_percent_define_default in ../src/muscle_tab.h exactly.  That is,
 463 # if the %define variable VARIABLE is undefined, set its value to DEFAULT.
 464 # Don't record this as a Bison usage of VARIABLE as there's no reason to
 465 # suspect that the value has yet influenced the output.
 466 #
 467 # For example:
 468 #
 469 #   b4_percent_define_default([[foo]], [[default value]])
 470 m4_define([b4_percent_define_default],
 471 [m4_ifndef([b4_percent_define(]$1[)],
 472            [m4_define([b4_percent_define(]$1[)], [$2])dnl
 473             m4_define([b4_percent_define_loc(]$1[)],
 474                       [[[[[Bison:b4_percent_define_default]:1.0]], [[[Bison:b4_percent_define_default]:1.0]]]])dnl
 475             m4_define([b4_percent_define_syncline(]$1[)],
 476                       [[]b4_syncline(1, [["[Bison:b4_percent_define_default]"]])[
 477 ]])])])
 478
 479 # b4_percent_define_check_values(VALUES)
 480 # --------------------------------------
 481 # Mimic muscle_percent_define_check_values in ../src/muscle_tab.h exactly
 482 # except that the VALUES structure is more appropriate for M4.  That is, VALUES
 483 # is a list of sublists of strings.  For each sublist, the first string is the
 484 # name of a %define variable, and all remaining strings in that sublist are the
 485 # valid values for that variable.  Complain if such a variable is undefined (a
 486 # Bison error since the default value should have been set already) or defined
 487 # to any other value (possibly a user error).  Don't record this as a Bison
 488 # usage of the variable as there's no reason to suspect that the value has yet
 489 # influenced the output.
 490 #
 491 # For example:
 492 #
 493 #   b4_percent_define_check_values([[[[foo]], [[foo-value1]], [[foo-value2]]]],
 494 #                                  [[[[bar]], [[bar-value1]]]])
 495 m4_define([b4_percent_define_check_values],
 496 [m4_foreach([b4_sublist], m4_quote($@),
 497             [_b4_percent_define_check_values(b4_sublist)])])
 498
 499 m4_define([_b4_percent_define_check_values],
 500 [m4_ifdef([b4_percent_define(]$1[)],
 501   [m4_pushdef([b4_good_value], [0])dnl
 502    m4_if($#, 1, [],
 503          [m4_foreach([b4_value], m4_dquote(m4_shift($@)),
 504                      [m4_if(m4_indir([b4_percent_define(]$1[)]), b4_value,
 505                             [m4_define([b4_good_value], [1])])])])dnl
 506    m4_if(b4_good_value, [0],
 507          [b4_complain_at(b4_percent_define_get_loc([$1]),
 508                          [[invalid value for %%define variable `%s': `%s']],
 509                          [$1],
 510                          m4_dquote(m4_indir([b4_percent_define(]$1[)])))])dnl
 511    m4_popdef([b4_good_value])],
 512   [b4_fatal([[undefined %%define variable `%s' passed to b4_percent_define_check_values]], [$1])])])
 513
 514 # b4_percent_code_get([QUALIFIER])
 515 # --------------------------------
 516 # If any %code blocks for QUALIFIER are defined, emit them beginning with a
 517 # comment and ending with synclines and a newline.  If QUALIFIER is not
 518 # specified or empty, do this for the unqualified %code blocks.  Also, record
 519 # Bison's usage of QUALIFIER (if specified) by defining
 520 # b4_percent_code_bison_qualifiers(QUALIFIER).
 521 #
 522 # For example, to emit any unqualified %code blocks followed by any %code
 523 # blocks for the qualifier foo:
 524 #
 525 #   b4_percent_code_get
 526 #   b4_percent_code_get([[foo]])
 527 m4_define([b4_percent_code_get],
 528 [m4_pushdef([b4_macro_name], [[b4_percent_code(]$1[)]])dnl
 529 m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])dnl
 530 m4_ifdef(b4_macro_name,
 531 [b4_comment([m4_if([$#], [0], [[Unqualified %code]],
 532                    [["%code ]$1["]])[ blocks.]])
 533 b4_user_code([m4_indir(b4_macro_name)])
 534 ])dnl
 535 m4_popdef([b4_macro_name])])
 536
 537 # b4_percent_code_ifdef(QUALIFIER, IF-TRUE, [IF-FALSE])
 538 # -----------------------------------------------------
 539 # If any %code blocks for QUALIFIER (or unqualified %code blocks if
 540 # QUALIFIER is empty) are defined, expand IF-TRUE, else expand IF-FALSE.
 541 # Also, record Bison's usage of QUALIFIER (if specified) by defining
 542 # b4_percent_code_bison_qualifiers(QUALIFIER).
 543 m4_define([b4_percent_code_ifdef],
 544 [m4_ifdef([b4_percent_code(]$1[)],
 545           [m4_ifval([$1], [m4_define([b4_percent_code_bison_qualifiers(]$1[)])])$2],
 546           [$3])])
 547
 548
 549 # Default values for %define.
 550 # ---------------------------
 551 # If the %token.prefix, it is empty.
 552 m4_percent_define_default([[token.prefix]], [[]])
 553
 554
 555
 556 ## ----------------------------------------------------------- ##
 557 ## After processing the skeletons, check that all the user's   ##
 558 ## %define variables and %code qualifiers were used by Bison.  ##
 559 ## ----------------------------------------------------------- ##
 560
 561 m4_define([b4_check_user_names_wrap],
 562 [m4_ifdef([b4_percent_]$1[_user_]$2[s],
 563           [b4_check_user_names([[%]$1 $2],
 564                                [b4_percent_]$1[_user_]$2[s],
 565                                [[b4_percent_]$1[_bison_]$2[s]])])])
 566
 567 m4_wrap_lifo([
 568 b4_check_user_names_wrap([[define]], [[variable]])
 569 b4_check_user_names_wrap([[code]], [[qualifier]])
 570 ])