src/parse-gram.y

   1 /* Bison Grammar Parser                             -*- C -*-
   2    Copyright (C) 2002 Free Software Foundation, Inc.
   3
   4    This file is part of Bison, the GNU Compiler Compiler.
   5
   6    This program is free software; you can redistribute it and/or modify
   7    it under the terms of the GNU General Public License as published by
   8    the Free Software Foundation; either version 2 of the License, or
   9    (at your option) any later version.
  10
  11    This program is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14    GNU General Public License for more details.
  15
  16    You should have received a copy of the GNU General Public License
  17    along with this program; if not, write to the Free Software
  18    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307  USA
  20 */
  21
  22
  23 %debug
  24 %defines
  25 %locations
  26 %pure-parser
  27 // %error-verbose
  28 %defines
  29 %name-prefix="gram_"
  30
  31 %{
  32 #include "system.h"
  33 #include "muscle_tab.h"
  34 #include "files.h"
  35 #include "getargs.h"
  36 #include "output.h"
  37 #include "gram.h"
  38 #include "reader.h"
  39 #include "conflicts.h"
  40
  41 /* Produce verbose parse errors.  */
  42 #define YYERROR_VERBOSE 1
  43 #define YYLLOC_DEFAULT(Current, Rhs, N)                 \
  44 do {                                                    \
  45   if (N)                                                \
  46   {                                                     \
  47     Current.first_column  = Rhs[1].first_column;        \
  48     Current.first_line    = Rhs[1].first_line;          \
  49     Current.last_column   = Rhs[N].last_column;         \
  50     Current.last_line     = Rhs[N].last_line;           \
  51   }                                                     \
  52   else                                                  \
  53   {                                                     \
  54     Current = Rhs[0];                                   \
  55   }                                                     \
  56 } while (0)
  57
  58 /* Pass the control structure to YYPARSE and YYLEX. */
  59 #define YYPARSE_PARAM gram_control
  60 #define YYLEX_PARAM gram_control
  61 /* YYPARSE receives GRAM_CONTROL as a void *.  Provide a
  62    correctly typed access to it.  */
  63 #define yycontrol ((gram_control_t *) gram_control)
  64
  65 /* Request detailed parse error messages, and pass them to
  66    GRAM_ERROR. */
  67 #undef  yyerror
  68 #define yyerror(Msg) \
  69         gram_error (yycontrol, &yylloc, Msg)
  70
  71 /* When debugging our pure parser, we want to see values and locations
  72    of the tokens.  */
  73 #define YYPRINT(File, Type, Value) \
  74         yyprint (File, &yylloc, Type, &Value)
  75 static void yyprint (FILE *file, const location_t *loc,
  76                      int type, const yystype *value);
  77
  78 symbol_class current_class = unknown_sym;
  79 char *current_type = 0;
  80 symbol_t *current_lhs;
  81 location_t current_lhs_location;
  82 associativity current_assoc;
  83 int current_prec = 0;
  84 %}
  85
  86
  87 /* Only NUMBERS have a value.  */
  88 %union
  89 {
  90   symbol_t *symbol;
  91   int integer;
  92   char *string;
  93   associativity assoc;
  94 };
  95
  96 /* Define the tokens together with there human representation. */
  97 %token GRAM_EOF 0 "end of string"
  98 %token STRING CHARACTER
  99 %token INT
 100
 101 %token PERCENT_TOKEN "%token"
 102 %token PERCENT_NTERM "%nterm"
 103 %token PERCENT_TYPE  "%type"
 104 %token PERCENT_UNION "%union"
 105 %token PERCENT_LEFT     "%left"
 106 %token PERCENT_RIGHT    "%right"
 107 %token PERCENT_NONASSOC "%nonassoc"
 108
 109 %token PERCENT_EXPECT "%expect"
 110 %token PERCENT_START "%start"
 111 %token PERCENT_PREC     "%prec"
 112 %token PERCENT_VERBOSE  "%verbose"
 113 %token PERCENT_ERROR_VERBOSE "%error-verbose"
 114
 115 %token PERCENT_OUTPUT "%output"
 116 %token PERCENT_FILE_PREFIX "%file-prefix"
 117 %token PERCENT_NAME_PREFIX "%name-prefix"
 118
 119 %token PERCENT_DEFINE "%define"
 120 %token PERCENT_PURE_PARSER "%pure-parser"
 121
 122 %token PERCENT_DEFINES "%defines"
 123
 124 %token PERCENT_YACC "%yacc"
 125
 126 %token PERCENT_DEBUG "%debug"
 127 %token PERCENT_LOCATIONS "%locations"
 128 %token PERCENT_NO_LINES "%no-lines"
 129 %token PERCENT_SKELETON "%skeleton"
 130 %token PERCENT_TOKEN_TABLE "%token-table"
 131
 132 %token TYPE
 133 %token EQUAL "="
 134 %token SEMICOLON ";"
 135 %token COLON ":"
 136 %token PIPE "|"
 137 %token ID "identifier"
 138 %token PERCENT_PERCENT "%%"
 139 %token PROLOGUE EPILOGUE
 140 %token BRACED_CODE
 141
 142 %type <string> CHARACTER TYPE STRING string_content
 143                BRACED_CODE PROLOGUE EPILOGUE epilogue.opt action
 144 %type <integer> INT
 145 %type <symbol> ID symbol string_as_id
 146 %type <assoc> precedence_declarator
 147
 148 %%
 149
 150 input:
 151   declarations "%%" grammar epilogue.opt
 152     {
 153       yycontrol->errcode = 0;
 154       epilogue_set ($4, @4);
 155     }
 156 ;
 157
 158
 159         /*------------------------------------.
 160         | Declarations: before the first %%.  |
 161         `------------------------------------*/
 162
 163 declarations:
 164   /* Nothing */
 165 | declarations declaration semi_colon.opt
 166 ;
 167
 168 declaration:
 169   grammar_declaration
 170 | PROLOGUE                                 { prologue_augment ($1, @1); }
 171 | "%debug"                                 { debug_flag = 1; }
 172 | "%define" string_content string_content  { muscle_insert ($2, $3); }
 173 | "%defines"                               { defines_flag = 1; }
 174 | "%error-verbose"                         { error_verbose = 1; }
 175 | "%expect" INT                            { expected_conflicts = $2; }
 176 | "%file-prefix" "=" string_content        { spec_file_prefix = $3; }
 177 | "%locations"                             { locations_flag = 1; }
 178 | "%name-prefix" "=" string_content        { spec_name_prefix = $3; }
 179 | "%no-lines"                              { no_lines_flag = 1; }
 180 | "%output" "=" string_content             { spec_outfile = $3; }
 181 | "%pure-parser"                           { pure_parser = 1; }
 182 | "%skeleton" string_content               { skeleton = $2; }
 183 | "%token-table"                           { token_table_flag = 1; }
 184 | "%verbose"                               { report_flag = 1; }
 185 | "%yacc"                                  { yacc_flag = 1; }
 186 ;
 187
 188 grammar_declaration:
 189   precedence_declaration
 190 | symbol_declaration
 191 | "%start" symbol
 192     {
 193       grammar_start_symbol_set ($2, @2);
 194     }
 195 | "%union" BRACED_CODE
 196     {
 197       typed = 1;
 198       MUSCLE_INSERT_INT ("stype_line", @2.first_line);
 199       muscle_insert ("stype", $2);
 200     }
 201 ;
 202
 203 symbol_declaration:
 204   "%nterm" { current_class = nterm_sym; } symbol_defs.1
 205     {
 206       current_class = unknown_sym;
 207       current_type = NULL;
 208     }
 209 | "%token" { current_class = token_sym; } symbol_defs.1
 210     {
 211       current_class = unknown_sym;
 212       current_type = NULL;
 213     }
 214 | "%type" TYPE {current_type = $2; } nterms_to_type.1
 215     {
 216       current_type = NULL;
 217     }
 218 ;
 219
 220 precedence_declaration:
 221   precedence_declarator type.opt
 222     { current_assoc = $1; ++current_prec; }
 223   terms_to_prec.1
 224     { current_assoc = non_assoc; current_type = NULL; }
 225 ;
 226
 227 precedence_declarator:
 228   "%left"     { $$ = left_assoc; }
 229 | "%right"    { $$ = right_assoc; }
 230 | "%nonassoc" { $$ = non_assoc; }
 231 ;
 232
 233 type.opt:
 234   /* Nothing. */ { current_type = NULL;}
 235 | TYPE           { current_type = $1; }
 236 ;
 237
 238 /* One or more nonterminals to be %typed. */
 239 nterms_to_type.1:
 240   ID                   { symbol_type_set ($1, current_type); }
 241 | nterms_to_type.1 ID  { symbol_type_set ($2, current_type); }
 242 ;
 243
 244 /* One or more symbols to be given a precedence/associativity.  */
 245 terms_to_prec.1:
 246   symbol
 247     {
 248       symbol_type_set ($1, current_type);
 249       symbol_precedence_set ($1, current_prec, current_assoc);
 250     }
 251 | terms_to_prec.1 symbol
 252     {
 253       symbol_type_set ($2, current_type);
 254       symbol_precedence_set ($2, current_prec, current_assoc);
 255     }
 256 ;
 257
 258 /* One token definition.  */
 259 symbol_def:
 260   TYPE
 261      {
 262        current_type = $1;
 263      }
 264 | ID
 265      {
 266        symbol_class_set ($1, current_class);
 267        symbol_type_set ($1, current_type);
 268      }
 269 | ID INT
 270     {
 271       symbol_class_set ($1, current_class);
 272       symbol_type_set ($1, current_type);
 273       symbol_user_token_number_set ($1, $2);
 274     }
 275 | ID string_as_id
 276     {
 277       symbol_class_set ($1, current_class);
 278       symbol_type_set ($1, current_type);
 279       symbol_make_alias ($1, $2);
 280     }
 281 | ID INT string_as_id
 282     {
 283       symbol_class_set ($1, current_class);
 284       symbol_type_set ($1, current_type);
 285       symbol_user_token_number_set ($1, $2);
 286       symbol_make_alias ($1, $3);
 287     }
 288 ;
 289
 290 /* One or more symbol definitions. */
 291 symbol_defs.1:
 292   symbol_def
 293     {;}
 294 | symbol_defs.1 symbol_def
 295     {;}
 296 ;
 297
 298
 299         /*------------------------------------------.
 300         | The grammar section: between the two %%.  |
 301         `------------------------------------------*/
 302
 303 grammar:
 304   rules_or_grammar_declaration
 305 | grammar rules_or_grammar_declaration
 306 ;
 307
 308 /* As a Bison extension, one can use the grammar declarations in the
 309    body of the grammar.  But to remain LALR(1), they must be ended
 310    with a semi-colon.  */
 311 rules_or_grammar_declaration:
 312   rules
 313 | grammar_declaration ";"
 314 ;
 315
 316 rules:
 317   ID ":" { current_lhs = $1; current_lhs_location = @1; } rhses.1 ";"
 318     {;}
 319 ;
 320
 321 rhses.1:
 322   rhs                { grammar_rule_end (@1); }
 323 | rhses.1 "|" rhs    { grammar_rule_end (@3); }
 324 ;
 325
 326 rhs:
 327   /* Nothing.  */
 328     { grammar_rule_begin (current_lhs, current_lhs_location); }
 329 | rhs symbol
 330     { grammar_current_rule_symbol_append ($2, @2); }
 331 | rhs action
 332     { grammar_current_rule_action_append ($2, @2); }
 333 | rhs "%prec" symbol
 334     { grammar_current_rule_prec_set ($3); }
 335 ;
 336
 337 symbol:
 338   ID              { $$ = $1; }
 339 | string_as_id    { $$ = $1; }
 340 | CHARACTER       { $$ = getsym ($1, @1); }
 341 ;
 342
 343 action:
 344   BRACED_CODE
 345    { $$ = $1; }
 346 ;
 347
 348 /* A string used as an ID: we have to keep the quotes. */
 349 string_as_id:
 350   STRING
 351     {
 352       $$ = getsym ($1, @1);
 353       symbol_class_set ($$, token_sym);
 354     }
 355 ;
 356
 357 /* A string used for its contents.  Strip the quotes. */
 358 string_content:
 359   STRING
 360     {
 361       $$ = $1 + 1;
 362       $$[strlen ($$) - 1] = '\0';
 363     };
 364
 365
 366 epilogue.opt:
 367   /* Nothing.  */
 368     {
 369       $$ = xstrdup ("");
 370     }
 371 | "%%" EPILOGUE
 372     {
 373       $$ = $2;
 374     }
 375 ;
 376
 377 semi_colon.opt:
 378   /* Nothing.  */
 379 | ";"
 380 ;
 381 %%
 382 /*------------------------------------------------------------------.
 383 | When debugging the parser, display tokens' locations and values.  |
 384 `------------------------------------------------------------------*/
 385
 386 static void
 387 yyprint (FILE *file,
 388          const location_t *loc, int type, const yystype *value)
 389 {
 390   fputs (" (", file);
 391   LOCATION_PRINT (file, *loc);
 392   fputs (")", file);
 393   switch (type)
 394     {
 395     case CHARACTER:
 396       fprintf (file, " = '%s'", value->string);
 397       break;
 398
 399     case ID:
 400       fprintf (file, " = %s", value->symbol->tag);
 401       break;
 402
 403     case INT:
 404       fprintf (file, " = %d", value->integer);
 405       break;
 406
 407     case STRING:
 408       fprintf (file, " = \"%s\"", value->string);
 409       break;
 410
 411     case TYPE:
 412       fprintf (file, " = <%s>", value->string);
 413       break;
 414
 415     case BRACED_CODE:
 416     case PROLOGUE:
 417     case EPILOGUE:
 418       fprintf (file, " = {{ %s }}", value->string);
 419       break;
 420     }
 421 }
 422
 423 void
 424 gram_error (gram_control_t *control ATTRIBUTE_UNUSED,
 425             location_t *yylloc, const char *msg)
 426 {
 427   LOCATION_PRINT (stderr, *yylloc);
 428   fprintf (stderr, ": %s\n", msg);
 429 }