tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2012 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------- ##
  24 ## Basic tests.  ##
  25 ## ------------- ##
  26
  27 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  28 # ------------------------------------------
  29 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  30 # taken in "slurp" mode, i.e., one can match end-of-lines.
  31 m4_define([AT_MATCHES_CHECK],
  32 [AT_CHECK([perl -0777 -ne '
  33 my $count = 0;
  34 s{$2}{ ++$count; "" }gem;
  35 printf "$count\n";' $1], [0], [$3
  36 ])])
  37
  38
  39 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  40 # ------------------------------------------------
  41 # Don't interfere with caller's files.
  42 m4_divert_text([PREPARE_TESTS],
  43 [at_save_special_files ()
  44 {
  45   for at_save_file in stderr experr expout
  46   do
  47     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  48   done
  49 }
  50
  51 at_restore_special_files ()
  52 {
  53   for at_save_file in stderr experr expout
  54   do
  55     test ! -f at-bison-check-$at_save_file.bak ||
  56       mv at-bison-check-$at_save_file.bak $at_save_file
  57   done
  58 }
  59 ])
  60
  61 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  62 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  63
  64
  65
  66 ## ------------------------------- ##
  67 ## Macros decoding Bison options.  ##
  68 ## ------------------------------- ##
  69
  70 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  71 # ----------------------------------------------------------------
  72 # Pushdef AT_LOC_(FIRST|LAST)_(LINE|COLUMN).
  73 m4_define([AT_LOC_PUSHDEF],
  74 [m4_pushdef([AT_LOC_FIRST_LINE],  [AT_LOC.$1])
  75 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.$2])
  76 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.$3])
  77 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.$4])])
  78
  79 # AT_LOC_POPDEF
  80 # -------------
  81 # Popdef AT_LOC_(FIRST|LAST)_(LINE|COL).
  82 m4_define([AT_LOC_POPDEF],
  83 [m4_popdef([AT_LOC_FIRST_LINE])
  84 m4_popdef([AT_LOC_FIRST_COLUMN])
  85 m4_popdef([AT_LOC_LAST_LINE])
  86 m4_popdef([AT_LOC_LAST_COLUMN])])
  87
  88
  89
  90 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  91 # -----------------------------------------
  92 m4_define([AT_BISON_OPTION_PUSHDEFS],
  93 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  94
  95
  96 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  97 # --------------------------------------------------
  98 # This macro works around the impossibility to define macros
  99 # inside macros, because issuing `[$1]' is not possible in M4 :(.
 100 # This sucks hard, GNU M4 should really provide M5 like $$1.
 101 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 102 [m4_if([$1$2], $[1]$[2], [],
 103        [m4_fatal([$0: Invalid arguments: $@])])dnl
 104 m4_pushdef([AT_DEFINES_IF],
 105 [m4_bmatch([$3], [%defines], [$1], [$2])])
 106 m4_pushdef([AT_SKEL_CC_IF],
 107 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 108 m4_pushdef([AT_SKEL_JAVA_IF],
 109 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 110 m4_pushdef([AT_LANG],
 111 [AT_SKEL_JAVA_IF([java],
 112                  [AT_SKEL_CC_IF([c++],
 113                                 [c])])])
 114 m4_pushdef([AT_GLR_IF],
 115 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 116 m4_pushdef([AT_LALR1_CC_IF],
 117 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 118 m4_pushdef([AT_GLR_CC_IF],
 119 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 120 # Using yacc.c?
 121 m4_pushdef([AT_YACC_IF],
 122 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 123 m4_pushdef([AT_LEXPARAM_IF],
 124 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 125 m4_pushdef([AT_LOCATION_IF],
 126 [m4_bmatch([$3], [%locations], [$1], [$2])])
 127 m4_pushdef([AT_LOCATION_TYPE_IF],
 128 [m4_bmatch([$3], [%define location_type], [$1], [$2])])
 129 m4_pushdef([AT_PARAM_IF],
 130 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 131 m4_pushdef([AT_PURE_IF],
 132 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 133            [m4_bmatch([$3], [%define  *api\.pure *"?false"?], [$2], [$1])],
 134            [$2])])
 135 m4_pushdef([AT_PURE_AND_LOC_IF],
 136 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
 137 m4_pushdef([AT_GLR_OR_PARAM_IF],
 138 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
 139 m4_pushdef([AT_NAME_PREFIX],
 140 [m4_bmatch([$3], [%name-prefix ".*"],
 141            [m4_bregexp([$3], [name-prefix "\([^""]*\)"], [\1])],
 142            [yy])])
 143 m4_pushdef([AT_API_PREFIX],
 144 [m4_bmatch([$3], [%define api\.prefix ".*"],
 145            [m4_bregexp([$3], [%define api\.prefix "\([^""]*\)"], [\1])],
 146            [yy])])
 147 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
 148 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 149 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
 150                     [$2])])
 151 # yyerror always sees the locations (when activated), except if
 152 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
 153 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 154 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 155                                         [$1])],
 156                             [$1])],
 157                 [$2])])
 158
 159 # The interface is pure: either because %define api.pure, or because we
 160 # are using the C++ parsers.
 161 m4_pushdef([AT_PURE_LEX_IF],
 162 [AT_PURE_IF([$1],
 163             [AT_SKEL_CC_IF([$1], [$2])])])
 164
 165 AT_PURE_LEX_IF(
 166 [m4_pushdef([AT_LOC], [(*llocp)])
 167  m4_pushdef([AT_VAL], [(*lvalp)])
 168  m4_pushdef([AT_LEX_FORMALS],
 169             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 170  m4_pushdef([AT_LEX_ARGS],
 171             [lvalp[]AT_LOCATION_IF([, llocp])])
 172  m4_pushdef([AT_USE_LEX_ARGS],
 173             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 174  m4_pushdef([AT_LEX_PRE_FORMALS],
 175             [AT_LEX_FORMALS, ])
 176  m4_pushdef([AT_LEX_PRE_ARGS],
 177             [AT_LEX_ARGS, ])
 178 ],
 179 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 180  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 181  m4_pushdef([AT_LEX_FORMALS],     [void])
 182  m4_pushdef([AT_LEX_ARGS],        [])
 183  m4_pushdef([AT_USE_LEX_ARGS],    [])
 184  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 185  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 186 ])
 187
 188 # Handle the different types of location components.
 189
 190 AT_SKEL_CC_IF(
 191   [AT_LOCATION_TYPE_IF(
 192     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 193     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 194   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 195
 196 ])# _AT_BISON_OPTION_PUSHDEFS
 197
 198
 199 # AT_BISON_OPTION_POPDEFS
 200 # -----------------------
 201 m4_define([AT_BISON_OPTION_POPDEFS],
 202 [m4_popdef([AT_LEX_PRE_ARGS])
 203 m4_popdef([AT_LEX_PRE_FORMALS])
 204 m4_popdef([AT_USE_LEX_ARGS])
 205 m4_popdef([AT_LEX_ARGS])
 206 m4_popdef([AT_LEX_FORMALS])
 207 m4_popdef([AT_VAL])
 208 m4_popdef([AT_LOC])
 209 m4_popdef([AT_PURE_LEX_IF])
 210 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 211 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 212 m4_popdef([AT_API_PREFIX])
 213 m4_popdef([AT_NAME_PREFIX])
 214 m4_popdef([AT_GLR_OR_PARAM_IF])
 215 m4_popdef([AT_PURE_AND_LOC_IF])
 216 m4_popdef([AT_LOCATION_TYPE_IF])
 217 m4_popdef([AT_LOCATION_IF])
 218 m4_popdef([AT_PARAM_IF])
 219 m4_popdef([AT_LEXPARAM_IF])
 220 m4_popdef([AT_YACC_IF])
 221 m4_popdef([AT_GLR_IF])
 222 m4_popdef([AT_SKEL_CC_IF])
 223 m4_popdef([AT_LANG])
 224 m4_popdef([AT_SKEL_JAVA_IF])
 225 m4_popdef([AT_GLR_CC_IF])
 226 m4_popdef([AT_LALR1_CC_IF])
 227 m4_popdef([AT_DEFINES_IF])
 228 AT_LOC_POPDEF
 229 ])# AT_BISON_OPTION_POPDEFS
 230
 231
 232
 233 ## -------------------------- ##
 234 ## Generating Grammar Files.  ##
 235 ## -------------------------- ##
 236
 237 # AT_DATA_SOURCE_PROLOGUE
 238 # ------------------------
 239 # The prologue that should be included in any source code that is
 240 # meant to be compiled.
 241 m4_define([AT_DATA_SOURCE_PROLOGUE],
 242 [[#include <config.h>
 243 /* We don't need perfect functions for these tests. */
 244 #undef malloc
 245 #undef memcmp
 246 #undef realloc
 247 ]])
 248
 249 # AT_DATA_GRAMMAR_PROLOGUE
 250 # ------------------------
 251 # The prologue that should be included in any grammar which parser is
 252 # meant to be compiled.
 253 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 254 [[%code top {
 255 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 256 [}
 257 ]])
 258
 259 # AT_DATA_SOURCE(NAME, CONTENT)
 260 # -----------------------------
 261 # Generate the file NAME, which CONTENT is preceded by
 262 # AT_DATA_SOURCE_PROLOGUE.
 263 m4_define([AT_DATA_SOURCE],
 264 [AT_DATA([$1],
 265 [AT_DATA_SOURCE_PROLOGUE
 266 $2])
 267 ])
 268
 269 # AT_DATA_GRAMMAR(NAME, CONTENT)
 270 # ------------------------------
 271 # Generate the file NAME, which CONTENT is preceded by
 272 # AT_DATA_GRAMMAR_PROLOGUE.
 273 m4_define([AT_DATA_GRAMMAR],
 274 [AT_DATA([$1],
 275 [AT_DATA_GRAMMAR_PROLOGUE
 276 $2])
 277 ])
 278
 279 # AT_YYLEX_DECLARE_EXTERN
 280 # AT_YYLEX_DECLARE
 281 # AT_YYLEX_DEFINE(INPUT-STRING, [ACTION])
 282 # ---------------------------------------
 283 m4_define([AT_YYLEX_DECLARE_EXTERN],
 284 [int AT_API_PREFIX[]lex (void);dnl
 285 ])
 286
 287 m4_define([AT_YYLEX_DECLARE],
 288 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 289 ])
 290
 291 m4_define([AT_YYLEX_DEFINE],
 292 [[#include <stdlib.h> /* abort */
 293 static int
 294 ]AT_API_PREFIX[lex (void)
 295 {
 296   static char const input[] = "$1";
 297   static size_t toknum = 0;
 298   int res;
 299   if (! (toknum < sizeof input))
 300     abort ();
 301   res = input[toknum++];
 302   ]$2;[]AT_LOCATION_IF([[
 303   ]AT_API_PREFIX[lloc.first_line = ]AT_API_PREFIX[lloc.last_line = 1;
 304   ]AT_API_PREFIX[lloc.first_column = ]AT_API_PREFIX[lloc.last_column = toknum;]])[
 305   return res;
 306 }]dnl
 307 ])
 308
 309 # AT_YYERROR_DECLARE_EXTERN
 310 # AT_YYERROR_DECLARE
 311 # AT_YYERROR_DEFINE
 312 # -------------------------
 313 # Beware that must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS
 314 # pair.
 315 m4_define([AT_YYERROR_DECLARE_EXTERN],
 316 [m4_case(AT_LANG,
 317 [c], [void AT_API_PREFIX[]error (]AT_YYERROR_ARG_LOC_IF([YYLTYPE *llocp, ])[const char *msg);])[]dnl
 318 ])
 319
 320 m4_define([AT_YYERROR_DECLARE],
 321 [m4_case(AT_LANG,
 322 [c], [static AT_YYERROR_DECLARE_EXTERN])[]dnl
 323 ])
 324
 325 m4_define([AT_YYERROR_DEFINE],
 326 [m4_case(AT_LANG,
 327 [c], [[#include <stdio.h>
 328 /* A C error reporting function.  */
 329 static void
 330 yyerror (]AT_YYERROR_ARG_LOC_IF([YYLTYPE *llocp, ])[const char *msg)
 331 {
 332 ]AT_YYERROR_SEES_LOC_IF([[
 333   fprintf (stderr, "%d.%d",
 334            ]AT_LOC_FIRST_LINE[, ]AT_LOC_FIRST_COLUMN[);
 335   if (]AT_LOC_FIRST_LINE[ != ]AT_LOC_LAST_LINE[)
 336     fprintf (stderr, "-%d.%d",
 337              ]AT_LOC_LAST_LINE[,  ]AT_LOC_LAST_COLUMN[ - 1);
 338   else if (]AT_LOC_FIRST_COLUMN[ != ]AT_LOC_LAST_COLUMN[ - 1)
 339     fprintf (stderr, "-%d",
 340              ]AT_LOC_LAST_COLUMN[ - 1);
 341   fprintf (stderr, ": ");]])[
 342   fprintf (stderr, "%s\n", msg);
 343 }]],
 344 [c++], [[/* A C++ error reporting function.  */
 345 void
 346 ]AT_NAME_PREFIX[::parser::error (const location_type& l, const std::string& m)
 347 {
 348   (void) l;
 349   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << std::endl;
 350 }]],
 351 [java], [[public void yyerror (String msg)
 352 {
 353   System.err.println (msg);
 354 }]])])
 355
 356
 357 ## --------------- ##
 358 ## Running Bison.  ##
 359 ## --------------- ##
 360
 361 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 362 # -------------------------------------------------
 363 # Check Bison by invoking `bison BISON_ARGS'.  BISON_ARGS should not contain
 364 # shell constructs (such as redirection or pipes) that would prevent
 365 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 366 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 367 #
 368 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 369 # Bison in the test suite.  For now it ensures that:
 370 #
 371 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 372 #      a non-zero exit status since Bison doesn't always try to free all memory
 373 #      in that case.
 374 #
 375 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 376 #      --graph and --report=all output for every working grammar.
 377 #
 378 #   3. If stderr contains a warning, -Werror and --warnings=error
 379 #      convert the warning to an error.
 380 #
 381 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 382 m4_define([AT_BISON_CHECK],
 383 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 384        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 385 AT_BISON_CHECK_NO_XML($@)])
 386
 387 m4_define([AT_BISON_WERROR_MSG],
 388           [[bison: warnings being treated as errors]])
 389
 390 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 391 # --------------------------------------------------------
 392 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 393 # when a tortured grammar's XML is known to be too large for xsltproc to
 394 # handle.
 395 m4_define([AT_BISON_CHECK_NO_XML],
 396 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 397                 [AT_QUELL_VALGRIND ])[[bison ]]$@)
 398 m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 399       m4_quote(m4_if(m4_quote($2), [], [0], [$2])), [0], [[
 400         # Defining POSIXLY_CORRECT causes bison to complain if options
 401         # are added after the grammar file name, so skip these checks
 402         # in that case.
 403         if test -z "${POSIXLY_CORRECT+set}"; then
 404           ]AT_SAVE_SPECIAL_FILES[
 405
 406           # To avoid expanding it repeatedly, store specified stdout.
 407           ]AT_DATA([expout], [$3])[
 408
 409           # Run with -Werror.
 410           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Werror]],
 411                     [[1]], [expout], [stderr])[
 412
 413           # Build expected stderr up to and including the "warnings being
 414           # treated as errors" message.
 415           ]AT_DATA([[at-bison-check-warnings]], [$4])[
 416           at_bison_check_first=`sed -n \
 417             '/: warning: /{=;q;}' at-bison-check-warnings`
 418           : ${at_bison_check_first:=1}
 419           at_bison_check_first_tmp=`sed -n \
 420             '/conflicts: [0-9].*reduce$/{=;q;}' at-bison-check-warnings`
 421           : ${at_bison_check_first_tmp:=1}
 422           if test $at_bison_check_first_tmp -lt $at_bison_check_first; then
 423             at_bison_check_first=$at_bison_check_first_tmp
 424           fi
 425           if test $at_bison_check_first -gt 1; then
 426             sed -n "1,`expr $at_bison_check_first - 1`"p \
 427               at-bison-check-warnings > experr
 428           fi
 429           echo ']AT_BISON_WERROR_MSG[' >> experr
 430
 431           # Finish building expected stderr and check.  Unlike warnings,
 432           # complaints cause bison to exit early.  Thus, with -Werror, bison
 433           # does not necessarily report all warnings that it does without
 434           # -Werror, but it at least reports one.
 435           at_bison_check_last=`sed -n '$=' stderr`
 436           : ${at_bison_check_last:=1}
 437           at_bison_check_last=`expr $at_bison_check_last - 1`
 438           sed -n "$at_bison_check_first,$at_bison_check_last"p \
 439             at-bison-check-warnings >> experr
 440           ]AT_CHECK([[sed 's,.*/\(]AT_BISON_WERROR_MSG[\)$,\1,' \
 441                       stderr 1>&2]], [[0]], [[]], [experr])[
 442
 443           # Now check --warnings=error.
 444           cp stderr experr
 445           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=error]],
 446                     [[1]], [expout], [experr])[
 447
 448           # Now check -Wnone and --warnings=none by making sure that
 449           # -Werror doesn't change the exit status when -Wnone or
 450           # --warnings=none is specified.
 451           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ -Wnone -Werror]],
 452                     [[0]], [expout])[
 453           ]AT_CHECK(AT_QUELL_VALGRIND[[ bison ]$1[ --warnings=none \
 454                     -Werror]], [[0]], [expout])[
 455
 456           ]AT_RESTORE_SPECIAL_FILES[
 457         fi
 458       ]])
 459 ])
 460
 461 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 462 # -----------------------------------------------------
 463 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 464 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 465 # have a non-zero exit status.
 466 m4_define([AT_BISON_CHECK_XML],
 467 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 468   AT_SAVE_SPECIAL_FILES
 469   [mkdir xml-tests]
 470   m4_pushdef([AT_BISON_ARGS],
 471              [m4_bpatsubsts([[$1]],
 472                             [--report(-file)?=[^][ ]*], [],
 473                             [--graph=[^][ ]*], [],
 474                             [--xml=[^][ ]*], [])])dnl
 475   # Don't combine these Bison invocations since we want to be sure that
 476   # --report=all isn't required to get the full XML file.
 477   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 478              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 479            [[0]], [ignore], [ignore])
 480   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 481            [[0]], [ignore], [ignore])
 482   m4_popdef([AT_BISON_ARGS])dnl
 483   [cp xml-tests/test.output expout]
 484   AT_CHECK([[$XSLTPROC \
 485              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 486              xml-tests/test.xml]], [[0]], [expout])
 487   [cp xml-tests/test.dot expout]
 488   AT_CHECK([[$XSLTPROC \
 489              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 490              xml-tests/test.xml]], [[0]], [expout])
 491   [rm -rf xml-tests expout]
 492   AT_RESTORE_SPECIAL_FILES
 493 [fi]])
 494
 495 # AT_QUELL_VALGRIND
 496 # -----------------
 497 # Put this before a Bison invocation to keep Valgrind from complaining about
 498 # reachable memory.
 499 #
 500 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 501 # The triple quoting below will cause test cases to fail if you do.  If you do
 502 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 503 # will then fail to shell-escape its contents when attempting to print them.
 504 # The testsuite verbose output, at least, will be incorrect, but nothing may
 505 # fail to make sure you notice.
 506 m4_define([AT_QUELL_VALGRIND],
 507 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 508
 509 ## ------------------------ ##
 510 ## Compiling C, C++ Files.  ##
 511 ## ------------------------ ##
 512
 513
 514 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 515 # ----------------------------------------
 516 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 517 # assume that we are linking too; this is a hack.
 518 m4_define([AT_COMPILE],
 519 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 520            0, [ignore], [ignore])])
 521
 522 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 523 # --------------------------------------------
 524 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 525 # assume that we are linking too; this is a hack.
 526 # If the C++ compiler does not work, ignore the test.
 527 m4_define([AT_COMPILE_CXX],
 528 [AT_KEYWORDS(c++)
 529 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 530 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 531          0, [ignore], [ignore])])
 532
 533 # AT_JAVA_COMPILE(SOURCES)
 534 # ------------------------
 535 # Compile SOURCES into Java class files.  Skip the test if java or javac
 536 # is not installed.
 537 m4_define([AT_JAVA_COMPILE],
 538 [AT_KEYWORDS(java)
 539 AT_SKIP_IF([[test -z "$CONF_JAVA$CONF_JAVAC"]])
 540 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 541          [[0]], [ignore], [ignore])])
 542
 543 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c]
 544 # --------------------------------------------
 545 m4_define([AT_LANG_COMPILE],
 546 [m4_case(AT_LANG,
 547 [c],    [AT_COMPILE([$1], [$2])],
 548 [c++],  [AT_COMPILE_CXX([$1], [$2])],
 549 [java], [AT_JAVA_COMPILE([$1.java], [$2])],
 550         [m4_fatal([unknown language: ]m4_defn([AT_LANG]))])[]dnl
 551 ])
 552
 553 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2])
 554 # -------------------------------------------
 555 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 556 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 557 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 558 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 559 # AT_SKEL_JAVA_IF.
 560 m4_define([AT_FULL_COMPILE],
 561 [m4_case(AT_LANG,
 562 [java],
 563   [AT_BISON_CHECK([-o $1.java $1.y])
 564    AT_LANG_COMPILE([$1],
 565                    m4_join([ ],
 566                            [$1.java],
 567                            m4_ifval($2, [[$1-$2.java]]),
 568                            m4_ifval($3, [[$1-$3.java]])))],
 569 [c++],
 570   [AT_BISON_CHECK([-o $1.cc $1.y])
 571    AT_LANG_COMPILE([$1],
 572                    m4_join([ ],
 573                            [$1.cc],
 574                            m4_ifval($2, [[$1-$2.cc]]),
 575                            m4_ifval($3, [[$1-$3.cc]])))],
 576 [c],
 577   [AT_BISON_CHECK([-o $1.c $1.y])
 578    AT_LANG_COMPILE([$1],
 579                    m4_join([ ],
 580                            [$1.c],
 581                            m4_ifval($2, [[$1-$2.c]]),
 582                            m4_ifval($3, [[$1-$3.c]])))])
 583 ])
 584
 585
 586 ## ---------------------------- ##
 587 ## Running a generated parser.  ##
 588 ## ---------------------------- ##
 589
 590
 591 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 592 # ------------------------------------------------------------
 593 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 594 #
 595 # Get rid of spurious messages when compiled with --coverage:
 596 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 597 m4_define([AT_PARSER_CHECK],
 598 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 599 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 600          [0], [], [$4])
 601 ])
 602
 603
 604 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 605 # -----------------------------------------------------------------
 606 m4_define([AT_JAVA_PARSER_CHECK],
 607 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 608
 609
 610 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 611 #                          DECLS, GRAMMAR, INPUT,
 612 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 613 #                          [OTHER-CHECKS],
 614 #                          [PARSER-EXIT-VALUE],
 615 #                          [PARSER-STDOUT], [PARSER-STDERR])
 616 # -------------------------------------------------------------
 617 # Using TITLE as the test group title, check the generated parser tables
 618 # and parser for a specified grammar file under a condition labeled by
 619 # COND-VALUE.
 620 #
 621 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 622 # recognized attribute is described below where it is relevant.
 623 #
 624 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 625 # the grammar file.  Insert basic yyerror, yylex, and main function
 626 # definitions as well.  Hardcode yylex to return the (possibly empty)
 627 # comma-delimited series of tokens in INPUT followed by token 0.
 628 #
 629 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 630 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 631 # On the bison command-line, specify `--report=all --defines'.  Check
 632 # that Bison exits with value 0, has no stdout, and has stderr
 633 # BISON-STDERR.
 634 #
 635 # If TEST-SPEC contains the attribute `last-state', check that the value
 636 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 637 # the grammar; in other words, check the number of states (minus one).
 638 # Otherwise, check that everything in the `.output' file starting with
 639 # the definition of state 0 is the same as the entire value of
 640 # TABLES-OR-LAST-STATE.
 641 #
 642 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 643 # `.output' file, which is named `input.output', and/or grammar file,
 644 # which is named `input.y'.
 645 #
 646 # Finally, compile the generated parser and then run it using
 647 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 648 # PARSER-STDERR as the 2nd-4th arguments.
 649 #
 650 # As a precondition, you must properly double-quote all arguments that
 651 # are to be interpreted as strings.
 652 #
 653 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
 654 # invokes m4_case with its own arguments but COND-VALUE inserted as the
 655 # first argument.  This is useful, for example, when wrapping multiple
 656 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
 657 # condition, in another macro.
 658 #
 659 # For example:
 660 #
 661 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
 662 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
 663 #   # ---------------------------------------------------------------------
 664 #   m4_define([AT_TEST_SYNTAX_ERROR],
 665 #   [
 666 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
 667 #                              [[last-state]],
 668 #                              [[%error-verbose ]$2], [$3], [$4],
 669 #                              [[]], [$5], [], [$6], [$7], [$8])
 670 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
 671 #                              [[last-state]],
 672 #                              [$2], [$3], [$4],
 673 #                              [[]], [$5], [], [$6], [$7], [$8])
 674 #   ])
 675 #
 676 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
 677 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
 678 #                        [[3]],
 679 #                        [[1]], [[]],
 680 #                        [AT_COND_CASE([[no verbose]],
 681 #                                      [[syntax error
 682 #   ]],
 683 #                                      [[syntax error, unexpected 'b', expecting $end
 684 #   ]])])
 685 m4_define([AT_TEST_TABLES_AND_PARSE],
 686 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
 687
 688 AT_SETUP([$1])
 689 AT_BISON_OPTION_PUSHDEFS([$4])
 690 AT_DATA_GRAMMAR([[input.y]],
 691 [[%code {
 692   #include <stdio.h>
 693   ]AT_YYERROR_DECLARE[
 694   ]AT_YYLEX_DECLARE[
 695 }
 696
 697 ]$4[
 698
 699 %%
 700
 701 ]$5[
 702
 703 %%
 704 ]AT_YYERROR_DEFINE[
 705 static int
 706 yylex (void)
 707 {
 708   static int const input[] = {
 709     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
 710   };
 711   static int const *inputp = input;
 712   return *inputp++;
 713 }
 714
 715 int
 716 main (void)
 717 {
 718   return yyparse ();
 719 }
 720 ]])
 721
 722 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
 723 # expanding macros, so it corrupts some special characters in the
 724 # macros.  To avoid this, expand now and pass it the result with proper
 725 # string quotation.  Assume args 7 through 12 expand to properly quoted
 726 # strings.
 727
 728 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
 729       [AT_BISON_CHECK],
 730       [AT_BISON_CHECK_NO_XML])([[--report=all --defines -o input.c input.y]],
 731                                [0], [], m4_dquote($7))
 732
 733 m4_if(m4_index(m4_quote($3), [last-state]), -1,
 734       [AT_CHECK([[sed -n '/^state 0$/,$p' input.output]], [[0]],
 735                 m4_dquote($8))],
 736       [AT_CHECK([[sed -n 's/^state //p' input.output | tail -1]], [[0]],
 737                 m4_dquote($8)[[
 738 ]])])
 739
 740 $9
 741
 742 # Canonical LR generates very large tables, resulting in very long
 743 # files with #line directives that may overflow what the standards
 744 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
 745 # will issue an error.
 746 #
 747 # There is no "" around `wc` since some indent the result.
 748 m4_bmatch([$4], [%define lr.type canonical-lr],
 749 [if test 32767 -lt `wc -l < input.c`; then
 750   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic //'`
 751   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic //'`
 752 fi])
 753 AT_COMPILE([[input]])
 754
 755 AT_PARSER_CHECK([[./input]],
 756                 m4_ifval([$10], [m4_dquote($10)]),
 757                 m4_ifval([$11], [m4_dquote($11)]),
 758                 m4_ifval([$12], [m4_dquote($12)]))
 759
 760 AT_BISON_OPTION_POPDEFS
 761 AT_CLEANUP
 762
 763 m4_popdef([AT_COND_CASE])])
 764
 765
 766
 767 ## ----------------------- ##
 768 ## Launch the test suite.  ##
 769 ## ----------------------- ##
 770
 771 AT_INIT
 772
 773 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
 774 # options are processed, so we don't know the value of CXX and
 775 # CXXFLAGS yet.
 776 #
 777 # Note that it also means that command line values for CXX and
 778 # CXXFLAGS will not be propagated to CC and CFLAGS.
 779 AT_ARG_OPTION([compile-c-with-cxx],
 780               [compile C parsers with the C++ compiler])
 781
 782 AT_COLOR_TESTS
 783
 784 AT_TESTED([bison])