src/parse-gram.y

   1 %{/* Bison Grammar Parser                             -*- C -*-
   2
   3    Copyright (C) 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   4
   5    This file is part of Bison, the GNU Compiler Compiler.
   6
   7    This program is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU General Public License as published by
   9    the Free Software Foundation; either version 2 of the License, or
  10    (at your option) any later version.
  11
  12    This program is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15    GNU General Public License for more details.
  16
  17    You should have received a copy of the GNU General Public License
  18    along with this program; if not, write to the Free Software
  19    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20    02110-1301  USA
  21 */
  22
  23 #include <config.h>
  24 #include "system.h"
  25
  26 #include "complain.h"
  27 #include "conflicts.h"
  28 #include "files.h"
  29 #include "getargs.h"
  30 #include "gram.h"
  31 #include "muscle_tab.h"
  32 #include "quotearg.h"
  33 #include "reader.h"
  34 #include "symlist.h"
  35 #include "scan-gram.h"
  36 #include "scan-code.h"
  37 #include "strverscmp.h"
  38
  39 #define YYLLOC_DEFAULT(Current, Rhs, N)  (Current) = lloc_default (Rhs, N)
  40 static YYLTYPE lloc_default (YYLTYPE const *, int);
  41
  42 #define YY_LOCATION_PRINT(File, Loc) \
  43           location_print (File, Loc)
  44
  45 static void version_check (location const *loc, char const *version);
  46
  47 /* Request detailed syntax error messages, and pass them to GRAM_ERROR.
  48    FIXME: depends on the undocumented availability of YYLLOC.  */
  49 #undef  yyerror
  50 #define yyerror(Msg) \
  51         gram_error (&yylloc, Msg)
  52 static void gram_error (location const *, char const *);
  53
  54 static char const *char_name (char);
  55
  56 static void add_param (char const *, char *, location);
  57
  58 static symbol_class current_class = unknown_sym;
  59 static uniqstr current_type = 0;
  60 static symbol *current_lhs;
  61 static location current_lhs_location;
  62 static int current_prec = 0;
  63
  64 #ifdef UINT_FAST8_MAX
  65 # define YYTYPE_UINT8 uint_fast8_t
  66 #endif
  67 #ifdef INT_FAST8_MAX
  68 # define YYTYPE_INT8 int_fast8_t
  69 #endif
  70 #ifdef UINT_FAST16_MAX
  71 # define YYTYPE_UINT16 uint_fast16_t
  72 #endif
  73 #ifdef INT_FAST16_MAX
  74 # define YYTYPE_INT16 int_fast16_t
  75 #endif
  76 %}
  77
  78 %debug
  79 %verbose
  80 %defines
  81 %locations
  82 %pure-parser
  83 %error-verbose
  84 %defines
  85 %name-prefix="gram_"
  86
  87 %initial-action
  88 {
  89   /* Bison's grammar can initial empty locations, hence a default
  90      location is needed. */
  91   boundary_set (&@$.start, current_file, 1, 0);
  92   boundary_set (&@$.end, current_file, 1, 0);
  93 }
  94
  95 /* Only NUMBERS have a value.  */
  96 %union
  97 {
  98   symbol *symbol;
  99   symbol_list *list;
 100   int integer;
 101   char *chars;
 102   assoc assoc;
 103   uniqstr uniqstr;
 104   unsigned char character;
 105 };
 106
 107 /* Define the tokens together with their human representation.  */
 108 %token GRAM_EOF 0 "end of file"
 109 %token STRING     "string"
 110 %token INT        "integer"
 111
 112 %token PERCENT_TOKEN       "%token"
 113 %token PERCENT_NTERM       "%nterm"
 114
 115 %token PERCENT_TYPE        "%type"
 116 %token PERCENT_DESTRUCTOR  "%destructor"
 117 %token PERCENT_PRINTER     "%printer"
 118
 119 %token PERCENT_LEFT        "%left"
 120 %token PERCENT_RIGHT       "%right"
 121 %token PERCENT_NONASSOC    "%nonassoc"
 122
 123 %token PERCENT_PREC          "%prec"
 124 %token PERCENT_DPREC         "%dprec"
 125 %token PERCENT_MERGE         "%merge"
 126
 127
 128 /*----------------------.
 129 | Global Declarations.  |
 130 `----------------------*/
 131
 132 %token
 133   PERCENT_AFTER_HEADER    "%after-header"
 134   PERCENT_BEFORE_HEADER   "%before-header"
 135   PERCENT_DEBUG           "%debug"
 136   PERCENT_DEFAULT_PREC    "%default-prec"
 137   PERCENT_DEFINE          "%define"
 138   PERCENT_DEFINES         "%defines"
 139   PERCENT_END_HEADER      "%end-header"
 140   PERCENT_ERROR_VERBOSE   "%error-verbose"
 141   PERCENT_EXPECT          "%expect"
 142   PERCENT_EXPECT_RR       "%expect-rr"
 143   PERCENT_FILE_PREFIX     "%file-prefix"
 144   PERCENT_GLR_PARSER      "%glr-parser"
 145   PERCENT_INITIAL_ACTION  "%initial-action"
 146   PERCENT_LEX_PARAM       "%lex-param"
 147   PERCENT_LOCATIONS       "%locations"
 148   PERCENT_NAME_PREFIX     "%name-prefix"
 149   PERCENT_NO_DEFAULT_PREC "%no-default-prec"
 150   PERCENT_NO_LINES        "%no-lines"
 151   PERCENT_NONDETERMINISTIC_PARSER
 152                           "%nondeterministic-parser"
 153   PERCENT_OUTPUT          "%output"
 154   PERCENT_PARSE_PARAM     "%parse-param"
 155   PERCENT_PURE_PARSER     "%pure-parser"
 156   PERCENT_REQUIRE         "%require"
 157   PERCENT_SKELETON        "%skeleton"
 158   PERCENT_START           "%start"
 159   PERCENT_START_HEADER    "%start-header"
 160   PERCENT_TOKEN_TABLE     "%token-table"
 161   PERCENT_VERBOSE         "%verbose"
 162   PERCENT_YACC            "%yacc"
 163 ;
 164
 165 %token BRACED_CODE     "{...}"
 166 %token CHAR            "char"
 167 %token EPILOGUE        "epilogue"
 168 %token EQUAL           "="
 169 %token ID              "identifier"
 170 %token ID_COLON        "identifier:"
 171 %token PERCENT_PERCENT "%%"
 172 %token PIPE            "|"
 173 %token PROLOGUE        "%{...%}"
 174 %token SEMICOLON       ";"
 175 %token TYPE            "type"
 176
 177 %type <character> CHAR
 178 %printer { fputs (char_name ($$), stderr); } CHAR
 179
 180 %type <chars> STRING string_content "{...}" PROLOGUE EPILOGUE
 181 %printer { fputs (quotearg_style (c_quoting_style, $$), stderr); }
 182          STRING string_content
 183 %printer { fprintf (stderr, "{\n%s\n}", $$); } "{...}" PROLOGUE EPILOGUE
 184
 185 %type <uniqstr> TYPE ID ID_COLON
 186 %printer { fprintf (stderr, "<%s>", $$); } TYPE
 187 %printer { fputs ($$, stderr); } ID
 188 %printer { fprintf (stderr, "%s:", $$); } ID_COLON
 189
 190 %type <integer> INT
 191 %printer { fprintf (stderr, "%d", $$); } INT
 192
 193 %type <symbol> id id_colon symbol string_as_id
 194 %printer { fprintf (stderr, "%s", $$->tag); } id symbol string_as_id
 195 %printer { fprintf (stderr, "%s:", $$->tag); } id_colon
 196
 197 %type <assoc> precedence_declarator
 198 %type <list>  symbols.1
 199 %%
 200
 201 input:
 202   declarations "%%" grammar epilogue.opt
 203 ;
 204
 205
 206         /*------------------------------------.
 207         | Declarations: before the first %%.  |
 208         `------------------------------------*/
 209
 210 declarations:
 211   /* Nothing */
 212 | declarations declaration
 213 ;
 214
 215 declaration:
 216   grammar_declaration
 217 | PROLOGUE
 218     {
 219       prologue_augment (translate_code ($1, @1), @1, typed);
 220     }
 221 | "%after-header" "{...}"
 222     {
 223       /* Remove the '{', and replace the '}' with '\n'.  */
 224       $2[strlen ($2) - 1] = '\n';
 225       prologue_augment (translate_code ($2+1, @2), @2, true);
 226     }
 227 | "%before-header" "{...}"
 228     {
 229       /* Remove the '{', and replace the '}' with '\n'.  */
 230       $2[strlen ($2) - 1] = '\n';
 231       prologue_augment (translate_code ($2+1, @2), @2, false);
 232     }
 233 | "%debug"                                 { debug_flag = true; }
 234 | "%define" string_content
 235     {
 236       static char one[] = "1";
 237       muscle_insert ($2, one);
 238     }
 239 | "%define" string_content string_content  { muscle_insert ($2, $3); }
 240 | "%defines"                               { defines_flag = true; }
 241 | "%end-header" "{...}"
 242     {
 243       /* Remove the '{', and replace the '}' with '\n'.  */
 244       $2[strlen ($2) - 1] = '\n';
 245       muscle_code_grow ("end_header", translate_code ($2+1, @2), @2);
 246     }
 247 | "%error-verbose"                         { error_verbose = true; }
 248 | "%expect" INT                            { expected_sr_conflicts = $2; }
 249 | "%expect-rr" INT                         { expected_rr_conflicts = $2; }
 250 | "%file-prefix" "=" string_content        { spec_file_prefix = $3; }
 251 | "%glr-parser"
 252     {
 253       nondeterministic_parser = true;
 254       glr_parser = true;
 255     }
 256 | "%initial-action" "{...}"
 257     {
 258       muscle_code_grow ("initial_action", translate_symbol_action ($2, @2), @2);
 259     }
 260 | "%lex-param" "{...}"                     { add_param ("lex_param", $2, @2); }
 261 | "%locations"                             { locations_flag = true; }
 262 | "%name-prefix" "=" string_content        { spec_name_prefix = $3; }
 263 | "%no-lines"                              { no_lines_flag = true; }
 264 | "%nondeterministic-parser"               { nondeterministic_parser = true; }
 265 | "%output" "=" string_content             { spec_outfile = $3; }
 266 | "%parse-param" "{...}"                   { add_param ("parse_param", $2, @2); }
 267 | "%pure-parser"                           { pure_parser = true; }
 268 | "%require" string_content                { version_check (&@2, $2); }
 269 | "%skeleton" string_content               { skeleton = $2; }
 270 | "%start-header" "{...}"
 271     {
 272       /* Remove the '{', and replace the '}' with '\n'.  */
 273       $2[strlen ($2) - 1] = '\n';
 274       muscle_code_grow ("start_header", translate_code ($2+1, @2), @2);
 275     }
 276 | "%token-table"                           { token_table_flag = true; }
 277 | "%verbose"                               { report_flag = report_states; }
 278 | "%yacc"                                  { yacc_flag = true; }
 279 | /*FIXME: Err?  What is this horror doing here? */ ";"
 280 ;
 281
 282 grammar_declaration:
 283   precedence_declaration
 284 | symbol_declaration
 285 | "%start" symbol
 286     {
 287       grammar_start_symbol_set ($2, @2);
 288     }
 289 | "%destructor" "{...}" symbols.1
 290     {
 291       symbol_list *list;
 292       const char *action = translate_symbol_action ($2, @2);
 293       for (list = $3; list; list = list->next)
 294         symbol_destructor_set (list->sym, action, @2);
 295       symbol_list_free ($3);
 296     }
 297 | "%printer" "{...}" symbols.1
 298     {
 299       symbol_list *list;
 300       const char *action = translate_symbol_action ($2, @2);
 301       for (list = $3; list; list = list->next)
 302         symbol_printer_set (list->sym, action, @2);
 303       symbol_list_free ($3);
 304     }
 305 | "%default-prec"
 306     {
 307       default_prec = true;
 308     }
 309 | "%no-default-prec"
 310     {
 311       default_prec = false;
 312     }
 313 ;
 314
 315
 316 /*----------*
 317  | %union.  |
 318  *----------*/
 319
 320 %token PERCENT_UNION "%union";
 321
 322 union_name:
 323   /* Nothing. */ {}
 324 | ID             { muscle_code_grow ("union_name", $1, @1); }
 325 ;
 326
 327 grammar_declaration:
 328   "%union" union_name "{...}"
 329     {
 330       char const *body = $3;
 331
 332       if (typed)
 333         {
 334           /* Concatenate the union bodies, turning the first one's
 335              trailing '}' into '\n', and omitting the second one's '{'.  */
 336           char *code = muscle_find ("stype");
 337           code[strlen (code) - 1] = '\n';
 338           body++;
 339         }
 340
 341       typed = true;
 342       muscle_code_grow ("stype", body, @3);
 343     }
 344 ;
 345
 346
 347
 348
 349 symbol_declaration:
 350   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 351     {
 352       current_class = unknown_sym;
 353       current_type = NULL;
 354     }
 355 | "%token" { current_class = token_sym; } symbol_defs.1
 356     {
 357       current_class = unknown_sym;
 358       current_type = NULL;
 359     }
 360 | "%type" TYPE symbols.1
 361     {
 362       symbol_list *list;
 363       for (list = $3; list; list = list->next)
 364         symbol_type_set (list->sym, $2, @2);
 365       symbol_list_free ($3);
 366     }
 367 ;
 368
 369 precedence_declaration:
 370   precedence_declarator type.opt symbols.1
 371     {
 372       symbol_list *list;
 373       ++current_prec;
 374       for (list = $3; list; list = list->next)
 375         {
 376           symbol_type_set (list->sym, current_type, @2);
 377           symbol_precedence_set (list->sym, current_prec, $1, @1);
 378         }
 379       symbol_list_free ($3);
 380       current_type = NULL;
 381     }
 382 ;
 383
 384 precedence_declarator:
 385   "%left"     { $$ = left_assoc; }
 386 | "%right"    { $$ = right_assoc; }
 387 | "%nonassoc" { $$ = non_assoc; }
 388 ;
 389
 390 type.opt:
 391   /* Nothing. */ { current_type = NULL; }
 392 | TYPE           { current_type = $1; }
 393 ;
 394
 395 /* One or more nonterminals to be %typed. */
 396 symbols.1:
 397   symbol            { $$ = symbol_list_new ($1, @1); }
 398 | symbols.1 symbol  { $$ = symbol_list_prepend ($1, $2, @2); }
 399 ;
 400
 401 /* One token definition.  */
 402 symbol_def:
 403   TYPE
 404      {
 405        current_type = $1;
 406      }
 407 | id
 408      {
 409        symbol_class_set ($1, current_class, @1, true);
 410        symbol_type_set ($1, current_type, @1);
 411      }
 412 | id INT
 413     {
 414       symbol_class_set ($1, current_class, @1, true);
 415       symbol_type_set ($1, current_type, @1);
 416       symbol_user_token_number_set ($1, $2, @2);
 417     }
 418 | id string_as_id
 419     {
 420       symbol_class_set ($1, current_class, @1, true);
 421       symbol_type_set ($1, current_type, @1);
 422       symbol_make_alias ($1, $2, @$);
 423     }
 424 | id INT string_as_id
 425     {
 426       symbol_class_set ($1, current_class, @1, true);
 427       symbol_type_set ($1, current_type, @1);
 428       symbol_user_token_number_set ($1, $2, @2);
 429       symbol_make_alias ($1, $3, @$);
 430     }
 431 ;
 432
 433 /* One or more symbol definitions. */
 434 symbol_defs.1:
 435   symbol_def
 436 | symbol_defs.1 symbol_def
 437 ;
 438
 439
 440         /*------------------------------------------.
 441         | The grammar section: between the two %%.  |
 442         `------------------------------------------*/
 443
 444 grammar:
 445   rules_or_grammar_declaration
 446 | grammar rules_or_grammar_declaration
 447 ;
 448
 449 /* As a Bison extension, one can use the grammar declarations in the
 450    body of the grammar.  */
 451 rules_or_grammar_declaration:
 452   rules
 453 | grammar_declaration ";"
 454 | error ";"
 455     {
 456       yyerrok;
 457     }
 458 ;
 459
 460 rules:
 461   id_colon { current_lhs = $1; current_lhs_location = @1; } rhses.1
 462 ;
 463
 464 rhses.1:
 465   rhs                { grammar_current_rule_end (@1); }
 466 | rhses.1 "|" rhs    { grammar_current_rule_end (@3); }
 467 | rhses.1 ";"
 468 ;
 469
 470 rhs:
 471   /* Nothing.  */
 472     { grammar_current_rule_begin (current_lhs, current_lhs_location); }
 473 | rhs symbol
 474     { grammar_current_rule_symbol_append ($2, @2); }
 475 | rhs "{...}"
 476     { grammar_current_rule_action_append (gram_last_string,
 477                                           gram_last_braced_code_loc); }
 478 | rhs "%prec" symbol
 479     { grammar_current_rule_prec_set ($3, @3); }
 480 | rhs "%dprec" INT
 481     { grammar_current_rule_dprec_set ($3, @3); }
 482 | rhs "%merge" TYPE
 483     { grammar_current_rule_merge_set ($3, @3); }
 484 ;
 485
 486
 487 /*---------------*
 488  | Identifiers.  |
 489  *---------------*/
 490
 491 /* Identifiers are returned as uniqstr values by the scanner.
 492    Depending on their use, we may need to make them genuine symbols.  */
 493
 494 id:
 495   ID
 496     { $$ = symbol_from_uniqstr ($1, @1); }
 497 | CHAR
 498     {
 499       $$ = symbol_get (char_name ($1), @1);
 500       symbol_class_set ($$, token_sym, @1, false);
 501       symbol_user_token_number_set ($$, $1, @1);
 502     }
 503 ;
 504
 505 id_colon:
 506   ID_COLON { $$ = symbol_from_uniqstr ($1, @1); }
 507 ;
 508
 509
 510 symbol:
 511   id
 512 | string_as_id
 513 ;
 514
 515 /* A string used as an ID: quote it.  */
 516 string_as_id:
 517   STRING
 518     {
 519       $$ = symbol_get (quotearg_style (c_quoting_style, $1), @1);
 520       symbol_class_set ($$, token_sym, @1, false);
 521     }
 522 ;
 523
 524 /* A string used for its contents.  Don't quote it.  */
 525 string_content:
 526   STRING
 527     { $$ = $1; }
 528 ;
 529
 530
 531 epilogue.opt:
 532   /* Nothing.  */
 533 | "%%" EPILOGUE
 534     {
 535       muscle_code_grow ("epilogue", translate_code ($2, @2), @2);
 536       gram_scanner_last_string_free ();
 537     }
 538 ;
 539
 540 %%
 541
 542
 543 /* Return the location of the left-hand side of a rule whose
 544    right-hand side is RHS[1] ... RHS[N].  Ignore empty nonterminals in
 545    the right-hand side, and return an empty location equal to the end
 546    boundary of RHS[0] if the right-hand side is empty.  */
 547
 548 static YYLTYPE
 549 lloc_default (YYLTYPE const *rhs, int n)
 550 {
 551   int i;
 552   YYLTYPE loc;
 553
 554   /* SGI MIPSpro 7.4.1m miscompiles "loc.start = loc.end = rhs[n].end;".
 555      The bug is fixed in 7.4.2m, but play it safe for now.  */
 556   loc.start = rhs[n].end;
 557   loc.end = rhs[n].end;
 558
 559   /* Ignore empty nonterminals the start of the the right-hand side.
 560      Do not bother to ignore them at the end of the right-hand side,
 561      since empty nonterminals have the same end as their predecessors.  */
 562   for (i = 1; i <= n; i++)
 563     if (! equal_boundaries (rhs[i].start, rhs[i].end))
 564       {
 565         loc.start = rhs[i].start;
 566         break;
 567       }
 568
 569   return loc;
 570 }
 571
 572
 573 /* Add a lex-param or a parse-param (depending on TYPE) with
 574    declaration DECL and location LOC.  */
 575
 576 static void
 577 add_param (char const *type, char *decl, location loc)
 578 {
 579   static char const alphanum[26 + 26 + 1 + 10] =
 580     "abcdefghijklmnopqrstuvwxyz"
 581     "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 582     "_"
 583     "0123456789";
 584   char const *name_start = NULL;
 585   char *p;
 586
 587   /* Stop on last actual character.  */
 588   for (p = decl; p[1]; p++)
 589     if ((p == decl
 590          || ! memchr (alphanum, p[-1], sizeof alphanum))
 591         && memchr (alphanum, p[0], sizeof alphanum - 10))
 592       name_start = p;
 593
 594   /* Strip the surrounding '{' and '}', and any blanks just inside
 595      the braces.  */
 596   while (*--p == ' ' || *p == '\t')
 597     continue;
 598   p[1] = '\0';
 599   while (*++decl == ' ' || *decl == '\t')
 600     continue;
 601
 602   if (! name_start)
 603     complain_at (loc, _("missing identifier in parameter declaration"));
 604   else
 605     {
 606       char *name;
 607       size_t name_len;
 608
 609       for (name_len = 1;
 610            memchr (alphanum, name_start[name_len], sizeof alphanum);
 611            name_len++)
 612         continue;
 613
 614       name = xmalloc (name_len + 1);
 615       memcpy (name, name_start, name_len);
 616       name[name_len] = '\0';
 617       muscle_pair_list_grow (type, decl, name);
 618       free (name);
 619     }
 620
 621   gram_scanner_last_string_free ();
 622 }
 623
 624 static void
 625 version_check (location const *loc, char const *version)
 626 {
 627   if (strverscmp (version, PACKAGE_VERSION) > 0)
 628     {
 629       complain_at (*loc, "require bison %s, but have %s",
 630                    version, PACKAGE_VERSION);
 631       exit (63);
 632     }
 633 }
 634
 635 static void
 636 gram_error (location const *loc, char const *msg)
 637 {
 638   complain_at (*loc, "%s", msg);
 639 }
 640
 641 char const *
 642 token_name (int type)
 643 {
 644   return yytname[YYTRANSLATE (type)];
 645 }
 646
 647 static char const *
 648 char_name (char c)
 649 {
 650   if (c == '\'')
 651     return "'\\''";
 652   else
 653     {
 654       char buf[4];
 655       buf[0] = '\''; buf[1] = c; buf[2] = '\''; buf[3] = '\0';
 656       return quotearg_style (escape_quoting_style, buf);
 657     }
 658 }