src/scan-skel.l

   1 /* Scan Bison Skeletons.                                       -*- C -*-
   2
   3    Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006 Free Software
   4    Foundation, Inc.
   5
   6    This file is part of Bison, the GNU Compiler Compiler.
   7
   8    Bison is free software; you can redistribute it and/or modify it
   9    under the terms of the GNU General Public License as published by
  10    the Free Software Foundation; either version 2, or (at your option)
  11    any later version.
  12
  13    Bison is distributed in the hope that it will be useful, but
  14    WITHOUT ANY WARRANTY; without even the implied warranty of
  15    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16    General Public License for more details.
  17
  18    You should have received a copy of the GNU General Public License
  19    along with Bison; see the file COPYING.  If not, write to the Free
  20    Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21    02110-1301, USA.  */
  22
  23 %option nodefault noyywrap nounput never-interactive debug
  24 %option prefix="skel_" outfile="lex.yy.c"
  25
  26 %{
  27 /* Work around a bug in flex 2.5.31.  See Debian bug 333231
  28    <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=333231>.  */
  29 #undef skel_wrap
  30 #define skel_wrap() 1
  31
  32 #define FLEX_NO_OBSTACK
  33 #define FLEX_PREFIX(Id) skel_ ## Id
  34 #include "flex-scanner.h"
  35
  36 #include <dirname.h>
  37 #include <error.h>
  38 #include <quotearg.h>
  39
  40 #include "complain.h"
  41 #include "getargs.h"
  42 #include "files.h"
  43 #include "scan-skel.h"
  44
  45 int skel_lex (void);
  46
  47 #define QPUTS(String) \
  48    fputs (quotearg_style (c_quoting_style, String), yyout)
  49
  50 #define BASE_QPUTS(File) \
  51    QPUTS (last_component (File))
  52
  53 %}
  54 %%
  55
  56 %{
  57   int lineno IF_LINT (= 0);
  58   char *outname = NULL;
  59 %}
  60
  61 "@output ".*\n {
  62   char const *file_name = yytext + sizeof "@output " - 1;
  63   yytext[yyleng - 1] = '\0';
  64
  65   /* Decode special file names.  They include the directory part,
  66      contrary to their "free" occurrences, used for issuing #includes,
  67      which must not include the directory part.  */
  68
  69   if (*file_name == '@')
  70     {
  71       if (strcmp (file_name, "@output_header_name@") == 0)
  72         file_name = spec_defines_file;
  73       else if (strcmp (file_name, "@output_parser_name@") == 0)
  74         file_name = parser_file_name;
  75       else
  76         fatal ("invalid token in skeleton: %s", yytext);
  77     }
  78   if (outname)
  79     {
  80       free (outname);
  81       xfclose (yyout);
  82     }
  83   outname = xstrdup (file_name);
  84   output_file_name_check (file_name);
  85   yyout = xfopen (outname, "w");
  86   lineno = 1;
  87 }
  88
  89 "@@"       fputc ('@', yyout);
  90 "@{"       fputc ('[', yyout);
  91 "@}"       fputc (']', yyout);
  92
  93 "@oline@"  fprintf (yyout, "%d", lineno + 1);
  94 "@ofile@"  QPUTS (outname);
  95 "@dir_prefix@" QPUTS (dir_prefix);
  96 "@output_parser_name@"  BASE_QPUTS (parser_file_name);
  97 "@output_header_name@"  BASE_QPUTS (spec_defines_file);
  98
  99   /* This pattern must not match more than the previous @ patterns. */
 100 @[^{}@\n]* fatal ("invalid @ in skeleton: %s", yytext);
 101 \n         lineno++; ECHO;
 102 [^@\n]+    ECHO;
 103
 104 <<EOF>> {
 105   if (outname)
 106     {
 107       free (outname);
 108       xfclose (yyout);
 109     }
 110   return EOF;
 111 }
 112 %%
 113
 114 /*------------------------.
 115 | Scan a Bison skeleton.  |
 116 `------------------------*/
 117
 118 void
 119 scan_skel (FILE *in)
 120 {
 121   skel_in = in;
 122   skel__flex_debug = trace_flag & trace_skeleton;
 123   skel_lex ();
 124   /* Reclaim Flex's buffers.  */
 125   yylex_destroy ();
 126 }