data/c++.m4

   1                                                             -*- Autoconf -*-
   2
   3 # C++ skeleton for Bison
   4
   5 # Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation,
   6 # Inc.
   7
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 m4_include(b4_pkgdatadir/[c.m4])
  22
  23 ## ---------------- ##
  24 ## Default values.  ##
  25 ## ---------------- ##
  26
  27 # Default parser class name.
  28 b4_percent_define_default([[parser_class_name]], [[parser]])
  29 b4_percent_define_default([[location_type]], [[location]])
  30 b4_percent_define_default([[filename_type]], [[std::string]])
  31 b4_percent_define_default([[namespace]], m4_defn([b4_prefix]))
  32 b4_percent_define_default([[global_tokens_and_yystype]], [[false]])
  33 b4_percent_define_default([[define_location_comparison]],
  34                           [m4_if(b4_percent_define_get([[filename_type]]),
  35                                  [std::string], [[true]], [[false]])])
  36
  37
  38 # b4_token_enums(LIST-OF-PAIRS-TOKEN-NAME-TOKEN-NUMBER)
  39 # -----------------------------------------------------
  40 # Output the definition of the tokens as enums.
  41 m4_define([b4_token_enums],
  42 [/* Tokens.  */
  43    enum yytokentype {
  44 m4_map_sep([     b4_token_enum], [,
  45 ],
  46            [$@])
  47    };
  48 ])
  49
  50
  51 ## ----------------- ##
  52 ## Semantic Values.  ##
  53 ## ----------------- ##
  54
  55
  56 # b4_lhs_value([TYPE])
  57 # --------------------
  58 # Expansion of $<TYPE>$.
  59 m4_define([b4_lhs_value],
  60 [(yyval[]m4_ifval([$1], [.$1]))])
  61
  62
  63 # b4_rhs_value(RULE-LENGTH, NUM, [TYPE])
  64 # --------------------------------------
  65 # Expansion of $<TYPE>NUM, where the current rule has RULE-LENGTH
  66 # symbols on RHS.
  67 m4_define([b4_rhs_value],
  68 [(yysemantic_stack_@{($1) - ($2)@}m4_ifval([$3], [.$3]))])
  69
  70 # b4_lhs_location()
  71 # -----------------
  72 # Expansion of @$.
  73 m4_define([b4_lhs_location],
  74 [(yyloc)])
  75
  76
  77 # b4_rhs_location(RULE-LENGTH, NUM)
  78 # ---------------------------------
  79 # Expansion of @NUM, where the current rule has RULE-LENGTH symbols
  80 # on RHS.
  81 m4_define([b4_rhs_location],
  82 [(yylocation_stack_@{($1) - ($2)@})])
  83
  84
  85 # b4_parse_param_decl
  86 # -------------------
  87 # Extra formal arguments of the constructor.
  88 # Change the parameter names from "foo" into "foo_yyarg", so that
  89 # there is no collision bw the user chosen attribute name, and the
  90 # argument name in the constructor.
  91 m4_define([b4_parse_param_decl],
  92 [m4_ifset([b4_parse_param],
  93           [m4_map_sep([b4_parse_param_decl_1], [, ], [b4_parse_param])])])
  94
  95 m4_define([b4_parse_param_decl_1],
  96 [$1_yyarg])
  97
  98
  99
 100 # b4_parse_param_cons
 101 # -------------------
 102 # Extra initialisations of the constructor.
 103 m4_define([b4_parse_param_cons],
 104           [m4_ifset([b4_parse_param],
 105                     [
 106       b4_cc_constructor_calls(b4_parse_param)])])
 107 m4_define([b4_cc_constructor_calls],
 108           [m4_map_sep([b4_cc_constructor_call], [,
 109       ], [$@])])
 110 m4_define([b4_cc_constructor_call],
 111           [$2 ($2_yyarg)])
 112
 113 # b4_parse_param_vars
 114 # -------------------
 115 # Extra instance variables.
 116 m4_define([b4_parse_param_vars],
 117           [m4_ifset([b4_parse_param],
 118                     [
 119     /* User arguments.  */
 120 b4_cc_var_decls(b4_parse_param)])])
 121 m4_define([b4_cc_var_decls],
 122           [m4_map_sep([b4_cc_var_decl], [
 123 ], [$@])])
 124 m4_define([b4_cc_var_decl],
 125           [    $1;])